"Sea Dreams" by "Michael D. Hilborn"

["Sea Dreams" by Michael D. Hilborn is licensed under a Creative Commons Attribution-Noncommercial-Share Alike 3.0 United States License.]

The story title is "Sea Dreams".
The story author is "Michael D. Hilborn".
The story headline is "An Interactive Beach Combing".
The story genre is "Fantasy".
The story description is "After midnight, alone on the beach, and your in the mood for a smoke. Time to find the old sea dog, Verna, and see what goodies she might have for you."
The story creation year is 2009.

Release along with a solution.
Release along with the source text.

Use no scoring.

Include Modified Help Menu by Biggles.[*Modified version of Basic Help Menu by Emily Short.]
Include Far Away by Jon Ingold.
[Include Simple Followers by Emily Short.]

Part 1 - Defining the Model World

Rule for deciding whether all includes scenery: 
	it does not.

Chapter 1 - New Kinds and Values

The immediate area is a backdrop. The immediate area is everywhere.

Instead of examining the immediate area:
	try looking.
	
Health status is a kind of value. The health statuses are unconscious, asleep, sickly, hallucinating, and awake.

A person has a health status. A person is usually awake.

Definition: A room is aquatic if it is Beneath the Pier or it is Breakers.

Definition: A room is fishable if it is Breakwater or it is Breakers or it is Breakwater's Edge.

An sentient sea creature is a kind of person. A sentient sea creature is usually neuter.

Instead of giving a something (called the item) to a sentient sea creature (called the being):
	try showing the item to the being;
	
Instead of telling a sentient sea creature (called the being) about something:
	say "Perhaps you should try asking [the being] about that topic."

Instead of answering a sentient sea creature (called the being) that something:
	say "Perhaps you should try asking [the being] about that topic."

Instead of asking a sentient sea creature (called the being) about something:
	say "'Sorry, but I haven't been fully implemented yet,' says [the being]. 'Please enjoy the rest of the game.'"
			
Chapter 2 - Verbs
 
Section 1 - New verbs

Rowing is an action applying to one visible thing.

Understand "row [direction]" as rowing.

Check rowing (this is the block rowing rule):
	say "Rowing [noun] not implemented yet." instead.
	
Swimming is an action applying to nothing.

Understand "swim" as swimming.

Check swimming (this is the block swimming rule):
	say "You need to be in water in order to swim." instead.
	
Smoking is an action applying to one touchable thing.

Understand "smoke [something]" as smoking.

Check smoking (this is the block smoking rule):
	say "You can't smoke [the noun]."
	
Blowing is an action applying to one visible thing.

Understand "blow [something]" or "blow on [something]" as blowing.

Report blowing:
	say "You gently blow a puff of air on [the noun].";
	
Covering it with is an action applying to one touchable thing and one touchable thing.

Understand "cover [something] with [something]" as covering it with.

Check covering it with (this is the convert to putting on rule):
	if the second noun is the fishing net or the second noun is the blanket,
		try putting the second noun on the noun instead;

Check covering it with (this is the block covering rule):
	say "You can't cover [the noun] with [the second noun]."

Part 2 - The Adventure

Chapter 1 - Creating The World

Section 1 - Beach and breakwater

Moonlit Beach is a room. The description of the Moonlit Beach is "Waves slog their way upon the shore to the east, their crests diaphanous strings in the moonlight. You stand on the damp, wet sand that serves as the border between land and sea. The beach continues south while north lies the darkened entrance to the boardwalk. Dunes roll away to the west."

Dunes is west of Moonlit Beach. Dunes is northwest of Lifeguard Stand. Dunes is southwest of Boardwalk Entrance. Dunes is southwest of Moonlit Beach. Dunes is northwest of Moonlit Beach. Dunes is west of Lifeguard Stand. The description of Dunes is "A range of sandy mounds fights off the beach town that encroaches the coast from the west and north. The boardwalk ends northeast of here while far to the south, the grassy hillocks give way to a salt marsh. You can return to the beach by heading east, and you can vaguely see the outline of a lifeguard stand to the southeast." Understand "dunes", "mounds" as the immediate area when in Dunes.

Instead of going north in the Dunes:
	try going west;
	
Instead of going southwest in the Dunes:
	try going west;
	
Instead of going northwest in the Dunes:
	try going west;
	
Instead of going west in the Dunes:
	say "The beach ends that way, and civilization begins. You have no desire to wander asphalt streets when you can be out by the water."
	
Instead of going south in the Dunes:
	say "Too much overgrowth and mud. It would be difficult to wander the salt marshes during the night."

Some grass is scenery in Dunes. The description of grass is "Dense thickets of long, slender reeds perforate the sandy hills."

Some driftwood is in Dunes. "Lying among the grass is some driftwood." The description of some driftwood is "A pile of wood, dry and brittle, perhaps from the hull of a deceased ship." Understand "wood", "pile of wood" as some driftwood.

Lifeguard Stand is south of Moonlit Beach. Lifeguard stand is southwest of Breakers. The description of the Lifeguard Stand is "A solitary lifeguard stand, devoid of a denizen at this hour, rises from the sand, overlooking the oceanic view to the east. To the south, the beach ends in a salt marsh. Southeast the shadowy outline of a breakwater emerges from the shoals."

Instead of going nowhere from the Lifeguard Stand:
	say "The southern expanse is blocked by the salt marsh, but you can go west toward the dunes, east into the ocean, southeast toward the breakwater, or continue north along the beach."

The solitary lifeguard stand is a supporter in Lifeguard Stand. The solitary lifeguard stand is scenery. The solitary lifeguard stand is enterable. The description of the solitary lifeguard stand is "The cracked, faded white paint and its tilt betray the stand's age. Still, it has many years left in it. You once sat upon the stand, a savior of the helpless, a bronze king among men, your whistle their command. That was long ago. In your youth."

Instead of climbing the solitary lifeguard stand:
	try entering the solitary lifeguard stand;

Breakwater's Edge is southeast of Lifeguard Stand. Breakwater's Edge is south of Breakers. The description of Breakwater's Edge is "The beach here gradually gives a sandy birth to a palisade of boulders that extends eastward above the ocean's waves. A salt marsh borders the southern exposure of the rocks and west the beach crests in a cascade of dunes. You can wade through the breakers to the north and to the northwest you can vaguely make out the outline of a lifeguard stand."

Instead of going nowhere from Breakwater's Edge:
	say "The ocean surrounding the breakwater is too turbulent for swimming and the salt marsh blocks the south. You can wade north through the breakers, head northwest to the beach, or walk out the breakwater to the east."

The fishing rod is in Breakwater's Edge. "Someone has left a fishing rod leaning against one of the boulders."

The tackle box is a container in Breakwater's Edge. The tackle box is openable. The tackle box is closed. "Next to [if the fishing rod is in the location of the tackle box]the fishing rod [otherwise]one of the boulders [end if]is [if the tackle box is open]an open[otherwise]a closed[end if] tackle box." The description of the tackle box is "A tackle box constructed of a sickly green plastic[if the tackle box is open and something is in the tackle box]. The tackle box is open, revealing [a list of things in the tackle box][otherwise if the tackle box is open]. The tackle box is open and empty[otherwise]. The tackle box is closed[end if]."

