"Octopus's Garden" by "Michael D. Hilborn"

["Octopus's Garden" by Michael D. Hilborn is licensed under a Creative Commons Attribution-Noncommercial-Share Alike 3.0 United States License.]

The story title is "Octopus's Garden".
The story author is "Michael D. Hilborn".
The story headline is "An Interactive Cephalopod Escapade".
The story genre is "Fantasy".
The story description is "You have no complaints about your aquarium... except for its view. You've been staring out the same window for months on end. It's time for this octopus to make a change."
The story creation year is 2009.

Release along with a solution.
Release along with the source text.

Use no scoring.

Include Modified Help Menu by Biggles.[*Modified version of Basic Help Menu by Emily Short.]

Part 1 - Setup

[The following sets up some verbs and relations used throughout the game.]

Chapter 1 - Verbs

[One of the puzzles of the game involves pushing an item with another item. Another puzzle involves squirting ink on an item. These verbs are defined here, both with default check rules that print a standard fail message.]
Pushing it with is an action applying to one visible thing and one carried thing.

Understand "push [something] with [something]" as pushing it with.

Check pushing it with (this is the block pushing it with rule):
	say "Nothing comes from pushing [the noun] with [the second noun]." instead.

Squirting it at is an action applying to one visible thing and one visible thing.

Understand "squirt [something] at/on [something]" as squirting it at.

