"Late Train To Nowhere" by "Michael D. Hilborn"

["Late Train To Nowhere" by Michael D. Hilborn is licensed under a Creative Commons Attribution-Noncommercial-Share Alike 3.0 United States License.]

The story title is "Late Train To Nowhere".
The story author is "Michael D. Hilborn".
The story headline is "An Interactive Train Ride".
The story genre is "Fiction".
The story description is "Downtrodden and despondent, you await the commuter rail. It's late as always. Doesn't matter. Nothing matters. When the train finally arrives, you board it without thinking, not really caring that you seem to be the only one to climb onboard."
The story creation year is 2009.

Release along with a solution.
Release along with the source text.

Use no scoring.

Include Modified Help Menu by Biggles.[*Modified version of Basic Help Menu by Emily Short.]

Chapter 1 - Generic stuff

[Herein I set up some basic properties, definitions, and rules.]

Section 1 - 

[There are times when I don't want the NPCs to respond to the PC because the NPC is in the middle of a conversation, usually a monologue of some sort. When an NPC is conversing, then the NPC should deflect 'talking' interactions from the PC. I call these talking interactions person-interaction. Perhaps I should have labeled them as conversation.]
A person can be greeted. A person can be conversing.

Answering someone that something is person-interaction.
Asking someone about something is person-interaction.
Telling someone about something is person-interaction.
Giving something to someone is person-interaction.
Showing something to someone is person-interaction.

[I got tired of typing "sit on seats" in order to sit down, so here's a non-specific "sit" verb that chooses a random support and seats the player on it.]
Sitting is an action applying to nothing.

Understand "sit" or "sit down" as sitting.

Check sitting (this is the need an enterable supporter rule):
	if the player cannot touch an enterable supporter,
		say "There is nothing to sit on." instead.

Check sitting (this is the already sitting rule):
	if the player is on a supporter (called the base),
		say "You are already on [the base]." instead.
		
Carry out sitting (this is the standard sitting rule):
	let the base be a random enterable supporter in the location of the player;
	move the player to the base, without printing a room description;
	
Report sitting (this is the standard report sitting rule):
	say "You sit down."
	
Chapter 2 - Setting up the train

[One of my biggest gripes about Inform is that when you define a room, Inform claims that you can't see it when you try to examine it. For example, if I created a room called "Well" and then typed "X WELL", I'll receive the standard 'you can't see any such thing here' response. The following backdrop, found everywhere, takes care of this conundrum.]
The train is a backdrop. The train is everywhere. The train can be running. The train is running. Understand "car", "passenger car", "cabin", "passenger cabin" as the train. Understand "dining car" as the train when the location is the Dining Car.

Instead of examining the train:
	try looking instead;

[Five train cars, all of them nearly identical in terms of scenery and objects, exist within the game. (I thought of truncating them down to three, but didn't; I defer to the readership on whether this was a wise decision. Here I generate a kind of room called a "train car" and various other kinds to populate the cars.]
A train car is a kind of room. The printed name of a train car is "Passenger Car". The description of a train car is "Row after row of seats flow up and down the cabin, surrounding you as if you drown in waves of plastic and leather. A dirty aisle, leading east and west to separate cars, parts this despondent sea[if the train is running]. Everything gently vibrates as the train continues its journey[end if]."

[Unlike most of the scenery in the train cars, the passenger descriptions vary from car to car, depending on whether they have been examined or not. I created the property "investigated" and the global boolean "passengers-examined" to track when and which passengers are investigated.]
Some passengers are a kind of people. Some passengers can be investigated. Some passengers are usually not investigated. "[if passengers-examined is true]The ghostly passengers pay no notice to your presence[otherwise]Dozens of passengers sit among the seats of the car, quietly assuming their individual lives[end if][if the item described is not investigated]. [one of]There's something unusual about this particular group[or]Something catches your eye about this particular group of passengers[at random][end if]." The description of some passengers is "Quiet, colorless, translucent shades of black and white. They go about their business, some reading, others working, a few dozing, and most simply staring out the windows, watching the scenery go by[age of passengers]." Some passengers are in every train car. Understand "ghosts", "ghostly passengers", "specters" as some passengers.

Passengers-examined is a truth state that varies.

Instead of examining some passengers for the first time:
	say "They go about their business, what you are used to seeing every day on the train. Some read, others work, a few sleep... Except everyone is quiet, even those chatting on the phone, and... there is no color to them. More disturbing yet, you can see [italic type]through[roman type] them, like they're all translucent shades who have emerged from a black and white TV[age of passengers].";
	now passengers-examined is true;
	let the group be random passengers in the location;
	now the group is investigated;
	
After examining some passengers (called the group):
	now the group is investigated;

To say age of passengers:
	say ".[paragraph break]You also notice that [if the location is the fifth passenger car]everyone in this car seems fairly young, teens and children, with no adults around[otherwise if the location is the fourth passenger car]everyone in this car seems younger than you, perhaps by a decade[otherwise if the location is the third passenger car]everyone in this car appears to be about your age[otherwise if the location is the second passenger car]everyone in this car is older than you, possibly by a decade or more[otherwise if the location is the first passenger car]the passengers of this car are extremely elderly[end if]";
	
Instead of showing something to the passengers:
	say "The ghostly passengers do not react to [the noun]."
	
The passing scenery is a kind of backdrop. The passing scenery is in every train car. "A featureless, repetitive tundra barren of life. It churns by the train again and again and again." Understand "rocks", "rock", "tundra" as the passing scenery.

Instead of examining the passing scenery for the first time:
	say "Your heart thumps when you stare out onto the unrecognizable wasteland. It's unlike anything you have ever seen. A barren tundra lies beyond the tracks and if not for the lumps of rock moving past the train, that world outside might as well be a stagnant void.[paragraph break] It takes a few moments, but you realize the pattern of rocks passing by in the foreground... it's repeating every few seconds, like you're watching the same frame of reality pass by again and again.";
	
Some windows are a kind of backdrop. Some windows are in every train car. Understand "window" as windows.

Instead of searching some windows (called the item):
	try examining the item;
	
Instead of examining some windows (called the item):
	let the background be a random passing scenery in the location;
	try examining the background;

The dirty aisle is a kind of backdrop. The dirty aisle is in every train car. The description of the dirty aisle is "Strewn with debris from the footfalls of thousands of passengers." Understand "debris" as the dirty aisle.
	
Some seats are a kind of supporter. Some seats are scenery. Some seats are in every train car. Some seats are enterable. The carrying capacity of some seats is one. The description of some seats are "Shades of gray, unlike the depressing deep blue and maroon that you are used to, yet depressing nonetheless." Understand "seat", "plastic", "leather" as some seats.

Report entering some seats:
	say "You find an empty seat by a window and sit down." instead.
	
Instead of getting off the seats:
	try exiting;
	
Instead exiting when the player is on some seats:
	say "You get up and move into the aisle of the train.";
	move the player to the location, printing an abbreviated room description;
	
[I define the actual train cars here. The first train car is the farthest to the east. The player starts in the middle, the third train car.]
First passenger car is a train car.

Instead of going east when the player is in the first passenger car:
	say "The passenger cars end here. Beyond this door lies the train engine, inaccessible to you."

Second passenger car is a train car. The second passenger car is west of the first passenger car.

Third passenger car is a train car. The third passenger car is west of the second passenger car.

Fourth passenger car is a train car. The fourth passenger car is west of the third passenger car.

Fifth passenger car is a train car. The fifth passenger car is west of the fourth passenger car.

[The Dining Car is its own individual, so I just made it a room.]
The Dining Car is west of the fifth passenger car. The description of the Dining Car is "A long bar dominates the center of this car. Ghostly passengers huddle on stools at the bar or congregate in the booths near the western and eastern exits[if the train is running]. The desolate tundra rolls by the windows[otherwise]. The train is still[end if]."

The bar is scenery in the Dining Car. "The bar itself is ornate, lively. Unlike anything else in this ungodly train. It's lined with stools, upon which sit several morose passengers. The bar's untended, not a barkeep in sight."

The booths are scenery in the Dining Car. The description of the booths is "Semi-circular seats surrounding round tables. They're all filled with the spectral passengers you have come to know."

The ghostly passengers are people in the Dining Car. The ghostly passengers are scenery. The description of the ghostly passengers is "Young and old congregate here, wallowing in ethereal drinks. Some sit on stools at the bar; others congregate around the booths. They don't speak, not to each other, not to themselves." Understand "spectral passengers", "specters", "ghosts" as the ghostly passengers.

The solitary stool is a supporter in the Dining Car. The solitary stool is scenery. The solitary stool is enterable. The carrying capacity of the solitary stool is 1. The description of the solitary stool is "A solitary stool at the bar[if the player is on the solitary stool], on which you sit[end if]. It's centered between your future self and your past self."

The lit cigarette is a thing. The description of the lit cigarette is "A cigarette. You swore you would never smoke those things."

After examining the lit cigarette when your future self can see the player for the first time:
	say "Your future self exhales a cloud of smoke. 'Started smoking these a few years after the divorce. A way of committing slow suicide, I guess.'";
	
The vodka martini is an edible thing. The description of the vodka martini is "A large, chilled martini topped with an olive." Understand "olive" as the vodka martini.

There is an edible thing called a gin-and-tonic. The printed name of the gin-and-tonic is "gin and tonic". The description of the gin-and-tonic is "On the rocks. With a lime." Understand "gin and tonic", "gin", "tonic", "lime", "ice" as the gin-and-tonic.

Instead of drinking the gin-and-tonic:
	say "You sip the gin and tonic only to discover that the glass has magically refilled itself to the brim.";

Dining car tundra is a kind of passing scenery that is in the Dining Car.	

Dining car windows is a kind of windows that is in the Dining Car.

[I needed an exit for the Dining Car, so I placed a room called "End of Line" outside of it. This allows NPCs and the player to exit the room when the train stops.]
End of line is outside of the Dining Car.

Chapter 3 - The player and his possessions

The player is in the third passenger car. The description of the player is "Not much to look at, you're sorry to say. Two day's growth of stubble shadow your chin and cheeks, and you haven't showered or changed in as many days."

When play begins:
	let the seat be random seats in the third passenger car;
	move the player to the seat, without printing a room description;

Your stubble is part of the player. 

Your clothes are part of the player. The description of your clothes is "A blue suit and tie. She bought it for you. She always enjoyed buying you clothes. It was a good thing, too, since you hated purchasing them yourself." Understand "suit", "your suit" as your clothes.

The player is wearing a wedding band. The description of the wedding band is "She slipped this on your finger with the most radiant and beautiful smile you have ever seen. Those green eyes flared with love and--You quickly shut out the memory since you suppose that by the end of the day, you won't be wearing the ring anymore." Understand "ring", "wedding ring" as the wedding band.

Instead of taking off the wedding band:
	say "You tug at it, then let the wedding band be. Not now. The time will come soon enough. Perhaps you'll pawn it."

The player is carrying a ticket. The description of the ticket is "A monthly commuter pass. You show it to the conductor every morning." Understand "pass", "commuter pass" as the ticket.

The player is carrying your briefcase. The briefcase is openable. The briefcase is closed. The description of your briefcase is "Black leather. One of the more expensive items you own. You bought it when you purchased [italic type]her[roman type] engagement ring. Figured you should reward yourself. Now it's a painful reminder of... everything[if the briefcase is open and the briefcase contains something]. In the briefcase [is-are a list of things in the briefcase][end if]."

The laptop is a device in the briefcase. The description of the laptop is "A thin, black computer, a birthday gift from her. It's one of the few things she hasn't asked for in the settlement."

Instead of switching on the laptop for the first time:
	say "It's asleep, so it only takes a moment for the screen to flare to life, but what it displays, in bright red words, is not what you expect:[paragraph break][fixed letter spacing]TIME TO END THIS[variable letter spacing][paragraph break]The computer enters sleep mode again."

Instead of switching on the laptop:
	say "It does not want to come back on."
		
A red folder is in the briefcase. The description is "A red folder[if the red folder encloses something], in which [is-are a list of things in the red folder][end if]." The carrying capacity of the briefcase is four.

Some divorce papers are in the red folder. The description of the divorce papers are "Here they are, all filled out and signed, her elegant signature next to your childlike scribble. After work today, the two of you will present them to the judge and... voilá! Your marriage of ten years, and life as you know it, comes to a bitter end."

A photograph is in the red folder. The description of the photograph is "A family photo. You, her, and your daughter, a little girl who has just turned eight. Your daughter is beautiful--much like her mother, you note bitterly--with her mother's flaming red hair and emerald eyes. The photo was taken for your annual holiday card... one week before your wife broke the news that she wanted a divorce. Nice timing. And the card still went out with the three of you on it." Understand "photo", "picture" as the photograph.

Chapter 4 - The Conductor

The conductor is a person in the fifth passenger car. The conductor is neuter. "Standing by the door at the western end of the car is a conductor." The description of the conductor is "Dressed in a black uniform complete with hat, the conductor rigidly stands before the western door, hands folded behind the small of the back. He... she... [italic type]it[roman type] has no face. No eyes. No nose. No mouth. No features to speak of."

The conductor is wearing a uniform. The description of the uniform is "Black with brass buttons upon the lapels and sleeves. The hat is embroidered with gold trim, which--are you imagining it?--seems to undulate." Understand "buttons", "brass buttons", "gold trim", "trim", "gold", "brass", "lapels", "sleeves", "hat" as the uniform.

Instead of giving something (called the item) to the conductor:
	try showing the item to the conductor;
	
Instead of showing the ticket to the conductor:
	say "The conductor reaches up with a hand so thin and pale you can see the shadow of bones beneath its flesh. When the conductor grasps the ticket, its skin brushes yours, and your own flesh recoils from its cold touch. The conductor holds the card aloft in front of its eyeless face, and inspects it.";
	move the ticket to the conductor;
	the conductor returns the ticket in one turn from now;
	
At the time when the conductor returns the ticket:
	if the conductor can see the player
	begin;
		say "The conductor hands the ticket back to you. [italic type]'Thisss isss a commuter passs,'[roman type] a quiet voice speaks. [italic type]'To enter the dining car, you mussst have a dining passs.'[roman type][line break]";
		move the ticket to the player;	
	end if.

Instead of going when the conductor is carrying the ticket:
	say "You're not leaving your ticket in the hands of the conductor. You paid an arm and a leg for that monthly pass."
		
Instead of telling the conductor about something:
	try asking the conductor about it. 
	
Instead of answering the conductor that something:
	try asking the noun about it.
	
Instead of asking the conductor about something:
	say "Silence. Terrible, deafening silence."
	
Instead of kissing the conductor:
	say "Embracing the eerie conductor is the last thought on your mind."[*Yes, I know. Technically not true if the player typed the command.]

Instead of attacking the conductor:
	say "The thought of what this conductor might be able to do to you stills your hand."
	
Instead of going west when in the fifth passenger car:
	say "Before you can enter the door, the conductor holds up a hand so thin and pale you can see the shadow of bones beneath its flesh. A quiet voice speaks, [italic type]'You mussst have a dining passs.'[roman type][line break]"

Chapter 5 - Future self

[The player encounters an elderly version of himself.]

Section 1 - Basic description and possessions

Your future self is a man in the first passenger car. Your future self can be seated or standing. Your future self is seated. Your future self can be asleep or alert. Your future self is asleep. Your future self can be recognized. Your future self is not recognized. "One person stands out from the rest[if passengers-examined is true], mostly because he's not translucent[end if]--an elderly gentleman wearing a suit similar to yours[if your future self is asleep]. He's also sound asleep[end if]." The description of your future self is "[future self's description]." Understand "person", "man", "old man", "gentleman", "elderly gentleman" as your future self.

To say future self's description:
	if your future self is not recognized
	begin;
		say "An elderly gentleman, probably in his early eighties, with thin, white hair and oddly familiar features. His suit is identical to yours, except much more frayed and faded[if your future self is asleep]. He's sound asleep[end if]";
	otherwise;
		say "A future version of yourself, elderly and gray, and much thinner. He wears a suit identical to yours, only frayed and faded";
	end if.
	
Your future self is carrying a dining pass. The description of the dining pass is "As far as you can tell, it looks identical to the commuter pass."

Your future self is wearing a watch. The description of the watch is "Gold. Analog. Scratched and worn."

After examining the watch when your future self is alert for the first time:
	say "The old man taps the watch. 'You buy this at the same damn shop where you pawn off your wedding band. It'll happen in a few weeks. Or maybe it won't if we play our cards right.'";
	
Your future self is wearing the old man's suit. The description of the old man's suit is "It's identical to yours, except faded and frayed." Understand "frayed tie" as the old man's suit.

After examining the old man's suit when your future self is alert for the first time:
	say "'Same suit that she bought us, all those years ago,' the old man says, straightening the tie. 'Never bothered to purchase a new one. Simply couldn't afford it, not with all those years of child support.'"

Section 2 - Greeting your future self

Instead of entering some seats (called the item) when in the first passenger car and your future self is seated:
	say "You take a seat next to the old man.";
	if Invitation To Sit is happening
	begin;
		say line break;
		say "'Took you long enough.' He checks his watch. 'It won't be long now. The train should stop and our oblivious, little friend will climb on board. In the meantime, you and I have much to discuss.'";
	end if;
	move the player to the item, without printing a room description;
	
Instead of person-interaction when (the noun is your future self or the second noun is your future self) and your future self is asleep:
	say "You will need to wake him up, first."
	
Instead of waking your future self for the first time:
	say "The old man starts awake, faces you, eyes at first a glower, then settling into annoyance. 'Ah, so it's you,' he says. He checks his watch. 'About time you got here. Don't recognize me, do you? Not surprised. You're so overwhelmed with life right now that you wouldn't recognize yourself even if I came up and slapped you in the face.'[paragraph break]It's those last words that trigger realization: You're staring at yourself--an older version of yourself--but yourself, nonetheless.";
	now your future self is greeted;
	now your future self is alert;
	now your future self is recognized;
	
Section 3 - Invitation to sit

Invitation To Sit is a scene. Invitation to Sit begins when your future self is alert. Invitation to sit ends when the player is on a random seats in the first passenger car.

Every turn when your future self can see the player during Invitation to Sit:
	if your future self is conversing
	begin;
		now your future self is not conversing;
	otherwise;
		say "[one of]'Please, have a seat,'[or]'Don't just stand there puttering about. Have a seat,'[or]'Sit down for a moment,'[or]The elderly man taps the seat next to him. 'Please, sit, there's much to discuss,'[at random] your future self says.";
	end if.
	
Instead of person-interaction when (the noun is your future self or the second noun is your future self) during Invitation To Sit:
	say "'If you sit your ass down, I'll explain,' your future self grumbles.";
	now your future self is conversing;

Section 4 - Monologue 
	
Waiting for First Stop is a scene. Waiting for First Stop begins when Invitation To Sit ends. Waiting for First Stop ends when your future self is standing.

Instead of person-interaction when (the noun is your future self or the second noun is your future self) during Waiting for First Stop:
	say "[one of]'It's not polite to interrupt your elders,'[or]'I'm talking, you're listening,'[at random] your future self snaps.";
	
Before exiting during Waiting For First Stop:
	say "Your future self grabs your arm. 'Hold on, now, I'm not through just yet. Sit and listen.'" instead;

Every turn during Waiting for First Stop:
	if the number of filled rows in the Table of Future Self Monologue is zero
	begin;
		say "The train shudders to a halt. 'That should be the boy getting onboard,' he says, excitedly. 'Now's our chance. Time to end this.' He gets up and strides down the aisle to the west. 'Come on. The fool will most likely be in the dining car celebrating what he thinks is his good fortune.'";
		now your future self is standing;
		now the train is not running;
	otherwise;
		repeat through the Table of Future Self Monologue
		begin;
			say "[comment entry][line break]";
			blank out the whole row;
			rule succeeds;
		end repeat;
	end if.
	
Table of Future Self Monologue
Comment
"'Life didn't get better, that's it in a nutshell,' your future self says, somberly. 'You... I... [italic type]we[roman type] never recovered from that damn divorce. Made us miserable for the rest of our lives.'"
"'She was selfish, devoid of empathy, single-minded, and we knew it,' your future self continues. 'Yet we were fools and married her anyway. We were desperate, ready to settle down, and damn it if she didn't have a wonderful family. Don't look away. You know it's true.'"
"'Ten years into the marriage, she decides she's had enough,' your future self growls. 'It ain't doing it for her, anymore. So the bitch quits, takes our daughter, and walks out. And we're left with the bill.'"

Heading For Dining Car is a scene. Heading for Dining Car begins when Waiting For First Stop ends. Heading For Dining Car ends when your future self is in the fifth passenger car.

Every turn during Heading For Dining Car:
	if the time since Heading For Dining Car began is two minutes
	begin;
		say "The train jolts forward and continues its journey.";
		now the train is running;
	end if;
	let the way be the best route from the location of your future self to the fifth passenger car;
	if your future self can see the player,
		say "'Come along, we need to get to the dining car,' your future self says.";	
	try your future self going the way;

Section 5 - Encounter with the conductor			

Approaching the Conductor is a scene. Approaching the Conductor begins when the player is in the fifth passenger car and your future self is in the fifth passenger car. Approaching the Conductor ends when the player is in the dining car. 

When Approaching the Conductor begins:
	say "Your future self holds up a dining pass and shows it to the conductor. 'For me and my friend,' your future self explains. The conductor shakes its head and a quiet voice says, [italic type]'Each passsenger must have his own passs.[roman type]'[line break]"

Understand "dining pass" or "pass" as "[dining-pass-topic]".

Instead of asking your future self about "[dining-pass-topic]" during Approaching the Conductor:
	try taking the dining pass;
	
Instead of person-interaction when (the noun is your future self or the second noun is your future self) during Approaching the Conductor:
	say "'We can talk when we get into the dining car. Let's just get past this foul conductor.'";

Instead of taking the dining pass when your future self is carrying the dining pass during Approaching the Conductor:
	try asking your future self for the dining pass.

Persuasion rule for asking your future self to try giving the dining pass to the player:
	persuasion succeeds.
	
Instead of your future self giving the dining pass to the player:
	try asking your future self for the dining pass.
	
Unsuccessful attempt by your future self giving the dining pass to the player:
	do nothing;
		
Instead of asking your future self for the dining pass when your future self is carrying the dining pass during Approaching the Conductor:
	if the conductor is not carrying the ticket
	begin;
		say "'That damn conductor will notice me passing the card to you,' your future self mutters. 'You'll need to distract it.'[line break]";
	otherwise;
		say "While the conductor inspects your ticket, your future self slips you his dining pass.";
		move the dining pass to the player;
	end if.
	
Instead of showing the dining pass to the conductor:
	say "The conductor accepts the pass in its chilling grasp. It inspects the pass, nods, and opens the door to the dining car. You [if the location of your future self is the location of the player]and your future self [end if]enter.";
	if the Dining car is unvisited
	begin;
		move your future self to the dining car;
		your future self seeks out your past self in zero turns from now;
	end if;
	move the player to the dining car;

At the time when your future self seeks out your past self:
	say "Your future self barges through the dining car. 'Where is the damn fool? I know he's here. Ah, there.' He storms over to another passenger at the bar and seats himself two stools away. He motions you to take the middle stool, but for the moment your dumbstruck. The other passenger--he's yet a third version of you, only a decade or so younger than you.";
	now your future self is seated;
	move your past self to the dining car;
	
Chapter 6 - Your past self

[The player's past self starts out in a jolly, good ol' mood. After all, he's about to ask his girlfriend to marry him and she's certain to say "yes". It's up the player and his future self to wipe that happiness away.]
Mood is a kind of value. The moods are utterly depressed, sad, somber, happy, and joyous.

Your past self is a man. Your past self has a mood. Your past self is joyous. "At the bar sits a younger version of yourself." Understand "boy" as your past self. The description of your past self is "You, only younger. A little over ten years younger, to be precise. He's a little disheveled. Clearly, she hasn't started dressing him yet.[paragraph break]He appears [mood of your past self]." Understand "fool", "fool boy", "boy", "young man", "younger self" as your past self.

Your past self is carrying an engagement ring. The description of the engagement ring is "A beautiful, silver ring embedded with bright diamonds."

Your past self is carrying a cold beer. The description of the cold beer is "A pale ale. You remember that it was once your favorite, but you've switched to gin and tonics now."

After examining the engagement ring when your future self can see your past self for the first time:
	say "'Most expensive piece of shit you ever bought,' your future self scowls. 'Aside from that car.'"

After examining your past self when your future self can see your past self for the first time:
	say "'At least he's not wearing that damnable blue suit and tie,' your future self says.";
	
Chapter 7 - The conversation at the bar

Introducing Yourself is a scene. Introducing Yourself begins when the location of the player is the location of your future self and the location of your future self is the location of your past self. Introducing Yourself ends when your past self is greeted.

When Introducing Yourself  begins:
	say "Your future self confirms your suspicions. 'Judging by your look, you've figured it out, but nevertheless--' He points back and forth between you and your younger doppelgänger. 'Past self, meet present self. Present self, meet past self. We all have a lot to talk about.' He nudges you. 'Go ahead. Ask the fool boy about his ring.'[line break]";
	now your past self is greeted;
	
Instead of person-interaction when (the noun is your future self or the second noun is your future self) or (the noun is your past self or the second noun is your past self) during Introducing Yourself:
	say "Your future self slaps your arm. 'You can talk as soon as I'm done with introductions.'";

Talking To Yourself is a scene. Talking To Yourself begins when Introducing Yourself ends.

[topics]
Understand "engagement ring", "ring", "the ring", "his ring" as "[ring-topic]".

Instead of telling your future self about something:
	say "'Don't tell me,' your future self snarls. 'Tell him.' He jabs a finger at your younger self."

Instead of telling your past self about something when the mood of your past self is utterly depressed:
	say "'Enough already!' your past self cries. 'You've made your point. I don't want to hear anymore.'";

Instead of asking your past self about "[ring-topic]":
	if the mood of your past self is less than somber
	begin;
		say "'I don't think there is any point in discussing the ring,' he says, somberly. 'Not certain what I'm going to do with it now.'";
	otherwise;
		say "'The ring?' your past self says, adamantly, bringing out a shiny engagement ring. 'Here it is. Tomorrow night, on Valentine's Day, I'm going to ask my beloved to marry me.'";
		say line break;
		say "'A fool's errand, boy,' says your elderly counterpart. 'You want to know what happens to that ring? She sells it on an online auction site after your divorce is final.' Your future self appraises you. 'Go on. Tell the boy about the marriage, the divorce, our daughter.'";
	end if.

Instead of asking your future self about "[ring-topic]":
	say "'Which one? The wedding band your wearing or the engagement ring that fool boy is carrying with him? Doesn't matter. Both end up being sold after the divorce.'"

Understand "divorce", "the divorce" as "[divorce-topic]".

Instead of asking your past self about "[divorce-topic]":
	if the mood of your past self is less than somber
	begin;
		say "'I never really thought about divorce until now,' your past self admits, sadly.";
		say line break;
		say "'Keep thinking about it, boy,' your future self chimes in. 'It's going to happen, whether you like it or not.'";
	otherwise;
		say "'Divorce? Not a chance! This girl loves me. And she swears she will never, ever get a divorce.'";
		say line break;
		say "'She's a fucking liar,' your future self nearly yells. 'Come on, you fool. I know you're smarter than this. You suspect she'll bail on the marriage if need be. I know you do. I remember.'";
	end if.

Instead of telling your past self about "[divorce-topic]":
	say "'Does it really happen?' he asks after you mention you get divorced.";
	say line break;
	say "'Yes, it really happens,' your future self says. 'And it's messy, too. Never bothered to sign a pre-nup, so all our assets got divided. We lost a whole lot of what we earned. And we never recovered, financially or emotionally.'";
	if past self knows about divorce is not true
	begin;
		depress your past self;
		now past self knows about divorce is true;
	end if;
	
Instead of asking your future self about "[divorce-topic]":
	say "'I think I told you already, we never get over it. It haunts us for the rest of our life.'"

Instead of asking your past self about "girlfriend/wife":
	if the mood of your past self is less than somber
	begin;	
		say "'I'm... I'm... not certain what to think of her, anymore,' your past self says, bitterly.";
		say line break;
		say "'You know what to think of her. She's selfish and single-minded. So single-minded, she ain't even aware of it. Blessedly innocent of her failings. Let me assure you, she'll do what's best for her, not for you, and deep in your heart, you suspect that.'";
		say line break;
		say "Your past self doesn't respond, but nods.";
	otherwise;
		say "'She's wonderful. Beautiful, intelligent, completely in love with me--'";
		say paragraph break;
		say "'For now,' the elderly man interrupts. 'She'll fall out of love when it suits her, which is about eight years down the road for you. Oh, she'll hang in there for another two years, but that's about it. Then she'll have that affair.' He looks at you. 'Oh, yeah, you don't know about that. Yet. She'll admit it to you in a few years from now.'";
	end if.

Instead of asking your future self about "marriage/wedding":
	say "'I admit it was a wonderful evening, one that I unfortunately can't forget. Led to our damn downfall.'"

Instead of telling your past self about "marriage":
	say "'My God,' your past self whispers into his drink. 'Was it really that loveless?'";
	say line break;
	say "'What did you expect? It's not love that's driving you to marry this girl. It's desperation and fear, fear that you'll never find the right woman. So you settle for her. And, ultimately, she picks up on that fact.'";
	if past self knows about marriage is not true
	begin;
		depress your past self;
		now past self knows about marriage is true;
	end if;
	
Instead of asking your past self about "marriage/wedding":
	if the mood of your past self is less than somber
	begin;	
		say "'I think I may be having second thoughts,' your past self admits, despondently.";
		say line break;
		say "'Good,' your future self barks. 'Save us all a lot of trouble if you don't go through with it.'";
	otherwise;
		say "'Maybe a year from tomorrow,' your past self grins. 'A year after I propose. Then we can have the wedding on her favorite holiday.'";
		say line break;
		say "'That's how it works out, not that you have much choice in the matter,' your future self says. 'She'll run the show, and you'll dutifully follow along like a fucking puppy. It's how it always works with her and you... us... Fuck.'";
	end if.
	
Instead of asking your future self about "train":
	say "'Don't know much about it,' grumbles the old man. 'But it'll give us a second chance, should we wish to take it.'"
	
Instead of asking your past self about "train":
	if the mood of your past self is less than somber
	begin;	
		say "'Wish I had never gotten onboard. I don't know what to think about any of this.'";
		say line break;
		say "'Break off the damn marriage, and you'll be thankful,' claims your future self. 'We'll all be thankful.'";
	otherwise;
		say "'I'm not certain how I got on here,' your past self admits. 'I thought it was the usual train. Seems nice, though.'";
		say line break;
		say "'You got on because you were so wrapped up in yourself,' your future self explains. 'You're so full of joy and expectation that you were oblivious to what was going on around you. That's how the train gets you. When you're not paying attention.'";
	end if.

Instead of asking your future self about "daughter":
	say "'Don't like to speak about that,' he mutters. 'Fell apart, we did, as she grew older. Not our fault, really. Her mother kept her away from us as best she could.'"

Instead of telling your past self about "daughter":
	say "'Our daughter never speaks to me?' your past self asks. 'To us, I mean? Why?'";
	say line break;
	say "Your elder self furrows his brow. 'It's our damn wife's fault. After the divorce, she gets custody and spits venom about us in our daughter's ear. That, and we hardly ever get to see our daughter. Her mother makes certain of that.'";
	if past self knows about daughter is not true
	begin;
		depress your past self;
		now past self knows about daughter is true;
	end if;
	
Instead of asking your past self about "daughter":
	if the mood of your past self is less than somber
	begin;	
		say "'From what you and the old fellow tell me, things don't work out for my daughter and I.'";
		say line break;
		say "Your future self grows compassionate. 'It's not our fault, boy, that's the honest truth. The rest of our mistakes--yes, we're to blame--but our daughter growing apart from us... That's not our fault. It's her mother's doing, simple as that.'";
	otherwise;
		say "'You say I will have a daughter?' your past self exclaims. 'That's wonderful news.'";
		say line break;
		say "'It doesn't work out,' your future self says. 'After she leaves, your wife keeps your daughter away from you. Feeds her with all kinds of false information as she gets older. We hardly get to see her. Of course, we have to pay for her. Child support. College. All of that. And what do we get from it? Nothing but bills and destitution.'";
	end if.

Instead of giving something to your future self:
	try showing the noun to your future self;

Instead of giving something to your past:
	try showing the noun to your past self;
	
Instead of showing the divorce papers to your past self for the first time:
	say "You hand over the divorce papers to your younger self, who reluctantly accepts them. 'Dear God,' he says, flipping through the documents. 'Can these be real?'";
	say line break;
	say "'Absolutely,' your future self says. 'Signed, sealed, and delivering our doom.'";
	if past self knows about papers is not true
	begin;
		depress your past self;
		now past self knows about papers is true;
	end if;

Instead of showing the divorce papers to your future self:
	say "Your future self waves them away. 'Please. I signed them once too many times.'"
	
Instead of showing the photograph to your future self:
	say "'Lovely. You burn that photo a few weeks from now.'"

Understand "drinks/drink/martini/gin/tonic" or "vodka martini" or "gin and tonic" as "[drink-topic]".

Instead of asking your future self about "[drink-topic]":
	say "'That's how it works here. Your favorite drink simply appears in your hand. Cigarettes, too, if you smoke them.'"

Instead of asking your past self about "[drink-topic]":
	say "'I don't know where it came from,' your past self admits, staring at the cold beer. 'It just appeared in my hand.'";

Instead of asking your future self for the lit cigarette:
	say "'You won't start smoking for another few years.'";

Instead of asking your future self about "cigarette":
	say "'Can't live without them. Filthy habit, but hey, it takes your mind off things. Calms you down.'";
	
[Sadly, to get the best ending of the game, you need to completely depress your past self. Here's where the magic happens.]

Past self knows about divorce is a truth state that varies.
Past self knows about marriage is a truth state that varies.
Past self knows about daughter is a truth state that varies.
Past self knows about papers is a truth state that varies.
		
To depress your past self:
	if your past self is not utterly depressed
	begin;
		change the mood of your past self to the mood before the mood of your past self;
		say line break;
		if your past self is happy
		begin;
			say "Your past self does not appear to be as joyous as he was a few moments ago.";
		otherwise if your past self is somber;
		say "The joy and happiness of his future engagement fades from your younger self.";
		otherwise if your past self is sad;
			say "Your past self sighs despondently and rubs his forehead, a sure sign he's not feeling well.";
		otherwise;
			say "You don't think your past self could get any more depressed.";
		end if;
	end if;
		
Chapter 8 - Getting off the train

Train Running is a recurring scene. 
Train at End of Line is a recurring scene.

Train Running begins when Introducing Yourself ends. Train Running begins when Train at End of Line ends. Train Running ends when Train at End of Line begins.

Train at End of Line begins when the time since Train Running began is ten minutes. Train at End of Line ends when the time since Train at End of Line began is two minutes.

When Train at End of Line begins:
	now the train is not running;
	if your future self can see the player
	begin;
		say "The train shudders to a halt and your future self directs a somber gaze at you. 'Here's our chance. One of us can leave the train now, but it's up to you. Which one will it be? The boy, you, or me[if the mood of your past self is utterly depressed]? I think the boy understands what happens to us[otherwise]? I don't think it really matters. The boy still thinks everything can be made right[end if]. As for you and me--' He shrugs. 'Lord knows if we've changed. Lord knows if we [italic type]can[roman type].'";
	otherwise;
		say "The train shudders to a halt.";
	end if.
	
When Train at End of Line ends:
	now the train is running;
	say "The train starts up again.";
	if your future self can see the player
	begin;
		say  "'Missed our chance for now,' says your future self. 'Don't worry. The train will stop again shortly.'";
	end if.

Instead of going west when the player is in the Dining Car:
	try going outside;
	
Instead of going outside when the player is in the Dining Car during Train Running:
	say "Before you can open the door to the outside of the train, a quiet voice whispers, [italic type]'Only when the train has ssstopped can you leave usss.'";
	
[Persuading other people to leave]
Definition: A person is a doppelganger if it is your past self or it is your future self.

Going west is leaving.
Going outside is leaving.
Exiting is leaving.

Understand "get off of train", "exit train", "leave", "get off train", "disembark" as exiting when in the Dining Car.

Persuasion rule for asking a doppelganger to try leaving during Train at End of Line:
	persuasion succeeds.
	
Unsuccessful attempt by a doppelganger leaving during Train Running:
	say "The train needs to stop before [the person asked] can leave.";
	
To say separator:
	say paragraph break;
	say "[bold type]   ***[roman type]";
	say paragraph break;
	
["Win" conditions]
Instead of going outside when the player is in the Dining Car during Train at End of Line:
	say "'As you leave the train, your future self calls after you: 'You can't change anything. It's all been set in motion. Let the boy go. He still has a choice. We don't!' You ignore him. 'Please!' he cries, running after you. 'Listen to--'";
	say separator;
	say "You step onto the platform of your destination. While your fellow passengers disembark around you, you stop and stare up into the grey sky. Snow descends, dancing in the frost of your sigh. Another day, another dollar, another divorce. You wonder how many other couples will be in the courtroom. You sigh again. It's going to be Hell. The rest of your life is going to be Hell. Might as well get used to it. At least the train was on time.";	
	end the game saying "Nothing changes";

After your future self going outside during Train at End of Line:
	say "Your future self can't conceal his shock or his disappointment. 'If you insist,' he says, getting up from his stool. 'Let bygones be bygones and all of that, I suppose. Can't say that I agree.' He approaches the door of the train, but just before he leaves, he turns to you and your younger self. 'You understand it ends now. All of it. And not happily.' He sighs, and descends down the stairs.";
	say separator;
	say "You step onto the platform of your destination. While your fellow passengers disembark around you, you stop and stare up into the grey sky. Jesus Christ, how long have you been doing this same thing morning after morning? Thirty, forty years? Nothing's changed since the divorce. You wanted to retire, but the child support and all of the expenses of a long lost marriage prevented it.";
	say line break;
	say "The train rolls away. Odd you don't remember much of the trip. Then again, your damn mind's been slipping away from you recently. Not that it matters. You don't have any family. No real friends. Just a tiresome, soul-sucking job.";
	say line break;
	say "[italic type]'TIME TO END THIS'[roman type]";
	say paragraph break;
	say "You're not certain whence the quiet voice originates, but the voice makes sense, so when the next train rolls into the station, you step in front of it.";
	end the game saying "You have ended it"; 

To say disembarkation:
	say "You step onto the platform of your destination. While your fellow passengers disembark around you, you stop and stare up into the grey sky.";
	say line break;
	say "You've been having doubts about the engagement, serious doubts, and for some reason, those qualms grew stronger during the train ride into work. You pull out the engagement ring you bought a month ago. It sparkles despite the lack of sun.";
	say line break;
	say "Do you really love this woman? Are you really ready to risk the rest of your life with her?";
	say line break;

After your past self going outside during Train at End of Line:
	if the mood of your past self is utterly depressed
	begin;
		say "'Well,' your younger self says, as he gets off his stool, 'you two have certainly given me something to think about. I'm not sure what I have to do.'";
		say line break;
		say "'I think you do know,' your elder self says, solemnly. 'It's for the better. You just have to trust us.'";
		say line break;
		say "Your younger self nods and heads for the door.";
		say line break;
		say "'There he goes,' your elder self whispers, turning back to the bar. 'That leaves you and me here, I guess, at this damn bar on this damn train. I suppose it won't be too bad. Can't be any worse than how we were living before.'";
		say line break;
		say "You agree and to your small comfort, another  gin and tonic has appeared before you. You take a sip. Delicious. And out of the corner of your eye, you see your younger self disappear.";
		say separator;
		say disembarkation;
		say "You're not surprised by your answer, though you are surprised you accept it. You won't be needing the engagement ring for awhile--certainly not for her. So you pocket the ring and leave the platform, humming contentedly to yourself. Life won't be what you anticipated even an hour ago, but it'll be a good life, and one to look forward to.";
		end the game saying "You have changed your destiny";
	otherwise;
		say "'Well, gentlemen, this is where I get off.' Your past self removes himself from his stool.";
		say line break;
		say "'Dammit!' your future self snarls. 'You're still going to do it. I can tell. You're still going to marry her. I'm warning you--'";
		say line break;
		say "Your younger self shrugs. 'Yes, I'm going to marry her[if the mood of your past self is less than joyous]. Despite what you've told me, I think things can change[otherwise]. I see no reason not to[end if].' He heads for the exit.";
		say line break;
		say "The old man nearly spills off his stool. 'No, wait! Listen to us. This can change! I swear it. If you just--' But your younger self disappears.";
		say separator;
		say disembarkation;
		say "You know the answers to the questions, but you don't like to think about them. It's time to get married, and that's that, even if the situation isn't ideal. So you pocket the ring and leave the platform, thinking about tomorrow night when you'll kneel before her, make your proposal, and change your life forever.";
		end the game saying "You get married and then divorced";
	end if.

Chapter 9 - Plot and atmosphere

When play begins:
	say "The morning commute. More depressing than usual with everything you need to do today. You barely notice the train pulling up to the station, late as always, and, without thinking, you trudge into the car, not really caring that you seem to be the only one to climb aboard.[paragraph break]Ignoring the other passengers already onboard, you take a seat, stare straight ahead, and wait for the conductor to inspect your ticket. It takes twenty minutes or so of being lost in your own, morose thoughts before you realize that the conductor may not be stopping by...";

When play begins:
	let the group be a random passengers in the third passenger car;
	now the group is investigated;
				
Every turn when the location of the player is the Dining Car during Talking To Yourself:
	if your future self is not carrying the vodka martini
	begin;
		say "A vodka martini materializes before your future self. 'Ah, wonderful,' your future self comments. He lifts the martini and sips it.";
		move the vodka martini to your future self;
	otherwise if your future self is not carrying the lit cigarette;
		say "You notice that a lit cigarette has mysteriously appeared between the fingers of your future self. He takes a heavy drag and exhales.";
		move the lit cigarette to your future self;
	otherwise if the gin-and-tonic is off-stage;
		say "A gin and tonic materializes in your hand. First the gin appears, complemented by the tonic, followed by the ice and glass, then at last topped with a lime.";
		move the gin-and-tonic to the player;
	otherwise if a random chance of 1 in 5 succeeds;
		say "[one of]Your younger self sips his beer[or]Your future self nurses his martini[or]Your future self taps his cigarette. Ash falls to the bar and disappears into thin air[or]Your future self takes a heavy drag on his cigarette[or]Your younger self glances around the cabin, his expression [mood of your past self][at random].";
	end if.
	
Chapter 10 - Hints and help

When play begins:
     choose row 1 in Table of Basic Help Options;
     change description entry to "'Late Train To Nowhere' is an Interactive Fiction game written by Michael D. Hilborn. Many thanks to Graham Nelson, Emily Short, and the crew of Inform 7 who made this rather despondent tale possible.[paragraph break]'Late Train To Nowhere' by Michael D. Hilborn is licensed under a Creative Commons Attribution-Noncommercial-Share Alike 3.0 United States License.";
	choose row 4 in Table of Basic Help Options;
     change description entry to "'Late Train To Nowhere' was written by Michael D. Hilborn. Feel free to send comments, criticisms, bug reports, or jokes to mhilborn@biggle2k.com";

After printing the banner text:
	say "[line break][bracket]New players may wish to type 'ABOUT'.[close bracket][paragraph break]";
	
Table of Stuckness Advice (continued)
title	subtable	description	toggle
"Things to try at the beginning of the game"	--	"To get you started, here's a list of commands to try typing at the beginning of the game. Note that you don't necessarily have to use these commands in this order:[paragraph break]EXAMINE ME[line break]INVENTORY[line break]EXAMINE TICKET[line break]EXAMINE BRIEFCASE[line break]OPEN BRIEFCASE[line break]EXAMINE LAPTOP[line break]TURN LAPTOP ON[line break]EXAMINE FOLDER[line break]EXAMINE PAPERS[line break]EXAMINE PHOTOGRAPH[line break]EXAMINE PASSENGERS[line break]GET UP"	--
"As a last resort (*Spoilers*)..."	Table of Hints-Menu	--	--

Table of Hints-Menu
title	subtable	description	toggle
"What am I supposed to do?"	Table of Hints-Main	--	hint toggle rule
"Are the items in the briefcase of any importance?"	Table of Hints-Briefcase	--	hint toggle rule
"Can I turn the laptop back on?"	Table of Hints-laptop	--	hint toggle rule
"What's with the passengers?"	Table of Hints-Passengers	--	hint toggle rule
"What's going on with this train?"	Table of Hints-Train	--	hint toggle rule
"What can I do with the sleeping old man?"	Table of Hints-Old Man	--	hint toggle rule
"I can't get to the engine of the train."	Table of Hints-Engine	--	hint toggle rule
"I can't get past the conductor."	Table of Hints-Conductor	--	hint toggle rule
"What do I do in the dining car?"	Table of Hints-Dining	--	hint toggle rule
"Okay. Just how do I get off this darn train?"	Table of Hints-End Game	--	hint toggle rule

Table of Hints-Template
hint	used
"[bracket]These hints will be completed later.[close bracket]"	a number

Table of Hints-Main
hint	used
"That's part of the fun--figuring out what you need to do."	a number
"But if you insist: What does one normally do after getting on a train?"	--
"You ride it for awhile, then get off at your destination."	--
"The ultimate goal of the game is to get yourself off the train."	--
"Now... which version of yourself leaves the train... well, that's another hint altogether."	--

Table of Hints-Briefcase
hint	used
"Yes."	a number
"Examine all of the contents."	--
"They give you background to the story."	--
"And the divorce papers can come in handy later."	--

Table of Hints-Laptop
hint	used
"No."	a number

Table of Hints-Passengers
hint	used
"Have you examined each set of passengers in each car?"	a number
"The passengers seem to be aging as you walk from west to east."	--
"Basically, the passengers give you a clue to the nature of the train."	--

Table of Hints-Train
hint	used
"Have you examined the passengers?"	a number
"Have you examined the windows?"	--
"Have you met the conductor?"	--
"Whatever this train is, you may not want to be on it. Best to try to get off."	--

Table of Hints-Old Man
hint	used
"Try WAKE OLD MAN."	a number
"He'll invite you to sit. Take him up on his offer."	--
"SIT and WAIT and listen to what he has to say."	--
"Then GET UP and follow him WEST toward the other end of the train."	--

Table of Hints-Engine
hint	used
"That's right, you can't."	--

Table of Hints-Conductor
hint	used
"What does one normally do with a conductor?"	a number
"SHOW THE TICKET TO THE CONDUCTOR"	--
"Hmmm. He's looking for a dining pass. Have you seen one somewhere?"	--
"The old man has one, and has already shown it to the conductor."	--
"Ask the old man to give you the pass: OLD MAN, GIVE ME THE DINING PASS."	--
"Except you want to distract the conductor, first."	--
"While the conductor is inspecting your ticket, ask the old man for the pass. Then show the pass to the conductor."	--
"SHOW TICKET TO CONDUCTOR. OLD MAN, GIVE ME THE DINING PASS. SHOW DINING PASS TO CONDUCTOR."	--
"Don't lose the dining pass! You may not be able to get back into the dining car."	--

Table of Hints-Dining
hint	used
"Chat with the old man and your younger self."	a number
"But what to chat about?"	--
"The old man gives you a hint during your introduction."	--
"ASK YONGER SELF ABOUT RING."	--
"You should also tell your younger self about your marriage, divorce, and daughter."	--
"TELL YOUNGER SELF ABOUT MARRIAGE. TELL YOUNGER SELF ABOUT DIVORCE. TELL YOUNGER SELF ABOUT DAUGHTER."	--
"You'll note your younger self gets sadder and sadder. This is important."	--
"You can also ask your younger self about the same topics, as well as talk to the old man. They have plenty to say about your history and how you got to where you are."	--

Table of Hints-End Game
hint	used
"Once you are in the dining car, wait until the train comes to a stop. You can go WEST or GO OUT."	a number
"Not satisfied with the ending?"	--
"That's okay. There are three more."	--
"When the train is stopped, listen to what the old man says."	--
"You can instruct either him to leave or your past self to leave."	--
"Try YOUNGER SELF, GO OUT or FUTURE SELF, GO OUT"	--
"Still not satisfied with the endings?"	--
"You need to thoroughly convince your younger self that he needs to change his life."	--
"You can do that by telling him about your marriage, divorce, and daughter."	--
"After that, really hammer it home: SHOW DIVORCE PAPERS TO YOUNGER SELF"	--
"After being subjected to so much misery, he will change his life."	--
"Still not satisfied with the ending?"	--
"Sorry, that's all we got."	--