The knife is in the tackle box. The description of the knife is "A large, sharp, serrated blade."

An instruction manual is in the tackle box. The description of the instruction manual is "It's a quick reference manual for using a fishing rod."
	
Breakwater is east of Breakwater's Edge. The description of the Breakwater is "Waves pummel the boulders, then melt among the crevices in bright silver streams of moonlight. You stand at the end of the breakwater, upon its tallest rock, with west as your only direct egress to the beach[if Hallucinations is happening]. Winds from the eastern storm stir here, buffeting you with the spray of the waves[end if]. Below you, a tidal pool has formed in a basin of among a ring of boulders."

The distant tidal-pool is scenery in Breakwater. The distant tidal-pool is distant. The printed name of the distant tidal-pool is "tidal pool". The description of the distant tidal-pool is "From here, the tidal pool is a clear circle of reflected moonlight and stars." Understand "tidal pool", "pool" as tidal-pool.

Instead of going nowhere from Breakwater:
	say "The ocean surrounding the breakwater is too turbulent for swimming. You can head west to the beach or climb down the rocks to the tidal pool."

Tidal Pool is down from Breakwater. The description of the Tidal Pool is "Crowned by boulders and fed by the drainage from the rocks, a pool of clear seawater no deeper than your knees has formed in this basin. You stand on its edge from where you can enter the pool or go up to the top of the breakwater."

The silver pool is scenery in Tidal Pool. The printed name of the silver pool is "tidal pool". The description of the silver pool is "Protected from the waves by the ring of the boulders, the pool lies still, a clear mirror that reflects the night sky." The silver pool is a container. The silver pool is enterable. Understand "tidal pool", "seawater" as silver pool.

Instead of going nowhere from Tidal Pool:
	say "You can go back up the breakwater or get in the tidal pool."
	
Breakers is east of Moonlit Beach. Breakers is east of Lifeguard Stand. Breakers is southeast of Moonlit Beach. Breakers is northeast of Moonlit Beach. The description of Breakers is "Here the waves crest around your knees, forming thin strands of frothy moonlight before ultimately spilling upon the western shore. To the south, the waves scatter among the boulders of a breakwater and to the north, they roll beneath the outline of a pier[if Hallucinations is happening][paragraph break]The waves are more fierce than before, a result of the storm brewing to the east[end if]." Understand "breakers" as the immediate area when in Breakers.

Instead of going northeast in Breakers:
	try going east;
	
Instead of going southeast in Breakers:
	try going east;
	
Instead of going east in Breakers:
	if the player is carrying something
	begin;
		say "You can't go swimming when carrying something.";
	otherwise;
		say "You dive into the waves and swim around in the darkness, being careful not to stray too far out into the currents. You return to the breakers, exhausted but energized.";
	end if.
	
Section 2 - Boardwalk and pier

Boardwalk Entrance is north of Moonlit Beach. Boardwalk Entrance is northwest of Breakers. The description of the Boardwalk Entrance is "The boardwalk, this beach town's primary attraction for locals and tourists, starts here, ramping up until it rises one story off the beach. The gates are closed and locked this late at night, but you can head around the entrance to the northeast where a pier leads out to the sea. South awaits your beach and dunes begin to the southwest."

The entrance gates are a door. The entrance gates are north of Boardwalk Entrance. The entrance gates are scenery. The entrance gates are closed. The entrance gates are locked.

Instead of going nowhere from Boardwalk Entrance:
	say "You can head northeast to the pier, south to the beach, or southwest to the dunes."

Beneath the Pier is northeast of Boardwalk Entrance. Beneath the Pier is north of Breakers. The description of Beneath the Pier is "You stand knee-deep in sludgy water beneath a pier formed by an extension of the boardwalk. A vaulted hall of barnacle-encrusted pillars leads west into the underbelly of the boardwalk and east out to sea. Southward, the ocean waves break upon the shoreline."

The distant light is in Beneath the Pier. "Light flickers to the west, beneath the boardwalk." 

Instead of going northeast in Beneath the Pier:
	try going east;

Instead of going southeast in Beneath the Pier:
	try going east;
		
Instead of going east in Beneath the Pier:
	say "The water beneath the pier is filthy and not suitable for swimming."
	
Instead of going nowhere from Beneath the Pier:
	say "You can go deeper beneath the boardwalk to the west, go wading to the south, or go southwest to the boardwalk entrance."

After examining the barnacle-encrusted pillars when in Beneath the Pier for the first time:
	say "After closer inspection, you notice a starfish clinging to one of the pillars.";
	move the starfish to Beneath the Pier.
	
The starfish is a thing. "Clinging among the barnacles is a common starfish."

Under the Boardwalk is west of Beneath the Pier. The description of Under the Boardwalk is "A gloomy sanctuary constructed by the pillars and planks of the boardwalk. The alcove is dimly aglow from a campfire [if the campfire is flickering]flickering[otherwise]blazing[end if] among a ring of shells in the sand. From here a vaulted hall of barnacle-encrusted pillars, the supports of a pier running above, heads east into the sea. This sandy patch ends to the north." Understand "Under the Boardwalk" as the immediate area when in Under the Boardwalk.

The boardwalk's underbelly is scenery in Under the Boardwalk. The description of the boardwalk's underbelly is "Shadows caper among the woodwork, jumping from one flicker of campfire light to the next." Understand "boardwalk", "woodwork" as boardwalk's underbelly.

The campfire is scenery in Under the Boardwalk. The campfire is lit. The campfire can be flickering or blazing. The campfire is flickering. The description of the campfire is "Verna's dug a small pit in the sand, ringed it with seashells, and set some driftwood alight. Right now the campfire is a [if the campfire is flickering]small flame flickering over the coals[otherwise]a fierce blaze above the coals[end if]." Understand "coals", "pit", "flames", "flame", "fire" as the campfire.

After examining the campfire for the first time:
	say "Local myth suggests that the campfire has never gone out: The flames rise eternal, both night and day. Others imply Verna can see the future within its flames. As for what you believe... Well, you've seen no evidence of either."
	
The ring of seashells is scenery in Under the BoardWalk. The description of the ring of seashells is "Verna's arranged a variety of seashells in a ring around the campfire." Understand "shells" as ring of seashells.

Instead of touching the campfire:
	say "Fucking hot!"

Filthy Shore is north of Under the Boardwalk. The description of the Filthy Shore is "Detritus from the boardwalk conglomerates here, either bobbing among the water or lying discarded on the damp sand. Escape from this sad coating of trash lies beneath the boardwalk, to the south." Understand "Filthy Shore" or "shore" as the immediate area when in Filthy Shore.
 