Check squirting it at (this is the can't squirt anything but ink rule):
	if the noun is not the ink, say "You can only squirt your ink at things." instead.
	
Check squirting it at (this is the block squirting it at rule):
	say "Your ink is a black fluid filled with a sloppy, slippery mucus. Squirting [the second noun] would only make a tremendous mess." instead.

[Players may try to turn the tv set on with the plunger. Here we create a verb "turn [something] on with [something]".]
Switching it on with is an action applying to one visible thing and one carried thing.
Understand "turn [something] on with [something]" as switching it on with. Understand "turn on [something] with [something]" as switching it on with. Understand "switch [something] with [something]" as switching it on with. Understand "switch on [something] with [something]" as switching it on with. Understand "switch [something] on with [something]" as switching it on with.

Check switching it on with (this is the can't switch it on with something that's not switchable rule):
	abide by the can't switch on unless switchable rule;
	
Check switching it on with (this is the block switching it on with rule):
	say "You can't switch on [the noun] with [the second noun]."
	
[There's a toilet in the game, so obviously players are going to try flushing it. We define the "flush" verb here. Again, a default check rule provides a default failure message.]
Flushing is an action applying to one touchable thing.

Understand "flush [something]" as flushing.

Check flushing (this is the block flushing rule):
	say "You can't flush [the noun]." instead.

Getting out of is an action applying to one touchable thing.

Understand "get out of [something]" as getting out of. Understand "climb out of [something]" as getting out of.

Instead of getting out of something:
	try exiting;

[There are numerous supporters and containers that our protagonist can climb to enter and exit. Rather than define a climbing rule for each object, we define some generic rules for climbing supporters and containers. These rules redirect the climbing action to either an entering or exiting action, where appropriate.]
Instead of climbing a container:
	if the player is in the noun
	begin;
		try exiting;
	otherwise;
		try entering the noun;
	end if.
	
Instead of climbing a supporter:
	if the player is in the noun
	begin;
		try exiting;
	otherwise;
		try entering the noun;
	end if.

Instead of going down when the player is on a supporter or the player is in a container:
	try exiting;

Understand "climb in/into/on/onto [something]" as entering.

Understand "climb out" as exiting.

Chapter 2 - Relations

[There's a clothesline on which can be hung some clothing, so we define a hanging relation to handle this.]
Hanging relates various things to one thing (called the hanger). The verb to hang (he hangs, they hang, he hung, it is hung, he is hanging) implies the hanging relation. The verb to be hanging from implies the hanging relation.

Chapter 3 - Properties

A thing can be water-proof. A thing is usually not water-proof.

Part 2 - The World Model

Chapter 1 - The Bedroom

Section 1 - The Bedroom itself

Bedroom is a room. "The solitary bedroom of a city apartment that your owner shares with her boyfriend. The queen-sized bed overtakes the west wall and on the opposite wall rests an extravagant dresser. Your aquarium and the ornate table on which it resides lie beneath the northern window and its view of the city, the view you so desperately want to change. Southeast an open doorway leads to a tiny bathroom; southwest a white door closes off the rest of the apartment."

[Although we define one bedroom, there are multiple locations within the room in which our hero will find itself. To clarify to the player where the protagonist is, we add a quick description of the protag's current abode to the locale description. (We do the same in the Bathroom).]
Before printing the locale description of the Bedroom:
	if the player is in the aquarium 
	begin;
		say "You're basking in the ethereal seawater of your aquarium. Your tentacles gently bob up and down from the current generated by the filtration system.";
	otherwise if the player is on the ornate table;
		say "You're resting on the small portion of the ornate table that isn't taken up by your aquarium. The table edge butts against the pane of the window[if the window is open], which you opened not too long ago[end if].";
	otherwise if the player is in the bottom drawer;
		say "You are nestled among some sweaters in the bottom drawer.";
	otherwise if the player is in the top drawer;
		say "You're nested among some shirts, socks, and underwear in the top drawer.";
	otherwise if the player is on the queen-sized bed;
		say "You are currently sprawled across the luxurious queen-sized bed.";
	otherwise;
		say "You're splayed out on the hardwood floor.";
	end if;
	
Instead of going up when in the bedroom:
	if the player is in the bottom drawer
	begin;
		try entering the top drawer;
	otherwise if the player is in the top drawer;
		say "The TV set takes up the entire length of the dresser. There's no room for you up there.";	
	otherwise if the player is in the aquarium;
		try exiting;
	otherwise;
		say "You can either climb the table or the bed[if the bottom drawer is open]. You can also climb the bottom drawer of the dresser[end if].";
	end if.
	
The hardwood floor is scenery in the bedroom.
	
Section 2 - Table and aquarium
	
The ornate table is a enterable supporter in the bedroom. The ornate table is scenery. The description of the ornate table is "Carved from mahogany and surfaced with marble, its the home of your aquarium, which takes up most of the tabletop. The legs of the table curve and flare. Based on their individual reactions, you judge your owner considers the piece beautiful, her boyfriend thinks it gaudy, and the other woman... Well, she's usually too busy on the bed with your owner's boyfriend to have an opinion."

[We want the player to climb up certain objects before interacting with other objects. For example, the aquarium and window should only be reachable from the table. For each container and supporter in the room, we define a generic set of "reaching inside" and "reaching outside" rule.]
A rule for reaching outside the ornate table:
	if the noun is the window, allow access;
	if the noun is the brass latch, allow access;
	say "[random stretch]. You need to get off the ornate table before you can reach that.";
	deny access;
	
A rule for reaching inside the ornate table when the player is not on the ornate table:
	say "[random stretch]. You need to be on the ornate table before you can reach that.";
	deny access;

Instead of exiting when the player is on the ornate table:
	say "You slide down the leg of the table.";
	move the player to the bedroom, printing an abbreviated room description.
	
The aquarium is an enterable container on the ornate table. The aquarium is transparent. The aquarium is scenery. The description of the aquarium is "[if the player is in the aquarium]Layered with sparkling pebbles and adorned with fake coral, the aquarium's been home since you were a little octopus. It seemed much bigger then; now you barely have enough room to unfurl your tentacles. A skeletal pirate protects a treasure chest at the bottom of the tank, and there's a filtration unit and a UV light along the top ledge.[paragraph break]One item of note: There's no lid. You and your owner have a unspoken, mutual understanding that so long as you create no mischief, you're allowed to roam free of the tank. At least, that's what [italic type]you[roman type] think is understood[otherwise]Your home is an enormous tank that takes up most of the ornate table on which it resides[end if]."  Understand "tank" as the aquarium.

A rule for reaching outside of the aquarium:
	if searching the window, allow access;
	say "[random stretch]. You need to be outside of the aquarium to reach that.";
	deny access;

A rule for reaching inside of the aquarium:
	say "[random stretch]. You need to be in the aquarium to reach that.";
	deny access;

Before entering the aquarium:
	if the player is carrying something or the player is wearing something,
		say "You'll need to get rid of the stuff you are carrying before getting into the aquarium." instead;
	 
After entering the aquarium:
	say "[italic type]Splash![roman type] You slither over the edge of the aquarium and sink pleasantly to the bottom of the tank[if the player is not energetic]. Water streams over your gills, filling your blood with refreshing oxygen[end if].";
	now the player is energetic;

Instead of exiting when in the aquarium for the first time:
	say "Octopi are curious creatures, and you're no exception. Onward! You scuttle out of the aquarium.";
	move the player to the ornate table, printing an abbreviated room description;

Instead of exiting when in the aquarium:
	say "You scuttle out of the aquarium.";
	move the player to the ornate table, printing an abbreviated room description;

Instead of inserting something (called the item) into the aquarium:
	say "Why clutter your home with [the item]?";
		
The marine decor is scenery in the aquarium. The description of the marine decor is "Pebbles and fake coral add a homey atmosphere to your abode." Understand "pebbles", "sparkling pebbles", "coral", "fake coral" as the marine decor.

The skeletal pirate is scenery in the aquarium. The description of the skeletal  pirate is "At first it was a sunken ship. You threw it overboard. Then a diver. You tossed him out of the tank, too. Then your owner brought you the pirate. You like him and the little chest he guards. Every now and then the chest opens, releasing a swath of bubbles." Understand "chest", "treasure chest" as the skeletal pirate.

Instead of opening the skeletal pirate:
	say "If you wait long enough, the treasure chest will eventually open on its own."

The filtration unit is scenery that is part of the aquarium. The description of the filtration unit is "The filtration unit monitors such important things as the salinity and oxygen levels of your tank. You like it because it bubbles and creates a gentle current. Out of curiosity, and much to your owner's chagrin, you dissembled the last unit. You couldn't help it. You were curious about how it worked." Understand "bubbles", "current", "filter", "filtration system", "system" as the filtration unit.

The UV light is a device that is part of the aquarium. The UV light is scenery. The description of the UV light is "Nothing more than a long tube. Very dull."

Instead of jumping when in the aquarium:
	say "You propel yourself upward, launching yourself out of the water. You return with a satisfying splash.";
	
Every turn when in the aquarium:
	if a random chance of 1 in 5 succeeds,
		say "The little treasure chest opens, releases a cloud of bubbles, and closes again."
		
Section 3 - The window
		
The window is a door. The window is north of the bedroom. The window is scenery. The window is lockable and locked. The description of the window is "[window's description]." Understand "pane" as the window.

[Two descriptions of the window are required: One for when the player is in the bedroom, and one for when the player is on the ledge.]
To say window's description:
	if the bedroom encloses the player
	begin;
		say "A large window of two panes, the bottom of which [if the window is open]has been pushed up enough that you could squeeze through it to the apartment's outer ledge[otherwise]can be pushed up[end if]. On the top of the lower pane is a brass latch. Through the window is the city vista that you've been staring at for months. It's really time for a change";
	otherwise;
		say "A large window of two panes, the bottom of which [if the window is open]has been pushed up enough that you could squeeze through it back to the apartment[otherwise]can be pushed up[end if]. On the top of the lower pane, inside the window, is a brass latch";
	end if;
		
[We redirect unlocking window actions to the brass latch.]
Instead of unlocking the window with something:
	try unlocking the brass latch with the second noun;
	
The brass latch is part of the window. The description of the brass latch is "You've seen your owner turn the latch before pushing up the window." 

Instead of doing something other than examining the brass latch when the player is in the Ledge:
	say "You'll need to get back into the apartment before you can fiddle with the latch.";
	
Instead of opening the brass latch:
	try pushing the brass latch;
	
Instead of turning the brass latch:
	try pushing the brass latch;

[A hint that the player needs something to reach the brass latch.]
Instead of pushing the brass latch:
	say "[random oomph]. The latch is just out of reach. How disappointing."

[The player can lock and unlock the brass latch by pushing it with the plunger. We redirect the push action to the appropriate lock/unlock action.]
Instead of pushing the brass latch with the plunger:
	if the brass latch is locked
	begin;
		try unlocking the brass latch with the plunger;
	otherwise;
		try locking the brass latch with the plunger;
	end if.

Instead of unlocking the brass latch with the plunger:
	if the window is closed
	begin;
		say "You grip your tentacles around the base of the plunger. Then, with a deft swat of your limbs, you hit the latch with the other end of the plunger. The latch flips, unlocking the window.";
		now the window is unlocked;
	otherwise;
		say "Hitting the latch with the plunger won't do any good when the window is open.";
	end if.

Instead of locking the unlocked brass latch with the plunger:
	if the window is closed
	begin;
		say "You grip your tentacles around the base of the plunger. Then, with a deft swat of your limbs, you hit the latch with the other end of the plunger. The latch flips, locking the window.";
		now the window is locked;
	otherwise;
		say "Hitting the latch with the plunger won't do any good when the window is open.";
	end if.
	
Instead of doing something with the window when the ornate table does not enclose the player and the Bedroom encloses the player:
	say "You can only interact with the window from the ornate table.";
	
Instead of going north when the player is not on the ornate table and the player is enclosed by the bedroom:
	try entering the window;	

Instead of entering the window when the player is on the ornate table:
	try going north;

Instead of going north when the player is on the ornate table:
	if the window is open
	begin;
		say "You slither over the window pane and onto the ledge.";
		move the player to the Ledge;
	otherwise;
		say "The window is closed.";
	end if;
	
Instead of searching the window when the player is enclosed by the bedroom:
	try examining the city vista;
	
The city vista is scenery in the bedroom. The description of the city vista is "Rooftops and chimneys, and beyond them, the sea. Interesting at first. Now dreadfully boring. There must be something else to look at. If only your owner would move out...[paragraph break]There's a ledge outside that you could crawl onto [if the window is open]through the window[otherwise]if the window open[end if], and a clothesline connects this building with the neighboring one. Your owner and her boyfriend use the line for their laundry." Understand "clothesline", "scenery", "ledge", "rooftops", "chimneys", "sea", "ocean", "wall", "building", "neighboring building", "neighboring one" as the city vista.
 
Section 4 - The bed

The queen-sized bed is an enterable supporter in the bedroom. The queen-sized bed is scenery. The description of the queen-sized bed is "Like the table, the bed belongs to your owner. She brought it along when you both moved into his apartment. It's large, covered with a thick quilt, and has several plush pillows on it.[paragraph break]Your owner and her boyfriend lie still on it every night, but sometimes [italic type]other[roman type], mysterious things go on, though you've never been a witness to it: Your owner insists on covering your tank with a blanket. Unlike when that other woman is over. Then there's no blanket at all. Very odd what goes on between her and your owner's boyfriend during those hours. Looks like it could hurt. At the very least, it must cause a rash." Understand "quilt" as the queen-sized bed.

A rule for reaching outside the queen-sized bed:
	say "[random stretch]. You need to get off the bed before you can reach that.";
	deny access;

A rule for reaching inside the queen-sized bed when the player is not on the queen-sized bed:
	say "[random stretch]. You need to be on the bed in order to reach that.";
	deny access;

Instead of exiting when the player is on the queen-sized bed:
	say "You crawl down the quilt onto the floor.";
	move the player to the bedroom, printing an abbreviated room description.
		
Some plush pillows are on the queen-sized bed. The plush pillows are scenery. The description of the plush pillows are "Soft and squishy, like you! They also have fringes, much like tentacles, only smaller."

Instead of doing something other than examining the plush pillows:
	say "There is no need to disturb the plush pillows."

The toy dolphin is a thing. The toy dolphin is water-proof. The description of the toy dolphin is "A rubber toy dolphin with plump cheeks topping off a merry grin. You used to play with it until your owner lost it. You're happy to have found it."

Instead of squeezing the toy dolphin:
	say "You give the toy dolphin an affectionate hug."
	
Instead of looking under the bed for the first time:
	say "What's this? You withdraw a toy dolphin lost under the bed. This disappeared weeks ago!";
	now the player is carrying the toy dolphin;
	
Section 5 - Dresser and TV
	
The dresser is a supporter in the bedroom. The dresser is scenery. The description of the dresser is "Pure black, which matches the color of the enormous television set on top. Your owner and her boyfriend had an argument about it when the two of you moved in. From their gesticulations, you gathered she wanted to remove it; he didn't. There are two drawers[if the top drawer is open and the bottom drawer is open]. Both of them are open[otherwise if the top drawer is open]. The top drawer is open[otherwise if the bottom drawer is open]. The bottom drawer is open[otherwise]. Both of them are closed[end if]."

A rule for reaching inside the dresser:
	say "[random stretch]. You can't reach that from here.";
	deny access;

Instead of climbing the dresser:
	if the bottom drawer is open and the player is not in the bottom drawer
	begin;
		try entering the bottom drawer;
	otherwise if the top drawer is open and the player is in the bottom drawer;
		try entering the top drawer;
	otherwise;
		say "Unfortunately, you have difficulty going up sheer, vertical surfaces.";
	end if.
	
The bottom drawer is an openable enterable container that is part of the dresser. The bottom drawer is closed. Understand "drawers" as the bottom drawer.

Report entering the bottom drawer:
	ignore the standard report entering rule;
	say "You scramble into the bottom drawer.";

Instead of exiting when the player is in the bottom drawer:
	say "You scramble over the edge of the drawer and onto the floor.";
	move the player to the bedroom, printing an abbreviated room description;
		
The top drawer is an openable enterable container that is part of the dresser. The top drawer is closed. Understand "drawers" as the top drawer.

[The player can only interact with the top drawer when in the bottom drawer or when in the top drawer.]	
Instead of doing something with the top drawer when the dresser does not enclose the player:
	say "[random stretch]. Try as you might, you cannot reach the top drawer from here.";
	
Instead of entering the closed top drawer when the player is in the bottom drawer:
	say "You can't enter the closed top drawer.";

Instead of entering the open top drawer when the player is in the bottom drawer:
	say "You haul yourself into the top drawer.";
	say line break;
	if something is in the top drawer,
		say "In the drawer [is-are a list of things in the top drawer].";
	move the player to the top drawer, without printing a room description;
	
Instead of jumping when the player is in the top drawer:
	try exiting;

The baseball cap is in the top drawer. The baseball cap is wearable. The description of the baseball cap is "A blue cap with a starfish embroidered on its front."

Report wearing the baseball cap:
	say "You proudly don the baseball cap." instead.
	
[When exiting the top drawer, the player either falls into the bottom drawer (if it is open), or falls to the floor (if the bottom drawer is closed). This is key for successfully getting away from the TV and into the aquarium before the player's owner enters the room.]
Instead of exiting when the player is in the top drawer:
	if the bottom drawer is open 
	begin;
		say "You clamber down and plop into the lower drawer.";
		move the player to the bottom drawer, printing an abbreviated room description;
	otherwise;
		say "You drop to the floor.";
		move the player to the bedroom, printing an abbreviated room description;
	end if;

[Just adding some scenery to the drawers. They shouldn't be empty.]
Some sweaters are in the bottom drawer. The description of the sweaters is "You don't care for them. They're itchy." Understand "sweater" as the sweaters.

Some shirts are in the top drawer. The description of the shirts is "Your owner and her boyfriend cover their torsos with these." Understand "shirt" as the shirts.

Some socks are in the top drawer. The description of the socks is "Your owner and her boyfriend wear these on their feet. You once put them on your tentacles, but didn't find much use for them." Understand "sock" as the socks.

Some underwear are in the top drawer. The description of the underwear is "Your owner and her boyfriend wear these beneath other garments."

Definition: A thing is clothing if it is the shirts or it is the socks or it is the underwear or it is the sweaters.

Instead of doing something other than examining clothing:
	say "Best not tamper with these. The last time you meddled with [the noun], your owner put the lid on your tank for a few days."

The television set is a switched off device on the dresser. The television set is scenery. The description of the television set is "An immense, rectangular device that produces all sorts of sights and reverberations. Your owner and her boyfriend often turn it on during the evening and sit on the bed and stare at it. You do, too. You can't help it. It's intriguing[if the television set is switched on].[paragraph break]Vivid imagery flickers across the screen; as always, the garden of colors entrances you[end if][if the player is in the top drawer and the television set is switched off].[paragraph break]Now that you're in the top drawer, you're close enough that you can reach the set[end if]." Understand "tv" and "tv set" as the television set.
	 
Instead of doing something other than examining the television set when the player is not in the top drawer:
	say "[random stretch]. You are unable to reach the television set from here."; 

Before switching the television set on with the plunger:
	say "You manage to rap the plunger against the set, but you'll need the dexterity of your tentacles to actually turn it on." instead.
	
Report switching on the television set:
	say "As soon as you flick the switch, the dresser and room begin to vibrate and the screen flowers with vivid imagery. Uh oh. This is bound to attract your owner's attention. Your hearts, all three of them, begin to beat rapidly." instead;

Section 6 - The white door
 	
The white door is a door. The white door is southwest of the bedroom. The white door is closed. The white door is locked. The white door is scenery. The description of the white door is "An insurmountable barrier. You can't even squeeze through the crack that is underneath it."

Instead of looking under the white door:
	try examining the crack;
	
The crack is part of the white door. The description of the crack is "Octopi are extremely flexible and can fit through most cracks. This crevice, however, is too small. Maybe when you were smaller, just a little octopus, you could have squeezed yourself through it, but not now.[paragraph break]Through the crack, you can see the shadow of your owner flit back and forth. She's clearly busy doing something in the main room." Understand "owner", "shadow" as the crack.

Instead of searching the crack:
	try examining the crack;

Instead of opening the white door:
	say "[random stretch]. Unfortunately, you can't reach the doorknob from down here. A shame."
	
Chapter 2 - Outside

Section 1 - Ledge and pulley

Ledge is north of the window. The description of Ledge is "You're high, high above the streets on a precariously thin ledge that ends at the corner of the building. Good thing your suckers are so strong, otherwise the winds today might spell doom. A clothesline stretches north between here and the neighboring building. The apartment window is to the south."

Instead of entering the window when the player is in the Ledge:
	try going south;
	
Instead of going south from the Ledge:
	say "You squeeze back into the bedroom.";
	move the player to the ornate table;

After going north from the Ledge:
	say "Tentacles wrapped tightly around the rope, you slowly inch your way along the clothesline.";
	continue the action;

[The pulley, which reels in the clothesline, initially starts out rusted unmovable. Once the player coats the pulley with ink, the pulley is free to turn.]	
The pulley is scenery in the Ledge. The pulley can be ink-coated or rusty. The pulley is rusty. The description of the pulley is "[if the pulley is ink-coated]A small pulley, over which the clothesline is wrapped, covered in your greasy ink[otherwise]A small, rusted pulley, over which the clothesline is wrapped[end if]."

Instead of pushing the pulley:
	try turning the pulley.
	
Instead of turning the rusty pulley:
	say "[random oomph]. You tug on the clothesline, but years of rain have rusted the pulley. It doesn't want to move."

Instead of turning the ink-coated pulley:
	if the clothesline is pulled-in
	begin;
		say "You tug on the clothesline, but it doesn't want to move any farther. There's probably an obstruction in the neighboring building's pulley.";
	otherwise;
		say "You tug on the clothesline. The pulley, now coated with your uncuous secretion, turns, allowing you to reel in the rope[if the distant undergarments are hanging from the clothesline]. The distant undergarments inch closer until they are about halfway to your ledge[end if]. Then the rope and pulley seize, perhaps because some obstruction on the neighboring building's pulley has gotten in the way.";
		move the female undergarments to Dangling;
		now the clothesline is pulled-in;
	end if.

[Here we override the squirting action so the player can coat the pulley in an oily residue.]
Instead of squirting your ink at the clothesline:
	try squirting ink at the pulley;
	
Instead of squirting your ink at the ink-coated pulley:
	say "You've already made a mess of it."
	
Instead of squirting your ink at the rusty pulley:
	say "You fire off a jet of oily ink that coats the pulley and clothesline.";
	now the pulley is ink-coated.

The bedroom vista is scenery in the Ledge. The description of the bedroom vista is "Through the window you can see the bedroom of your owner's apartment. Up against the window is your aquarium and the ornate table on which it rests." Understand "aquarium", "ornate table", "table" as the bedroom vista.

Instead of searching the window:
	try examining the bedroom vista;
	
The neighboring building is scenery in the Ledge. The description of the neighboring building is "You've observed this building for months from your aquarium, in particular the window opposite yours. A curvy female of your owner's species often appears at the window, hanging garments upon the clothesline. Sometimes your owner's boyfriend stops to watch her, too. In fact, they sometimes chat and on occasion, she comes over to stay in the bed.";

Every turn when in the Ledge:
	if a random chance of 1 in 5 succeeds,
		say "A gust of wind threatens to tear you from the ledge."
		
Section 2 - Dangling from the clothesline

Dangling is north of the Ledge. The description of Dangling is "Climbing out here may not have been the best of ideas. As high up as you are, the street seems to plummet away even farther when you look down. Thank Neptune you have so many tentacles clinging to the rope, otherwise the wind might have sailing over the cityscape by now. Safety lies back in the direction whence you came."

Instead of dropping something when the player is in Dangling or the player is in Ledge:
	say "But you would lose [the noun] to the city below!";
	
Instead of going north when the player is in Dangling:
	say "To Neptune with that! You're barely hanging on as it is. If anything, you should be heading back to the ledge. You're not certain how long you can dangle from here."

The clothesline is a backdrop in the Ledge and in Dangling. The clothesline can be pulled-in. The clothesline is not pulled-in. The description of the clothesline is "A thin length of rope[if the player is in Dangling], bending under your weight, [end if] that runs between your owner's building and its neighbor[if the player is in the Ledge]. The clothesline runs over a pulley attached to the wall of this building[end if]." Understand "rope", "line" as the clothesline.

Instead of climbing the clothesline:
	try going north.
	
Instead of pulling or pushing the clothesline when the player is in the Ledge:
	try turning the pulley.

[When the player first steps outside the apartment, he/she might notice some undergarments in the distance. The goal is to eventually obtain said undergarments and place them conspicuously in the bedroom. To obtain the undergarments, the player must (1) first reel in the clothesline so that the garments are halfway between the two buildings, and (2) climb out onto the clothesline and gather them up.

Initially, the undergarments are out of reach and viewable from either the ledge or the clothesline. So we create an object called the "distant undergarments" that we ensure cannot be interacted with, and have it move (with the player) between the two rooms. The distant undergarments disappear when the player has removed the garments or when the player is on the clothesline and the garments are within reach.]		
Some distant undergarments are in the Ledge. The distant undergarments are hanging from the clothesline. "Hanging from the clothesline,[if the clothesline is pulled-in] about halfway over the street[otherwise] near a window of the neighboring building[end if], are what you recognize as some female undergarments." The description of the distant undergarments are "They are pink, unlike the color of your owner's."

Instead of doing something other than examining the distant undergarments:
	say "[random stretch]. The undergarments are too far away from you."

Some female undergarments are a wearable thing. The female undergarments are hanging from the clothesline. "Hanging from the clothesline are the female undergarments you spotted earlier." The description of the female undergarments is "Several pairs of interesting things, all pink, most filmy, some frilly, and one that appears to be no more than a few bits of string tied together. You've seen them before. Your owner's boyfriend and the woman who wears them often fling them to the floor."

Instead of dropping the female undergarments when the player is in Dangling:
	try putting the female undergarments on the clothesline;

Instead of putting the female undergarments on the clothesline when the player is in Dangling:
	say "You gingerly hang the garments back on the clothesline, hoping the wind won't take them away.";
	move the female undergarments to Dangling;
	now the female undergarments are hanging from the clothesline;
	
After taking the female undergarments:
	now the female undergarments are not hanging from the clothesline;
	continue the action;
	
Report taking the female undergarments when the player is in Dangling and the female undergarments are hanging from the clothesline:
	say "Cautiously, making certain you don't lose your own precarious hold, you pluck the undergarments, one by one, from the clothesline." instead.
		
After going north from the Ledge:
	if the female undergarments are hanging from the clothesline and the clothesline is not pulled-in
	begin;
		move the distant undergarments to Dangling;
		now the distant undergarments are hanging from the clothesline;
	otherwise if the female undergarments are hanging from the clothesline and the clothesline is pulled-in;
		move the female undergarments to Dangling;
	otherwise;
		remove the distant undergarments from play;
		now the distant undergarments are not hanging from the clothesline;
	end if;
	continue the action;
	
After going south from Dangling:
	if the female undergarments are hanging from the clothesline and the clothesline is not pulled-in
	begin;
		move the distant undergarments to the Ledge;
	otherwise if the female undergarments are hanging from the clothesline and the clothesline is pulled-in;
		move the female undergarments to Dangling;
	otherwise;
		remove the distant undergarments from play;
		now the distant undergarments are not hanging from the clothesline;
	end if;
	continue the action;

Every turn when in Dangling:
	if a random chance of 1 in 5 succeeds,
		say "A gust of wind forces you to cling to the clothesline."

	
Chapter 3 - The Bathroom

Bathroom is southeast of the Bedroom. "Tiny and spotless. Your owner must clean in here at least twice a week. Alas, what happens in here often remains a mystery to you because the curtain overhanging the northwestern doorway is frequently drawn. There's the sink, high above your reach when you're upon the floor; a basin of water your owner calls a toilet; and the bathtub, where you've spent time while your owner cleans your aquarium."

Before printing the locale description of the bathroom:
	if the player is in the toilet
	begin;
		say "You're splashing about the water in the toilet.";
	otherwise if the player is in the bathtub;
		say "You're in the bathtub. Its faucet is now within reach.";
	otherwise if the player is in the sink;
		say "You're curled up in the sink, high above the floor. The sink's faucet sparkles from a recent cleaning.";
	otherwise;
		say "You're splayed out on the tiled floor.";
	end if.
	
Instead of going up when the player is in the bathroom:
	say "You can climb the toilet or the sink."

The curtain is a backdrop. The curtain is in the bedroom and the bathroom. The curtain can be drawn. The curtain is not drawn. The description of the curtain is "It separates the bathroom from the bedroom. It is currently [if the curtain is drawn]drawn[otherwise]thrown wide open[end if]."

Instead of opening the curtain:
	if the curtain is drawn
	begin;
		say "You drag the curtain open.";
		now the curtain is not drawn;
	otherwise;
		say "It's already open.";
	end if.

Instead of closing the curtain:
	if the curtain is not drawn
	begin; 
		say "You draw the curtain to a close.";
		now the curtain is drawn;
	otherwise;
		say "It's already drawn.";
	end if.

The toilet is an enterable container in the Bathroom. The toilet is openable. The toilet is scenery. The carrying capacity of the toilet is one. The description of the toilet is "The toilet is a mysterious basin always full of water. Even when emptied, it magically refills. You don't know what your owner and her boyfriend use it for. Drinking, perhaps?" Understand "basin", "crapper" as the toilet.

A rule for reaching outside of the toilet:
	say "Unfortunately, that is too far away. You will need to haul yourself out of the toilet, first.";
	deny access;

Instead of exiting when in the toilet:
	say "You scuttle over the edge of the toilet and onto the floor.";
	move the player to the bathroom, printing an abbreviated room description;
	
Instead of flushing the toilet:
	say "[italic type]Whoosh![roman type][if the rubber duck is in the toilet] The rubber duck dances around the toilet[otherwise] The water disappears in a beautiful spiral, only to magically reappear a few moments later[end if]."

Instead of flushing the toilet when the player is in the toilet:
	say "Ahhhh! The water spirals over you, giving you a soothing massage.";

[Both sinks and bathtubs have faucets. We devise this kind of device.]		
A faucet is a kind of device. Understand "water" as a faucet when the faucet is switched on.

Instead of examining a faucet (called the tap):
	if the tap is switched on
	begin;
		say "Water miraculously flows from [the tap]." instead;
	otherwise;
		say "A miracle that your owner can perform. She can make water appear simply by turning on this device." instead;
	end if.

Before switching on a faucet (called the tap) when the player is carrying something that is not water-proof:
	if the tap is part of something (called the target)
	begin;
		if the player is in the target,
			say "Better not. You're likely to get some of the stuff you are carrying very wet. Your owner didn't appreciate that last time." instead;
	end if.

Before switching on a faucet (called the tap):
	if the tap is part of something (called the target)
	begin;
		if something that is not water-proof is in the target,
			say "Better not. You're likely to get [the list of things in the target] all wet." instead;
	end if.
	
Report switching on a faucet (called the tap):
	say "You wrap a tentacle around the device and with a twist, water, glorious water, flows from its mouth." instead;
	
Report switching off a faucet (called the tap):
	say "You wrap a tentacle around the device and with a twist, the water sadly stops its flow." instead;
	
The bathtub is an enterable container in the Bathroom. The bathtub is scenery. "When your owner cleans your aquarium, you spend time in here, though it's full of water when you're in it. It's much bigger than your aquarium, so you can really stretch out, but it doesn't have the coral or pebbles or the skeletal pirate you like so much." Understand "tub", "bath" as the bathtub.

A rule for reaching outside of the bathtub:
	say "[random stretch]. You will need to get out of the bathtub before reaching that.";
	deny access;

Instead of exiting when the player is in the bathtub:
	say "You scramble over the edge of the tub and drop to the floor.";
	move the player to the bathroom, printing an abbreviated room description;
	
Report entering the bathtub:
	ignore the standard report entering rule;
	say "You slide over the edge of the tub[if the bathtub's faucet is switched on]. Water from the faucet pleasantly flows over you[end if].";
	
	
The bathtub's faucet is a faucet that is part of the bathtub.

The rubber duck is in the bathtub. The rubber duck is water-proof. "Sitting in the bathtub is a rubber duck." The description of the rubber duck is "A bright yellow body with an orange beak and two wide, blue eyes. You often play with it when your owner puts you in the bathtub. It's squeezable."

Instead of squeezing the rubber duck:
	say "The rubber duck compresses, then re-inflates."
		
The sink is an enterable container in the Bathroom. The sink is scenery. The description of the sink is "[if the player is not in the sink]From here you can only see the underside of the sink and the metal pipe that leads up to it[otherwise]It's cramped in here[end if]." Understand "metal pipe", "pipe" as the sink.

A rule for reaching outside of the sink:
	say "[random stretch]. You will need to get out of the sink before reaching that.";
	deny access;
	
Instead of exiting when the player is in the sink:
	say "You drop to the floor with a splat.";
	move the player to the bathroom, printing an abbreviated room description;
	
Report entering the sink:
	ignore the standard report entering rule;
	say "You climb up the pipe, reach up to the edge of the sink, and drag yourself in[if the sink's faucet is switched on]. Water from the tap gently flows over you. Mmmm[end if].";
	
The sink's faucet is a faucet that is part of the sink.

Instead of doing something with the sink's faucet when the player is not in the sink:
	say "[random stretch]. You cannot reach that from here.";
	
The plunger is in the bathroom. The plunger is water-proof. "Resting in the corner next to the toilet is a plunger." The description of the plunger is "A typical plunger with a wooden handle and orange sucker that is much larger than any of the ones on your tentacles.";

The tiled floor is scenery in the bathroom.
	
Chapter 4 - Defining Aqueous Objects

[Several of the objects the player can explore have or may contain water. We define these objects as 'aqueous' so we can give them similar properties.]
Definition: A thing is aqueous if a switched on faucet is part of it or it is the aquarium or it is the toilet.

Before entering something that is aqueous:
	if the player is carrying something (called the item) that is not water-proof or the player is wearing something (called the item) that is not water-proof
	begin;
		say "If you get in [the noun] now, you're liable to get the stuff your carrying all wet. Your owner would not approve, and the last time you got something of hers wet, she put a lid over your aquarium for a week.";
		stop the action;
	end if.
	
Before inserting something that is not water-proof into something that is aqueous:
	say "Your owner would not approve of you getting something of hers all wet. Last time you did that, she put a lid over your aquarium for a week.";
	stop the action;
	
Part 3  - The Player

[Part 3 defines the protagonist, adding some personality through the provision of physical attributes and custom responses to standard verbs.]

Chapter 1 - Our Friend, the Octopus

The player is in the aquarium. The carrying capacity of the player is eight. the player is water-proof.

Instead of examining the player:
	try examining your body;
	
Your body is part of the player. The description of your body is "A bulbous head, two slitted eyes, eight wondrous tentacles, a beak for a mouth, and an ink sac. What more could one ask for? You're the perfect specimen[if the player is wearing the female undergarments]. You're also wearing the female undergarments. They don't fit very well[end if]."  

Your bulbous head is part of the player. The description of your bulbous head is "Pretty much everything is in there. Brain, tummy, hearts (three of them); yep, all conveniently packaged[if the player is wearing the baseball cap]. Perched on your mantle is a baseball cap[end if]."

Your slitted eyes are part of the player. The description is "Your vision is quite acute, but even your eyes can't see themselves."

Your ink is part of the player. The description of your ink is "Well, technically, you can't see the ink sac since it's inside you. You can use it to SQUIRT INK AT SOMETHING if you feel the need." Understand "ink sack", "sack", "ink sac", "sac" as your ink.

Your tentacles are part of the player. The description of your tentacles is "Eight of them, with two rows of suckers flowing down each. They're very flexible and extremely tactile. It's sad that your owner doesn't seem to have any. How does she taste anything?" Understand "limbs", "arms", "tentacles", "tentacle", "suckers" as your tentacles.

Your beak is part of the player. The description of your beak is "It's what you use to eat, though you taste things through the suckers on your tentacles." Understand "mouth" as beak.

Chapter 2 - The Sensual Octopus

A procedural rule (this is the ignore ambient sound rule): ignore the ambient sound rule;

Rule for supplying a missing noun while listening:
	change the noun to the player;
	
Before listening to something:
	say "But octopi lack auditory organs!" instead;

Rule for supplying a missing noun while smelling:
	change the noun to the player;
	
A procedural rule (this is the ignore ambient odour rule): ignore the ambient odour rule;

Before smelling something:
	say "Octopi have an acute sense of smell, but you don't detect anything interesting from [the noun]." instead;

Instead of touching something:
	try tasting the noun;

Instead of tasting something:
	say "[random oomph]. Definitely not as tasty as the bits of crab your owner treats you."

Instead of waving something:
	say "With one of your tentacles, you vigorously shake [the noun].";

Instead of waving the plunger when the player is wearing the baseball cap:
	say "You tilt your hat down like you see some people do when they're playing some game on the TV. You wind up, then swing the plunger, imagining it smacking a ball."
	
Instead of waving hands:
	say "You thrash your tentacles a bit and accomplish nothing."

Instead of singing:
	say "A few bubbles escape from your beak."
	
Instead of jumping:
	say "With a generous thrust of your tentacles, you propel yourself upward."

Instead of kissing something:
	try squeezing the noun;
	
Instead of squeezing something:
	say "You briefly wrap your tentacles around [the noun] and give it a hug."
	
To say random stretch:
	say "[random oomph]. [one of]You elongate a tentacle as far as you can to no avail[or]Despite your best effort, your tentacles only stretch so far[or]You extend a tentacle as far as you can. No good[or]Your tentacles are only so tensile[or]To the best of your ability, you stretch a tentacle as far as you can. It's no use[purely at random]";
	
To say random oomph:
	say "[one of]Oomph[or]Errk[or]Errg[or]Eeef[or]Augh[or]Oog[purely at random]";
	
Chapter 3 - Drowning

[An octopus can survive only so long out of water, so we emulate this by providing four levels of health. While the player remains out of the aquarium, the player's health gradually diminishes until death occurs. Of course, once the player returns to the aquarium, the player's health is reset and the octopus can romp around anew.]
A person can be energetic, tired, sickly, or near-death. The player is energetic.
 
Drowning is a recurring scene. Drowning begins when the player is not in the aquarium. Drowning ends when the player is in the aquarium.

Every turn during Drowning:
	if the time since Drowning began is 20 minutes
	begin;
		say "Phew! All this running around is making you breathless.";
		now the player is tired;
	otherwise if the time since Drowning began is 30 minutes;
		say "You're feeling a little ill. It might be the lack of oxygen. Better get back to your tank soon.";
		now the player is sickly;
	otherwise if the time since Drowning began is 40 minutes;
		say "You're really running out of breath. If you don't get yourself back in the aquarium, it's curtains for you.";
		now the player is near-death;
	otherwise if the time since Drowning began is 45 minutes;
		say "Lacking oxygen and unable to take breath, you collapse.";
		end the game in death;
	end if.

Part 4 - The Plot Thickens

[The small amount of plot, including the owner's eminent arrival after the player turns on the TV set, is handled here.]

Chapter 1 - When Play Begins

When play begins:
	say "When your owner and you first moved into this apartment, the view out the window excited you. The city! The buildings! The rooftops! The clotheslines! So many things one doesn't find underwater...[paragraph break]Alas, it's been months, and you've grown bored staring out the same window, at the same view, day after day. Time for a change in scenery. But how to get your owner to move on?"
	
Chapter 2 - Switching On the TV

Your owner is a woman. Your owner can be forgiving or annoyed. Your owner is forgiving.

Owner Approaches is a recurring scene. Owner Approaches begins when the television set is switched on. Owner Approaches ends when the time since Owner Approaches began is four minutes.

Every turn during Owner Approaches:
	if the time since Owner Approaches began is one minute
	begin;
		if the player can see the white door,
			say "Your keen eyes detect the shift of light underneath the white door. Your owner! She's approaching!";
	otherwise if the time since Owner Approaches began is two minutes;
		if the player can see the white door,
			say "The handle on the white door jiggles. It's your owner, for certain! She's about to come in! If she finds you outside your aquarium...";
	otherwise if the time since Owner Approaches began is three minutes;
		move your owner to the Bedroom;
		[Win condition!]
		if your owner can see the female undergarments and the player is in the aquarium 
		begin;
			say "The white door opens, revealing your owner, bewilderment etched in her frown as she first gazes at the [if the television set is switched off]still[otherwise]animated[end if] screen of the television set, then stares suspiciously to you, at which point you stare innocently out the window. She sighs, surveys the rest of the room, and her eyes lock on the myriad of female undergarments you've strewn about. Suspicion transforms back to puzzlement, then to shock, then back to suspicion again.";
			say line break;
			say "It's apropos that her boyfriend walks into the apartment at that very minute. His greeting dies when she shows him the underwear. The argument that ensues... Well, you're glad you don't have ears. Nevertheless, it's very exciting.";
			say line break;
			say "[bold type]*** ONE MONTH LATER ***[roman type]";
			say paragraph break;
			say "Ah, a new place, a new view. You and your owner have moved out of her ex-boyfriend's apartment into a house in the suburbs. Your aquarium rests next to a window overlooking a floral garden complete with hedgerows and trees and even a little pond in which goldfish swim. Birds often visit the feeder, and sometimes you see deer. It's heaven. For now. You'll see how long it lasts. When you grow bored, you'll have to figure out how to get her to move again...";
			end the game saying "You have had a change of scenery";
		otherwise;
			have the player's owner clean up;
			move the player to the aquarium, without printing a room description;
		end if;
	end if.
	
To have the player's owner clean up:
	if the owner can see the player
	begin;
		say "The white door opens, revealing your owner, bewilderment etched in her frown as she first gazes at the [if the television set is switched off]still[otherwise]animated[end if] screen of the television set[if the player is in the aquarium], then stares suspiciously to you, at which point you stare innocently out the window. She sighs and surveys the rest of the room.[otherwise], locks her eyes with yours. You freeze in mid-action and if you could grin sheepishly, you would[end if]";
	otherwise if the player is in the bottom drawer or the player is in the top drawer;
		say "You huddle in the darkness of the drawer. Maybe she won't notice that the aquarium is--Nope. Light briefly blinds you as she opens the drawer";
	otherwise if the player is enclosed by the bathroom;
		say "Your owner strides into the bathroom, hands on her hips, her glare directed at you. If you could grin sheepishly, you would. Unfortunately, all you can offer is a little froth of bubbles";
	otherwise;
		say "You give her this much: She's good at tracking a vagrant octopus down";
	end if;
	if the player is not in the aquarium
	begin;
		say ". Not a moment later you're plucked up[if the player is carrying something or the player is wearing something], relieved of your possessions, [end if] and deposited back in the aquarium.";
		say line break;
		say "Shaking her head in frustration, she fixates you with a glare";
		if your owner is annoyed
		begin;
			say ". Next thing you know, there's a lid over your aquarium.";
			end the game saying "You'll never get a change of scenery now";
			stop;
		otherwise;
			say " and holds up one finger. The meaning is clear: She better not catch you out of the aquarium again, otherwise... game over.";
			now your owner is annoyed;
		end if;
		say line break;
		say "She [if the television set is switched on]turns off the TV and [end if]storms out, slamming the door behind her. So vexed is she that she doesn't bother to tidy up like she usually does[if your owner can see the female undergarments] and she doesn't even notice the female undergarments that aren't hers[end if].";
	otherwise;
		say line break;
		say "She [if the television set is switched on]turns off the TV and [end if]leaves you alone, closing the door behind her. So perlexed is she that she doesn't bother to tidy up like she usually does[if your owner can see the female undergarments] and she doesn't even notice the female undergarments that aren't hers[end if].";
	end if;
	[Clean up]
	repeat with item running through things enclosed by the player
	begin;
		if the item is not part of the player,
			move the item to the bedroom;
	end repeat;
	remove your owner from play;
	now the television is switched off.
	
Part 5 - Help

Chapter 1 - Table of Basic Help Options

When play begins:
     choose row 1 in Table of Basic Help Options;
     change description entry to "'Octopus's Garden' is an Interactive Fiction game written by Michael D. Hilborn. Many thanks to Graham Nelson, Emily Short, and the crew of Inform 7 who made this particular cephlapod adventure possible.[paragraph break]'Octopus's Garden' by Michael D. Hilborn is licensed under a Creative Commons Attribution-Noncommercial-Share Alike 3.0 United States License.";
	choose row 4 in Table of Basic Help Options;
     change description entry to "'Octopus's Garden' was written by Michael D. Hilborn. Feel free to send comments, criticisms, bug reports, or jokes to mhilborn@biggle2k.com";

After printing the banner text:
	say "[line break][bracket]New players may wish to type 'ABOUT'.[close bracket][paragraph break]";
	
Chapter 2 - Hints

Table of Stuckness Advice (continued)
title	subtable	description	toggle
"Things to try at the beginning of the game"	--	"To get you started, here's a list of commands to try typing at the beginning of the game. Note that you don't necessarily have to use these commands in this order:[paragraph break]EXAMINE ME[line break]INVENTORY[line break]EXAMINE AQUARIUM[line break]EXAMINE SKELETAL PIRATE[line break]OPEN CHEST[line break]EXAMINE UV LIGHT[line break]TURN LIGHT ON[line break]TURN LIGHT OFF[line break]EXAMINE WINDOW[line break]LOOK THROUGH WINDOW[line break]GET OUT OF AQUARIUM[line break]EXAMINE TABLE"	--
"As a last resort (*Spoilers*)..."	Table of Hints-Menu	--	--

Table of Hints-Menu
title	subtable	description	toggle
"What am I supposed to do?"	Table of Hints-Main	--	hint toggle rule
"I'm stuck in the aquarium. How do I get out?"	Table of Hints-Tank	--	hint toggle rule
"Can I open the window?"	Table of Hints-Window	--	hint toggle rule
"I can't climb up the dresser."	Table of Hints-Dresser	--	hint toggle rule
"I can't reach the television set."	Table of Hints-TV	--	hint toggle rule
"What can I do with the bed?"	Table of Hints-Bed	--	hint toggle rule
"Is there anything useful about the toys?"	Table of Hints-Toys	--	hint toggle rule
"What can I do in the bathroom?"	Table of Hints-Bathroom	--	hint toggle rule
"Is the plunger useful?"	Table of Hints-Plunger	--	hint toggle rule
"I'm on the ledge. Is there a way to get on the clothesline?"	Table of Hints-Clothesline	--	hint toggle rule
"I can't reach the undergarments."	Table of Hints-Undergarment Puzzle	--	hint toggle rule
"I have the undergarments. What do I do with them?"	Table of Hints-Undergarments	--	hint toggle rule	
"My owner keeps catching me outside of the aquarium!"	Table of Hints-Owner	--	hint toggle rule

Table of Hints-Template
hint	used
"[bracket]These hints will be completed later.[close bracket]"	a number

Table of Hints-Main
hint	used
"Have you read the introduction?"	a number
"EXAMINE and LOOK THROUGH THE WINDOW."	--
"You're an octopus who lives in an aquarium that has only one view. You want to change it by getting your owner to move."	--
"EXAMINE THE TABLE and EXAMINE THE BED. When you're on the ledge, EXAMINE THE NEIGHBORING BUILDING and the FEMALE UNDERGARMENTS."	--
"Hmm. Seems like your owner's boyfriend is up to no good."	--
"If you can to prove it, your owner will probably move out, taking you with her."	--
"The goal of the game is to get the female undergarments, leave them in a place where your owner can see them, and make certain you are in the aquarium before your owner finds them."	--

Table of Hints-Tank
hint	used
"It's easy enough. Just CLIMB OUT or CLIMB OUT OF AQUARIUM."	a number

Table of Hints-Window
hint	used
"Yes, but you need to unlock it first."	a number
"EXAMINE THE WINDOW. Note the brass latch. Try unlocking that."	--
"Can't reach it? You might need something else to extend your reach."	--
"See the hints about the plunger."	--

Table of Hints-Dresser
hint	used
"You can't climb sheer surfaces, so maybe there is a way to make the dresser more climbable."	a number
"Have you opened the drawers?"	--
"You can use them to climb up the dresser."	--
"You can open the bottom drawer from the floor, but you can't open the top drawer unless you are in the bottom drawer."	--
"Try this: OPEN BOTTOM DRAWER. CLIMB INTO IT. OPEN TOP DRAWER. CLIMB INTO IT."	--

Table of Hints-TV
hint	used
"You can't reach it from the floor."	a number
"You can't reach it from the bottom drawer."	--
"You CAN reach it from the top drawer."	--
"See the hints about climbing the dresser."	--

Table of Hints-Bed
hint	used
"Have you tried climbing it?"		a number
"Have you looked underneath it?"	--
"You can leave the female undergarments on it, but it's really not necessary."	--
"Sorry, the bed's mainly there for scenery. After all, a bedroom isn't a bedroom without a bed."	--

Table of Hints-Toys
hint	used
"I'm assuming you mean the rubber duck and the toy dolphin."	a number
"You can try squeezing them."	--
"But other than that, they're only there to play with. Same with the baseball cap."	--

Table of Hints-Bathroom
hint	used
"Explore, mostly. You can enter and exit the sink, bathtub, and toilet."	a number
"You can turn the faucets on and off."	--
"But the most important item is the plunger. Make sure you take it with you."	--

Table of Hints-Plunger
hint	used
"Well, it's long and can extend your reach."	a number
"Is there something just out of your reach when you try to interact with it?"	--
"It won't help you reach the TV set."	--
"EXAMINE THE WINDOW when you are on the table. Pay particular attention to the brass latch."	--
"UNLOCK BRASS LATCH WITH THE PLUNGER."	--

Table of Hints-Clothesline
hint	used
"Yes."	a number
"Try going NORTH from the ledge or CLIMB CLOTHESLINE."	--
"You can't go any farther than half-way, so there's no use trying."	--

Table of Hints-UnderGarment Puzzle
hint	used
"The undergarments are initially next to the neighboring building, far out of reach."	a number
"You can try climbing out to them by going NORTH from the ledge..."	--
"But that only gets you half-way there."	--
"You need to reel them in: PULL CLOTHESLINE when on the ledge."	--
"Unfortunately, the pulley is initially stuck."	--
"Have you examined it?"	--
"It's very rusty. Have you seen some lubricant somewhere?"	--
"Examine yourself."	--
"Specifically, your ink sack. Your ink might be slippery enough."	--
"Squirt your ink on the pulley and you can reel the undergarments in."	--
"They only reel in half-way, but now you can climb out on the clothesline to get them."	--
"From the ledge: SQUIRT INK ON PULLEY. PULL CLOTHESLINE. CLIMB CLOTHESLINE. TAKE UNDERGARMENTS."	--

Table of Hints-Undergarments
hint	used
"You want your owner to find them."	a number
"Leave them anywhere out in the open in the bedroom."	--
"Now all you need to do is get your owner to come in the bedroom."	--
"Have you tried turning the TV set on?"	--
"After you turn the TV on, your owner enters the room."	--
"But if you're out of your tank, you're a distraction and she won't notice the undergarments aren't hers."	--
"So make certain you are in the tank when your owner comes in the room. Then she'll find the undergarments."	--

Table of Hints-Owner
hint	used
"You have three turns to get from the top drawer into your aquarium."	a number
"But it seems to take FOUR turns to get from the top drawer to the aquarium. Why is that?"	--
"You drop first into the bottom drawer (one turn), then onto the floor (second turn), but when you get on the table (third turn), your owner comes in."	--
"You need to skip one of the steps."	--
"Is there a way to get directly to the floor from the top drawer?"	--
"Try closing the bottom drawer. Do it before you turn on the TV set."	--
"When in the top drawer, the correct sequence is: CLOSE BOTTOM DRAWER. TURN TV ON. D. CLIMB TABLE. GET IN AQUARIUM."	--
"Oh. Make certain you are not carrying or wearing anything, otherwise you may not be able to enter the aquarium."	--
 