The trash is scenery in the Filthy Shore. The description of the trash is "Mostly discarded cans, styrofoam cups, and assorted fast food wrappers, all tossed over the edge of the boardwalk." Understand "cans", "cups", "discarded cans", "fast food wrappers", "wrappers", "papers" as the trash.

Instead of going nowhere from the Filthy Shore:
	say "The water is too filthy to wade in. The only escape is to the south."
	
Instead of taking the trash:
	say "As much as you would like to clean it all up, there is far too much for a single individual to handle."

Instead of searching the trash:
	try examining the trash;
	
After examining the trash for the first time:
	say "You didn't notice it before, but a dead fish floats among the trash.";
	move the dead fish to the Filthy Shore.

The rusty lobster trap is in the Filthy Shore. The rusty lobster trap is a container. The rusty lobster trap is openable. The rusty lobster trap is transparent. The carrying capacity of the rusty lobster trap is 1. "Discarded among the trash is a rusty lobster trap." The description of the rusty lobster trap is "A thin, wire-framed trap with a door that is [if the rusty lobster trap is open]open[otherwise]closed[end if][if something is in the rusty lobster trap]. The trap contains [a list of things in the rusty lobster trap][end if]."

The dead fish is a thing. "Floating among the trash is a dead fish." The description of the dead fish is "Limp and coated with slime. A nasty odor lingers around it." Understand "slime" as the dead fish.

Some bait is a thing. The description of the bait is "Several, thin filets of raw fish." Understand "filets", "fish", "raw fish" as the bait.

Instead of cutting the fish when the player is carrying the knife:
	say "Using the knife, you gut, skin, and filet the dead fish, discarding the remains. You now have some bait.";
	remove the dead fish from play; 
	move some bait to the player;
	
Section 3 - Regions

Coast is a region. Moonlit Beach, Breakers, Lifeguard Stand, Breakwater's Edge, Breakwater, Tidal Pool, Dunes, Boardwalk Entrance, Under the Boardwalk, Beneath the Pier, and Filthy Shore are in the Coast.

Understand "beach", "shore", "coast", "coastline", "shoreline" as the immediate area when in the Coast.


Section 4 - Backdrops

The waves are a backdrop. The description of the waves is "The ocean waves crash up and down the shore, their crests glittering in the full moon." The waves are in the Coast. Understand "crests" as the waves.

The ocean is a backdrop. The description of the ocean is "Beyond the rolling waves, the ocean [if Hallucinations is happening]no longer lies still; it simmers beneath the approaching storm[otherwise]lies still like a blanket thrown beneath the horizon[end if]." The ocean is in the coast. Understand "sea", "water", "view" as the ocean.

The wet sand is backdrop. The description of the wet sand is "Soft and damp, the sand squelches beneath every footstep." The wet sand is in Moonlit Beach, Breakers, Breakwater's Edge, Lifeguard Stand, and Filthy Shore.

Instead of taking the wet sand:
	say "You scoop up a handful, then let it dribble back to the ground."

The dry sand is backdrop. The description of the dry sand is "Cool and brusque against your footfalls." The dry sand is in Dunes and Under the Boardwalk.

Instead of taking dry sand:
	say "You take handful, only to have it sift through your fingers."

The distant dunes are backdrop. The distant dunes are distant. The distant dunes are in Moonlit Beach, Boardwalk Entrance, Lifeguard Stand, and Breakwater's Edge. The description of the distant dunes is "Waves of sand and grass that separate your beach from the rest of civilization."

The salt marsh is a backdrop. The salt marsh is distant. The description of the salt marsh is "A flood plain of saltwater and grasses that borders the southern expanse of your beach." The salt marsh is in the Dunes, Lifeguard Stand, and Breakwater's Edge.

The distant boardwalk is a backdrop. The distant boardwalk is distant. The description of the distant boardwalk is "A few hours ago, the boardwalk was a strip of lights that lined the beach, awash with the sound of people. It's closed now, silent and dark, awaiting the dawn so it may open again." The distant boardwalk is in Moonlit Beach, Dunes, Under the Pier, Boardwalk Entrance, and Filfthy Shore.

The distant breakwater is a backdrop. The distant breakwater is distant. The distant breakwater is in Breakers, Lifeguard Stand, and Dunes. The description of the distant breakwater is "A dark palisade of boulders surfaces from the southeastern corner of the beach." Understand "boulders" as the distant breakwater.

The beach town is a backdrop. The beach town is distant. The description of the beach town is "A solid grid of beach houses, condominiums, surf shops and stores engulfs the island. Bustling with activity during the day, the town is wonderfully dormant now, though every now and then you can hear the sigh of a distant, passing car." The beach town is in the Dunes and Boardwalk Entrance.

The boulders are a backdrop. The boulders are in Breakwater's Edge, Breakwater, and Tidal Pool. The description of the boulders is "The boulders emerge from the ocean like the grey vertebrae of an ancient serpent."

The distant lifeguard stand is a backdrop. The distant lifeguard stand is distant. The distant lifeguard stand is in Breakwater's Edge, Dunes, and Moonlit Beach.

The barnacle-encrusted pillars are a backdrop. The barnacle-encrusted pillars are in Beneath the Pier and Under the Boardwalk. The description of the barnacle-encrusted pillars is "The pillars, encrusted with barnacles, support the pier." Understand "barnacles" as the barnacle-encrusted pillars.

Instead of searching the barnacle-encrusted pillars:
	try examining the barnacle-encrusted pillars;
	
The pier is a backdrop. The pier is distant. The pier is in Breakers, Beneath the Pier, and Under the Boardwalk. The description of the pier is "Held aloft by pillars one story high, the pier extends east from the boardwalk and over the sea. During the day it is packed with tourists and locals who dine from the hot dog and sausage carts parked at the pier's edge." 

The moon is a backdrop. The moon is in the Coast. The description of the moon is "Full and beautiful this night, its glow splayed out upon the ocean for all to see[if Hallucinations is happening]. Tendrils from the growing storm have begun to slide across its face[end if]."

The night sky is a backdrop. The night sky is in the Coast. The description of the night sky is "A crisp, clear night[if Hallucinations is happening] high above, but as the sky approaches the horizon, ominous clouds swallow the stars[otherwise]. The stars prick the black underbelly of the heavens with their sharp light[end if]." Understand "stars", "heavens" as the night sky.

The storm is a backdrop. The description of the storm is "Far off on the eastern horizon, clouds blot out the stars. Sheets of light skitter across the underbelly of the storm." 

Section 5 - Every turn rules

Every turn when in the Coast during Wide Awake:
	if a random chance of 1 in 5 succeeds
	begin;
		say "[one of]A fresh breeze brings with it the aroma of saltwater[if the location is the Dunes] and rustles the grass[end if][or]You hear the distant clang of a buoy[or]Far up the coast, a foghorn sounds[purely at random].";
	end if.
	
Every turn when in the Coast during Hallucinations:
	if a random chance of 1 in 5 succeeds
	begin;
		say "[one of]Thunder grumbles in the distance[or]A gust of cold wind blows down the beach[or]Far to the east, lightning plays among the clouds[or]An echo of thunder emanates from the east[or]An arm of a storm cloud momentarily obscures the moonlight[or]Far up the coast, a foghorn sounds[or]You hear the distant clang of a buoy[purely at random].";
	end if.
	
Every turn when in Breakwater and a random chance of 1 in 10 succeeds:
	say "A particularly large wave smashes against the rocks, showering you with a salty spray."

Section 6 - Dropping stuff

Before dropping something:
	if the location is aquatic
	begin;
		say "But you would lose [the noun] in the water." instead;
	end if;
	
Chapter 2 - Verna And the Campfire

Section 1 - Establishing the NPC

Verna is a woman in Under the Boardwalk. "[one of]The woman sitting huddled before the campfire... Her name is Verna, a denizen of the beach for as long as you remember, and others proclaim her as old as the sand itself.[paragraph break]'Wondered when you might come about,' she says to you, lifting her eyes from the flames. A thin cigar dangles from her mouth, and smoke wisps with her words. 'Been lonely here. Not another soul about this night. And the fire's dying.' She pokes the coals with a piece of driftwood[or][Verna's locale description][stopping]."

To say Verna's locale description:
	say "Verna sits before the campfire, [if Hallucinations is happening]those dead, white [otherwise]her [end if]eyes transfixed on the flames[if Hallucinations is happening]. She murmurs quietly to herself, obviously unaware of your presence if anything at all[end if]"
	
The description of Verna is "[if Wide Awake is happening]Tan skin, cracked and flayed by sun and sand. She's thin, almost atrociously so, with her long gray hair falling limply from beneath a kerchief tied round her head. A necklace of shells drapes around her neck.[paragraph break]She's been here, underneath the boardwalk, for as long as you can remember. You saw her from afar when you were a child and she didn't seem much different back then. The other kids kept away from here, proclaimed or a sea hag or witch[otherwise]She's different from what you remember: Her nose and chin are longer and her skin has taken on a greenish tinge. Seaweed twists among the braids of her hair and her eyes--they are milky white with no pupils and they are fixated on the fire[end if]."

[After examining Verna for the first time during Hallucinations:
	say "Verna lifts her head, directing those ghastly white eyes at your own. 'Don't be afraid, dear. I am no more than I used to be. You just see me for who I truly am: a daughter of the Coast, a Sea Witch.'"]

Verna is carrying the piece of driftwood. The description of the piece of driftwood is "A slender stick with a sharp end[if Hallucinations is happening]. It's smoother than what you remember, and polished now. It reminds you of a magician's wand[end if]." Understand "branch", "wand", "stick" as the piece of driftwood.

Verna is carrying the thin cigar. The thin cigar is lit. The description of the thin cigar is "[if the player is carrying the thin cigar]A thin cigar, partially smoked, and knowing Verna, certain to possess ingredients other than tobacco[otherwise]It dangles from Verna's mouth, the tip glowing and fading with each of her breaths[end if]." Understand "cigarette", "joint", "smoke" as the thin cigar.

Verna is wearing the necklace. The description of the necklace is "A strand of small seashells of various shapes and colors. It is adorned with a small starfish." Understand "seashells", "starfish" as the necklace.

Verna is wearing the kerchief. The description of the kerchief is "It's difficult to discern the color the kerchief might have once been. Verna has the grey cloth tied around her hair, similar to how you imagine a gypsy might wear it." Understand "handkerchief", "cloth" as the kerchief.

Section 2 - Conversations with Verna

Instead of telling Verna about something:
	say "You may want to try asking Verna about that."

Instead of answering Verna that something:
	say "You may want to try asking Verna about that."

Instead of giving something to Verna:
	try showing the noun to Verna;
	
After asking Verna about a topic listed in the Table of Verna's Responses during Wide Awake:
	say "[response entry][line break]";
			
Table of Verna's Responses
Topic	Response
"herself/Verna/job"	"'Old Verna? The sea hag?' she replies. 'The witch beneath the boardwalk?' She smiles, revealing a few missing teeth. 'I know what they call me.'"
"sea hag" or "sea witch" or "sea witches" or "witch/hag/hags/witches"	"'Daughters of the Coast, so the local legends say. They protect the sea from man, and man from the sea.'"
"campfire/fire/flame/flames"	"'Keeps me company when others don't,' she says. 'It's warm, animate, and always has something to say.' As she speaks, the fire pops and crackles[if the campfire is flickering]. 'Shame it's not ablaze like before. Maybe you can do something about it.' She gazes up at you, imploringly[end if]."
"beach/shore/coast/shoreline/coast"	"'Home to me and you, my dear, and others,' she says. 'It gets a little smaller every year. Mankind is eating her up bit by bit.'"
"mankind/island"	"She rolls her eyes. 'Sometimes it feels like they've destroyed everything: Land, air, sea. This island, for instance, once a lush canopy of land and marine life. Now...' She shrugs. 'Asphalt, concrete, sewage, and trash.'"
"beach town" or "town"	"[if Verna is carrying the thin cigar]Before she answers, she takes a long drag on her cigar. [end if]'The place has grown up around me. Gets busier every year. Don't know how much more this island can stand.'"
"cigar/cigarette/smoke/smoking" or "thin cigar"	"[if Verna is carrying the thin cigar]She takes a long hit. [end if]'Not certain of the blend. More potent than usual. Allows one to see what one normally can't[if the player is carrying the thin cigar]. Go on, try it, my dear. It won't hurt[end if][if the campfire is flickering]. If you can get this campfire going again, my dear, I'll share it with you[end if].'"
"boardwalk/pier"	"'This place--' She indicates the boardwalk with a scrawny finger. 'This place epitomizes entertainment over environment. A beach destroyed to erect shops, restaurants, mini-golf, arcades, and fairgrounds.' She sighs. 'And it's my home now.'"
"sand"	"She scoops up a handful of hand and allows it to drift through her fingers. 'Crystals of time,' she murmurs. 'Once great boulders and rocks... worn down to this over the millennia.'"
"me/myself"	"'You, my dear?' She chuckles. 'You keep me company when the campfire can't. I've known you before you've known me. Saw you as a kid, when you used to run around the boardwalk. Now you're older. Not as old as I, never as old as I, but I can see the years on you. Sand and sun and surf--they age a man quicker than one would like.'"
"ocean"	"'Broad and undiscovered,' she whispers. 'The shores and the coasts are a loss. We've destroyed them. But farther out, in the greatest of depths, well, there lies a realm we don't understand.'"
"kerchief/hat"	"'This?' she asks, tugging at the kerchief. 'It's silk. Was silk. I guess it still is. It's so old. Like me.'"
"necklace"	"She tugs at the strand of seashells and fingers the starfish. 'Don't know where I got this. Always worn it. Been with me forever.'"
"age/old"	"'Older than most, my dear' she says."

Report asking Verna about something during Wide Awake:
	say "'That, I cannot help you with,' she says, quietly." instead.

Section 3 - Getting the cigar from Verna

Persuasion rule for asking Verna to try giving the thin cigar to the player: persuasion succeeds.

Unsuccessful attempt by Verna giving the thin cigar to the player:
	do nothing;
	
Instead of taking the thin cigar when Verna is carrying the thin cigar:
	try asking Verna for the thin cigar;
	
Instead of Verna giving the thin cigar to the player:
	try asking Verna for the thin cigar;
	
Instead of asking Verna for the thin cigar:
	if the player is carrying the thin cigar
	begin;
		say "Her eyes twinkle. 'You already have the cigar, my dear.'";
	otherwise if the campfire is flickering;
		say "'I'll lend you a smoke if you can get the campfire aflame again,' Verna says.";
	otherwise if the campfire is blazing and Verna is carrying the thin cigar;
		say "She hands you the thin cigar. 'Here you go, my dear, it is all yours. Smoke it. You'll thank me for it.'";
		move the thin cigar to the player;
	otherwise;
		say "'I don't have the cigar, my dear.'";
	end if;

Instead of going when the player is carrying the thin cigar and Verna can see the player during Wide Awake:
	say "'If you don't mind, my dear, I'll take that smoke back before you leave.'";
	
Instead of giving the thin cigar to Verna when the player is carrying the cigar:
	say "'Thank you, my dear,' she says, plucking the cigar from you. She takes a heavy hit.";
	now Verna is carrying the thin cigar;
  
Section 4 - Idle Verna

Every turn when in Under the Boardwalk during Wide Awake:
	if a random chance of 1 in 5 succeeds
	begin;
		if Verna is carrying the thin cigar
		begin;
			say "[one of]Verna warms her frail hands over the fire[or]Verna takes a long drag from the cigar[or]Verna coughs[or]Verna sighs to herself and takes a hit of her cigar[purely at random].";
		otherwise;
			say "[one of]Verna stares into the fire[or]Verna seems transfixed by the flames of the campfire[or]Verna pokes at the campfire with her stick[or]Verna picks up some sand and lets it flow through her fingers[purely at random].";
		end if;
	end if;
	
Chapter 3 - The mermaid

Temperature is a kind of value. The temperatures are cold, chilled, and warm.

The pale woman is a woman. The pale woman is unconscious. The pale woman can be cleansed or uncleansed. The pale woman is uncleansed. The pale woman has a temperature. The pale woman is cold.  The description of the pale woman is "[mermaid's description]."

Rule for writing a paragraph about the pale woman:
	if the pale woman is wearing the net and the pale woman is unconscious
	begin;
		say "[one of]You stop dead in your tracks. Lying [or] Lying [stopping]unconscious upon the sand is a woman entangled in a fishing net. She must have recently washed ashore. The net trembles with her shivers.";
	otherwise if the pale woman is unconscious and the woman is wearing the blanket;
		say "Lying unconscious upon the sand is a beautiful woman wrapped in your blanket[if the temperature of the pale woman is less than warm]. Despite the blanket, she shivers uncontrollably[end if].";
	otherwise if the pale woman is unconscious;
		say "Lying unconscious upon the sand is a beautiful, naked woman[if the temperature of the pale woman is less than warm]. She shivers uncontrollably[end if].";
	otherwise if the pale woman is sickly and the temperature of the pale woman is less than warm;
		say "A pale woman sits here, arms wrapped around her knees, slowly rocking back and forth while she shivers uncontrollably.";
	otherwise if the pale woman is sickly and the pale woman can see the campfire;
		say "Huddled before the campfire is the sickly, pale woman.";
	otherwise if the pale woman is sickly;
		say "The pale woman stands nearby.";
	otherwise;
		say "The beautiful woman stands nearby.";
	end if.
	
To say mermaid's description:
	if the pale woman is unconscious and the pale woman is wearing the fishing net
	begin;
		say "Pale, slender, naked... and hopelessly entwined in a fishing net slathered with human trash. She shivers uncontrollably";
	otherwise if the pale woman is unconscious and the pale woman is wearing the blanket;
		say "Pale and slender with long silver hair tangled with mud and trash. She's wrapped in your army blanket and just above the folds of the blanket, you can see several small slits on each side of her neck[if the temperature of the pale woman is less than warm]. Despite the blanket, she still shivers[end if]";
	otherwise if the pale woman is unconscious and the pale woman is uncleansed;
		say "Pale, slender, naked, and beautiful despite the filth gnarled in her silver hair and streaked across her skin. Several small slits trace each side of her neck[if the temperature of the pale woman is less than warm]. She shivers uncontrollably[end if]";
	otherwise if the pale woman is sickly and the pale woman is uncleansed;
		say "Pale, slender, and wrapped in a blanket. Filth entangles her long silver hair, and mars her cheeks and bare shoulders. Several small slits trace either side of her neck[if the temperature of the pale woman is less than warm]. She shivers uncontrollably[end if]";
	otherwise if the pale woman is sickly and the pale woman is cleansed;
		say "Pale, slender, and wrapped in your blanket. Her silver hair, which flows over her shoulder, dapples with moonlight and water. Despite her beauty, the flesh over her cheeks is drawn, and bags float beneath her eyes";
	otherwise if the pale woman is sickly and the pale woman is in the silver pool;
		say "She floats serenely in the tidal pool, hair floating about her like the tendrils of a basket starfish";
	otherwise;
		say "A gossamer gown woven of moonlight covers the woman. Her hair cascades about her shoulders in silver waterfalls. Her cheeks and complexion are pale, but full like the moon above";
	end if.

The woman's gills are part of the pale woman. The description of the woman's gills is "Upon closer inspection, they are small flaps of skin that undulate with each of the woman's breaths." Understand "throat", "neck", "flaps", "slits" as the woman's gills.

The pale woman is wearing the fishing net. The fishing net can be severed. The fishing net is not severed. The description of the fishing net is "[if the woman is wearing the fishing net]Thick coils of filthy netting entangle the woman[otherwise]The discarded netting is woven of thick, sickly rope and is entangled with bits of trash and other detritus[end if]."

Chapter 4 - The player

The player is carrying the blanket. The blanket is wearable. The description of the blanket is "A thick, green army blanket on which you sleep." Understand "army blanket" as the blanket.

Report putting on the blanket:
	say "You wrap the blanket around your shoulders." instead.
	
Instead of examining the player:
	try taking inventory;
	
Instead of putting something on the player:
	try wearing the noun;
	
Part 3 - Plot

When play begins:
	say "After midnight, and the beach is yours. A perfect summer night: The sky is clear, the air cool, the water warm... And you're dying to start it off with a smoke.[paragraph break]Verna... Verna should be around. She always is, sitting by her campfire, under the boardwalk. She'll have something to smoke--she always does, and it's always interesting."
	
Chapter 1 - Setting the campfire ablaze

Instead of putting something on the campfire:
	try inserting the noun into the campfire.

Instead of inserting something into the campfire:
	say "That would surely destroy [the noun]."
		
Instead of inserting some driftwood into the flickering campfire:
 	say "You drop the dry and brittle pile of wood into the campfire. Almost instantly, the flickering fire bursts to life, consuming the wood and growing into a fierce blaze.[paragraph break]'Wonderful, my dear,' says Verna. 'That should last for the rest of the night. If you would like to share a smoke, just ask for it.'";
	now the campfire is blazing;
	remove the driftwood from play;
	
Instead of blowing the flickering campfire:
	say "With each breath, the flame bursts up, only to die down again."
	
Instead of blowing the blazing campfire:
	say "The campfire is already ablaze."
	
Instead of showing the driftwood to Verna:
	say "'That should do, nicely,' she says. 'Go ahead. Put the wood on the fire.'"

Chapter 2 - Smoking the cigar

Instead of smoking the thin cigar for the first time during Wide Awake:
	say "You close your eyes, inhale deeply, and savor the strange flavor that licks about your tongue and throat. After a few moments, you exhale, and open your eyes. The world looks the same, though it feels a little less heavy.";
	if the player can see Verna
	begin;
		say line break;
		say "'That's it, my dear,' whispers Verna. 'Try it again.'";
	end if;
	
Instead of smoking the thin cigar for the second time during Wide Awake:
	say "You close your eyes, inhale deeply, and savor the strange flavor that licks about your tongue and throat. After a few moments, you exhale, and try to open your eyes; unfortunately, your lids refuse to widen. You stumble, almost collapse, but manage to straighten yourself. You open your eyes...";
	now the player is hallucinating;
	say line break;
	if the player can see Verna
	begin;
		say "Verna laughs. 'Potent stuff, no?' Her laugh turns to a cackle, and her eyes... they've turned milky white and have lost their pupils.";
		say line break;
		say "In the distance, thunder grumbles. Verna lifts those unearthly eyes toward the horizon where storm clouds have taken shape. 'Mother Ocean,' she whispers. 'She is angry. I must find out why.' She stirs, readjusts herself until she is sitting cross-legged before the fire, then, staring into the flames, she begins to murmur.";
		move the storm to the Coast;
		move the pale woman to the Moonlit Beach;
		set up the breakwater dinner;
		Verna draws a new image in zero turns from now;
		now Verna's drawing is old;
	otherwise;
		say "Nothing seems to have changed.";
	end if.
	
Instead of smoking the thin cigar:
	say "You inhale, then exhale a cloud of smoke. Nothing. You've seemed to obtained a tolerance for whatever was in it.";

Chapter 3 - Verna's drawing

Image is a kind of value. The images are no-image, entangled-woman, woman-by-fire, woman-showering, and woman-in-tidal-pool.

Verna's drawing is a thing. The drawing can be old or new. Verna's drawing is old. Verna's drawing has an image. The image of Verna's drawing is no-image. "Etched in the sand by the campfire is a drawing[if Verna's drawing is new]. The drawing has changed since you last saw it[end if]." The description of Verna's drawing is "[drawing description]." Understand "picture", "sand" or "Verna's picture" as the drawing.

To say drawing description:
	say "Etched in the sand is an image of ";
	if Verna's drawing is entangled-woman
	begin;
		say "a stick figure covered by a series of hashed lines";
	otherwise if Verna's drawing is woman-by-fire;
		say "a stick figure dressed in a cloak and huddled by a fire";
	otherwise;
		say "a few words that say 'BUG: PLAYER SHOULDN'T SEE THIS'";
	end if;
	
At the time when Verna draws a new image:
	if the player can see Verna
	begin;
		say "Verna's hand suddenly acts on its own accord, reaching out with the stick. While she stares into the fire, her hand busily inscribes a picture into the sand. Moments later, her hand drops to her side, finished with its task.";
	end if;
	move Verna's drawing to Under the Boardwalk;
	change the image of Verna's drawing to the image after the image of Verna's drawing;
	if Verna's drawing is not entangled-woman,
		now Verna's drawing is new;
		
Instead of waking Verna during Hallucinations:
	say "Despite our best efforts, Verna remains in a trance."
	
Chapter 4 - Finding the woman and freeing her from the net

Instead of taking the pale woman when the pale woman is wearing the fishing net:
	say "Try as you might, you're unable to lift her up: You can't wrap your arms around the bulk of the fishing net."
	
Instead of taking the pale woman when the pale woman is unconscious or (the temperature of the pale woman is less than warm and the pale woman is sickly):
	if the player is carrying the woman
	begin;
		say "You are already carrying her.";
	otherwise if the player is carrying something;
		say "You can't carry the woman while you are holding something else.";
	otherwise if the pale woman is sickly;
		say "The shivering woman allows you to lift her up. She rests her head on your shoulder.";
		now the player is carrying the pale woman;
	otherwise;
		say "You gently lift the pale woman up in your arms.";
		now the player is carrying the pale woman;
	end if.

Instead of taking something when the player is carrying the pale woman:
	say "You need to put down the woman, first."
	
Instead of dropping the pale woman:
	if the location is aquatic
	begin;
		say "You can't leave her here. She would surely drown.";
	otherwise;
		say "You gently lower the woman to the ground.";
		move the pale woman to the location;
	end if;
	
Instead of attacking the fishing net:
	try cutting net;

Instead of cutting the fishing net when the pale woman is wearing the fishing net:
	if the player is carrying the knife
	begin;
		say "Using the knife, you cut through several of the thick coils of rope. Eventually you are able to remove the netting from the woman.";
		now the fishing net is in the location;
		Verna draws a new image in two turns from now;
	otherwise;
		say "You tug and pull at the net, but are unable to severe any of the ropes.";
	end if;

Instead of cutting the fishing net:
	say "It's already been cut.";

Instead of taking the fishing net when the pale woman is wearing the fishing net:
	say "You tug and pull at the net to no avail."		

Chapter 5 - Bringing the woman to the campfire

Instead of waking the unconscious pale woman:
	say "She does not respond."
	
Instead of dropping the pale woman when in Under the Boardwalk:
	say "You gently lower the woman next to Verna who takes no notice of your charge. [if the pale woman is unconscious]Unconsciously sensing [otherwise]Sensing [end if]warmth, the pale woman curls up into a fetal position";
	move the pale woman to Under the Boardwalk;
	now the pale woman is chilled;
	if the woman is wearing the blanket
	begin;
		say ". [no line break]";
		warm up the pale woman;
	otherwise;
		say ". Her shivers lighten, but don't completely dissipate.";
	end if;
	
Instead of putting the blanket on the pale woman when the pale woman is not wearing the blanket:
	say "You delicately wrap the blanket around the pale woman.";
	now the pale woman is wearing the blanket;
	now the pale woman is chilled;
	if the pale woman is in Under the Boardwalk
	begin;
		say line break;
		warm up the pale woman;
	end if;
	
Instead of taking the blanket when the unconscious pale woman is wearing the blanket:
	say "You remove the blanket from the woman.";
	move the blanket to the player;
	
To warm up the pale woman:
	say "The fire and blanket do their job, warming the pale woman. She [if the pale woman is unconscious]blinks, coughs up water, and suddenly sits up, staring [otherwise]looks [end if]gratefully at you. Her shivering abates.";	
	now the pale woman is sickly;
	now the pale woman is warm;
	Verna draws a new image in zero turns from now;
	end the game saying "And the adventure continues...";
	
Chapter 6 - Cleansing the Woman

Section 1 - Defining the shower

The shower stand is a supporter in the Boardwalk Entrance. The shower stand is enterable. The carrying capacity of the shower stand is one. "An open, freshwater shower rises out of the sand, available to beach dwellers who want to rinse off before entering the boardwalk[if the faucet is switched on]. The shower has been turned on[end if]." The description of the shower stand is "It's little more than a pipe, faucet and showerhead that rise above a square plank of sand-covered wood[if the faucet is switched on]. Fresh, warm water rains down from the showerhead, dribbles off the stand, and drains into the sand[end if]." Understand "plank", "pipe", "showerhead" as the shower stand. Understand "water" as the shower stand when the faucet is switched on.

The faucet is a device that is part of the shower stand.

Instead of switching on the shower stand:
	try switching on the faucet;
	
Instead of switching off the shower stand:
	try switching off the faucet;

Report switching on the faucet:
	say "You turn the shower on. Warm water flows from the showerhead." instead.

Report switching off the faucet:
	say "You twist the faucet, turning the shower off." instead

	
Section 2 - Shower rules

Definition: A thing is needed-dry if it is the blanket or it is the driftwood.

Suppress-printing is a truth state that varies.

Showering rules is a rulebook.

A showering rule (this is the shower is crowded rule):
	if (putting something on the shower stand or entering the shower stand) and something (called the item) is on the shower stand
	begin;
		say "You will have to move [the item] off the shower stand, first.";
		rule fails;
	end if.
	
A showering rule (this is the can't carry in something that needs to be dry in rule):
	if entering the shower stand and the player is carrying something (called the item) that is needed-dry
	begin;
		say "You don't want to get [the item] soaked.";
		rule fails;
	end if;
	
A showering rule (this is the can't soak something that needs to be dry rule):
	if the shower stand encloses something (called the item) that is needed-dry
	begin;
		say "You don't want to get [the item] soaked.";
		rule fails;
	end if;
	
A showering rule (this is the unconscious woman showers rule):
	if (entering the shower stand and the player is carrying the unconscious pale woman) or the shower stand encloses the unconscious pale woman or (putting the unconscious pale woman on the shower stand)
	begin;
		say "Warm water pours over the helpless woman, ridding some of the filth that cakes her pale skin. Suddenly she coughs, sputters, and her eyes fling open. She looks up at you, frightened, and still shivering uncontrollably.";
		now suppress-printing is true;
		now the pale woman is sickly;
		rule succeeds;
	end if.

A showering rule (this is the conscious woman showers rule):
	if (entering the shower stand and the player is carrying the sickly pale woman) or the shower stand encloses the sickly pale woman or (putting the sickly pale woman on the shower stand)
	begin;
		say "Warm water pours over the helpless woman. She closes her eyes against the stream.";
		now suppress-printing is true;
		rule succeeds;
	end if.

A showering rule (this is the showering yourself rule):
	if entering the shower stand or the player is on the shower stand,
		rule succeeds;
		
A showering rule (this is the successful shower rule):
	let the item be a random thing on the shower stand;
	say "You turn on the shower, drenching [the item].";
	rule succeeds;
	
Section 3 - Showering stuff

Instead of entering the shower stand when the faucet is switched on:
	follow the showering rules;
	if rule failed, stop the action;
	if suppress-printing is false,
		say "You get onto the shower stand and start rinsing yourself off.";
	move the player to the shower stand, without printing a room description;
	now suppress-printing is false;

[Showering something else]
Instead of inserting something (called the item) into the shower stand:
	try putting the item on the shower stand;
	
Instead of switching on the faucet when something (called the item) is on the shower stand:
	follow the showering rules;
	if the rule failed, stop the action;
	if the item is the player and suppress-printing is false,
		say "You turn on the shower and quickly rinse yourself off.";
	now the faucet is switched on;
	now suppress-printing is false;

Instead of putting something on the shower stand when the faucet is switched on:
	follow the showering rules;
	if the rule failed, stop the action;
	move the noun to the shower stand;
	now suppress-printing is false;
	
Section 4 - Persuading woman to take a shower
[When she is unconscious.]
	
Chapter 7 - Capturing the White Crab

Chapter 8 - Fishing

Chapter 9 - Swimming

Instead of swimming when in Breakers:
	try going east;
	
Instead of swimming when in Beneath the Pier:
	try going east;
	
Instead of swimming when in Breakwater or in Breakwater's Edge:
	say "The water is too turbulent here. You would be smashed against the rocks."
	
Instead of swimming when in Tidal Pool:
	try entering the silver pool;
	
Instead of swimming when in the Filthy Shore:
	say "The water is too disgusting here to wade in, let alone swim."
	
Chapter 10 - The Breakwater Moonlit Dinner

Section 1 - Table and ornaments

The dinner table is a supporter. The dinner table is fixed in place.

Instead of examining the dinner table:
	say "An long, oval table covered with an ornate tablecloth. On the table [is-are a list of things on the dinner table]."
	
The candelabra is a lit thing on the dinner table.

The cushioned chair is an enterable supporter. The cushioned chair is scenery.

Section 2 - Seafood

Seafood dinner is a kind of thing. A seafood dinner can be served. A seafood dinner has some text called tasting-it. Understand "food" or "seafood" as seafood dinner.
	
A bowl of seafood bisque is a seafood dinner on the dinner table. Tasting-it of the bowl of seafood bisque is "You take a spoonful of the seafood bisque. It's warm and delicious."

The plate of calamari is a seafood dinner on the dinner table.  Tasting-it of the plate of calamari is "You slip a piece of fried calamari off the plate, dip it in the cocktail sauce, and tuck it in your mouth. Excellent."

The basket of fish-n-chips is a seafood dinner on the dinner table. The printed name of the basket of fish-n-chips is "basket of fish and chips". Tasting-it of the basket of fish-n-chips is "Using the provided fork, you remove a filet of fried fish and some chips from the basket. You sample them, finding them very tasty."

The serving tray is on the dinner table. The printed name of the serving tray is "serving tray stacked with oysters". The description of the serving tray is "A seemingly endless supply of oysters are stacked upon it."

Instead of taking the serving tray:
	try taking the oysters;
	
The oysters are a seafood dinner. The oysters are on the serving tray. Tasting-it of the oysters is "You dip the oyster in cocktail sauce and slide one down your throat." 
	
Instead of taking seafood dinner (called the food) that is not served:
	say "[one of]The lobster slaps your hand with its larger claw[or]A tentacle from the anemone slaps your hand[purely at random]. [one of]'Please, good fellow, wait until you are served[or]'Most impolite, my dear fellow. You should wait until you are served[or]'My dear fellow, please restrain yourself. Wait for your turn[or]'I hope you don't mind if we ask you to wait your turn[purely at random].'";
	
Instead of eating seafood dinner (called the food) that is served:
	say tasting-it of the food;
	say line break;

Section 3 - Dinner companions

The giant lobster is a sentient sea creature.

The enormous sea anemone is a sentient sea creature. 

Rule for writing a paragraph about the giant lobster:
	say "[one of]The scene before you brings you to a standstill. You blink your eyes, rub them, then blink them again.[paragraph break]Apparently[or]Apparently[stopping] someone has set up a dinner party on the breakwater. On one particularly large boulder, a giant lobster and a enormous sea anemone sit on opposite ends of a table filled with food.[paragraph break][if the player is not on the cushioned chair]A fancy, cushioned chair rests empty at the middle of the table[otherwise]You are sitting on a cushioned chair in between the giant lobster and the enormous sea anemone[end if].";
	now the enormous sea anemone is mentioned;
	now the dinner table is mentioned;
	
Section 4 - Setting up

To set up the breakwater dinner:
	move the table to the Breakwater;
	move the giant lobster to the Breakwater;
	move the enormous sea anemone to the Breakwater;
	move the cushioned chair to the Breakwater;
		
Section 5 - Rotating dinners


Section 6 - Dinner conversation

		
Chapter 11 - Scenes

Wide Awake is a scene. Wide Awake begins when Entire Game begins. Wide Awake ends when the player has gotten drowsy.

To decide whether the player has gotten drowsy:
	if the player is hallucinating, decide yes;
	decide no;

Hallucinations is a scene. Hallucinations begins when Wide Awake ends.

Part 4 - Help and hints
	  
When play begins:
     choose row 1 in Table of Basic Help Options;
     change description entry to "'Sea Dreams' is an Interactive Fiction game written by Michael D. Hilborn. Many thanks to Graham Nelson, Emily Short, and the crew of Inform 7 who made this submission possible.[paragraph break]'Sea Dreams' by Michael D. Hilborn is licensed under a Creative Commons Attribution-Noncommercial-Share Alike 3.0 United States License.";
	choose row 4 in Table of Basic Help Options;
     change description entry to "'Sea Dreams' was written by Michael D. Hilborn. Feel free to send comments, criticisms, bug reports, or jokes to mhilborn@biggle2k.com";

After printing the banner text:
	say "[line break][bracket]New players may wish to type 'ABOUT'.[close bracket][paragraph break]";
	
Table of Stuckness Advice (continued)
title	subtable	description	toggle
"Things to try at the beginning of the game"	--	"To get you started, here's a list of commands to try typing at the beginning of the game. Note that you don't necessarily have to use these commands in this order:[paragraph break]INVENTORY[line break]EXAMINE BLANKET[line break]W[line break]EXAMINE DRIFTWOOD[line break]TAKE DRIFTWOOD[line break]NE[line break]NE[line break]W[line break]EXAMINE VERNA[line break]EXAMINE CAMPFIRE[line break]ASK VERNA ABOUT CAMPFIRE[line break]ASK VERNA FOR SMOKE"	--
"As a last resort (*Spoilers*)..."	Table of Hints-Menu	--	--

Table of Hints-Menu
title	subtable	description	toggle
"What am I supposed to do?"	Table of Hints-Main	--	hint toggle rule
"Where can I find Verna?"	Table of Hints-Verna	--	 hint toggle rule
"What does Verna talk about?"	Table of Hints-Verna Talk	--	hint toggle rule
"Verna won't give me a smoke!"	Table of Hints-Smoke	--	hint toggle rule
"How do I set the campfire ablaze?"	Table of Hints-Campfire	--	 hint toggle rule
"What do I do after smoking the cigar?"	Table of Hints-After Cigar	--	 hint toggle rule
"How do I get the net off the pale woman?"	Table of Hints-Net	--	hint toggle rule
"How can I help the pale woman?"	Table of Hints-Helping Woman	--	hint toggle rule

Table of Hints-Main
hint	used
"That's part of the fun--figuring out what you need to do."	a number
"Did you read the introduction?"	--
"You're itching for a smoke and Verna might be able to help you."	--
"The first goal of the game is to find Verna and get a smoke from her."	--
"The overall goal you will learn after smoking the thin cigar."	--
"Are you certain you want to be spoiled?"	--
"Okay. You asked for it: The overall goal of the game is to return the pale woman, the Daughter of the Sea, to the ocean before the storm wipes out the island."	--

Table of Hints-Verna
hint	used
"Again, did you read the introduction?"	a number
"She can be found sitting by her campfire under the boardwalk."	--
"From the Moonlit Beach: GO N. NE. W."	--

Table of Hints-Verna Talk
hint	used
"You can talk to her about a variety of local subjects."	a number
"After she goes into a trance, she won't say very much, so take this opportunity while you can."	--
"Topics that she will respond to include (among others): VERNA, MYSELF, BEACH, WITCH, OCEAN, BOARDWALK, TOWN, MANKIND, SMOKE."	--

Table of Hints-Smoke
hint	used
"Have you tried asking her for a smoke?"	a number
"She'll ask you to get the campfire going again."	--
"Once the campfire is ablaze: ASK VERNA FOR SMOKE"	--
"Then SMOKE CIGAR. SMOKE CIGAR again."	--
"Wow. Head rush!"	--

Table of Hints-Campfire
hint	used
"Try blowing on it."	a number
"Nope. You'll need fuel for the fire."	--
"There is some lying around nearby"	--
"Check the dunes west of the moonlit beach."	--
"You can use the driftwood: PUT WOOD ON FIRE"	--

Table of Hints-After Cigar
hint	used
"Keep exploring."	a number
"You'll find some things have changed."	--
"Examine Verna, for instance. Ominous."	--
"Examine the storm, as another example. Very ominous."	--
"In particular, try find the pale woman who has washed up on shore. That should get you started."	--
"She's on the moonlit beach."	--

Table of Hints-Net
hint	used
"Taking, tugging, or pulling it won't help."	--
"Perhaps it can be cut."	--
"Seen anything that might be useful in cutting the net?"	--
"The knife in the tackle box should do the trick."	--
"Once you have the knife: CUT NET or ATTACK NET"	--

Table of Hints-Helping Woman
hint	used
"First, you need to remove the net."	--
"After the net is removed, examine her."	--
"She's shivering and naked. That's not good for her health."	--
"Is there something nearby that might warm her and wake her?"	--
"(Other than yourself, you naughty person!)"	--
"The warm shower water isn't enough."	--
"How about the blanket?"	--
"PUT BLANKET ON WOMAN"	--
"Hmm. She's still shivering."	--
"Is there something else nearby that might warm her?"	--
"(Other than yourself, you naughty, naughty person!)"	--
"Take her to the campfire."	--
"You'll need to carry her."	--
"Drop all of your possessions, then TAKE WOMAN."	--
"Go to the campfire and PUT WOMAN DOWN."	--
"Once the woman is next to the campfire and shrouded in the blanket, she should wake up."	--






