"Heaven-Sent" by "Michael D. Hilborn"

[A short game, light on puzzles and story, designed to be submitted during the first week of Interactive Fiction Writing Month. Don't expect to see any comments within the source code; it's written in I7 and should (mostly) be self explanatory.

This work is licensed under a Creative Commons Attribution 3.0 United States License.]

Release along with a solution.
Release along with the source text.
Use no scoring.

When play begins:
	say "The first rays of the new day permeate the stained-glass saints who watched over you last night. How long you have been staring at them--at those cold, glass eyes--you don't remember. It doesn't matter. All that matters is somehow you survived through the night.[paragraph break]She didn't."

Chancel is a room. "From upon its dais, the altar rises above where the congregation would normally sit. They won't be here this morning, though. Perhaps never again.[paragraph break]Stained-glass windows, brilliant in the dawn's easterly light, line the top half of the walls, except to the north where the only feature is an oak door. Westward, the church falls into shadow[if the player is on the altar].[paragraph break]You are sitting slumped on the altar, where you spent most of the night. Sunlight streams through the stained-glass windows, bathing you[end if]." 

The altar is a supporter in the Chancel. "Sunlight pours through the stained-glass windows and shrouds the altar." The description of the altar is "Solid and formidable and shrouded in sunlight[if the bottles of wine are on the altar]. The light dapples off several bottles of wine[end if][if the player is on the altar]. You are sitting on the altar[end if]." Understand "dais" as the altar.

After examining the altar for the first time:
	say italic type;
	say "'It's hard to believe we were married here just two weeks ago,' she says, her voice weaker than before. You can't see her in the darkness, but you can hear her shuffling restlessly about the pews. 'And now I'm going to--'[paragraph break]'Don't say it,' you bark, too harshly. 'We'll... we'll get through this... somehow. Morning. Let's wait until morning. Let's see what it brings.'[paragraph break]'No, morning will be too late,' she answers. 'By then, I'll have... I'll have become one of them.'";

After getting off the altar for the first time:
	say "As you push yourself off the altar, your hand hits one of the many empty bottles of wine strewn about you. It rolls off the altar, smashes upon the floor.";
	say line break;
	say "You remember the windshield shattering like that... when your car plowed into two of...[italic type]them[roman type]. You recall the squeal of tires and sinew. The sickening thuds. The car wouldn't start after that, and you and she had no choice but to make a mad dash to the church.";	
	move the shattered bottle of wine to the Chancel;
	
The sunlight is scenery in the chancel. The description of the sunlight is "It filters through the stain-glass window and outlines the altar." Understand "sun", "light", "dawn" as the sunlight.

After examining the sunlight for the first time:
	say "The first rays of the sun. That's when the noise stopped. The movement. Everything.";
	
The bottles of wine are on the altar. The bottles of wine are scenery. The description of the bottles of wine is "There are many bottles, and every one drained dry by you."

After examining the bottles of wine for the first time:
	say italic type;
	say "'At least we won't go thirsty,' she says. In the darkness, you can only imagine her grin... and it vanishing a moment later. 'I guess they didn't have a chance to put it away. Where do you think they went?'[paragraph break]'Out there,' you answer, looking up at the stained-glass windows. 'With the rest of them.'";

Instead of taking the bottles of wine:
	say "You've already had enough. You emptied the bottles, one-by-one, after you spent your last moments with her."
	
The shattered bottle of wine is a thing. "A shattered bottle of wine lies at the foot of the altar." The description is "Remnants of wine glisten like blood among shattered glass." Understand "glass" as the shattered bottle.

Instead of taking the shattered bottle of wine for the first time:
	say "You take a piece of glass from the remains of the wine bottle.";
	move the piece of glass to the player;

Instead of taking the shattered bottle of wine:
	say "You have already removed a piece of glass from the shattered bottle.";
	
The piece of glass is a thing. The description is "Sharp and smooth. Like a knife."

After examining the piece of glass for the first time:
	say "[italic type]They[roman type] had claws. Fangs and claws. They glinted like knives in the moonlight.";

Instead of cutting yourself when the player is carrying the piece of glass:
	say "Carefully, you gouge a deep, bloody line down the length of your wrist. It's painful, but only for a little while.";
	end the game in death;

The stained-glass windows are scenery in the Chancel. The description of the stained-glass windows is "Seven windows of seven saints who stare down at you with cold, glass gazes. You don't know who they are. Never were a religious man." Understand "window", "saints", "saint", "walls" as the stained-glass windows.

After examining the stained-glass windows for the first time:
	say italic type;
	say "Something skitters across the windows. You can hear it.[paragraph break]'They can climb the walls,' she breathes, huddled next to you. 'How can they climb the walls?'[paragraph break]'I don't know,' you say. You've said it too many times tonight.[paragraph break]'You're not safe here,' she moans. 'Not with me here. You're not safe.'";

The oak door is a door. The oak door is north of the Chancel and south of the Bottom of Stairs. The oak door is scenery. The oak door is locked. The description of the oak door is "A heavy door of oak."

After examining the oak door for the first time:
	say italic type;
	say "Something slams against the oak door. It shudders, but holds.[paragraph break]'The belfry,' she whispers, frantically. 'They're getting in through the belfry. How could they get up there?'[paragraph break]Another thud. And another. Like the drums of war. And still the door holds.";
	
Bottom of Stairs is a room. "Stairs of old wood spiral upward to the bell tower. A door, its sturdy oak surface gouged and marred, lies to the south."

The old stairs are scenery in Bottom of Stairs. The description of the old stairs is "Like the door, rents and gouges mar the surface of the stairs. Something came down here last night. A [italic type]big[roman type] something.";

The Belfry is above the Bottom of Stairs. "Sun. Warmth. A vista of a summery New England village. Except for the enormous crater in the center of town, where [italic type]it[roman type] landed, there is no sign of last night's devastation. No sign at all. Where have they all gone? When you no longer wish to think about it, an old staircase spirals down and away from the view."

Instead of jumping when in the belfry:
	say "You spread your arms wide and leap. It's a pleasant sensation, weightlessness, but it lasts only a little while.";
	end the game in death.

The bell is in the belfry. "The church bell, brilliantly polished, seems to shimmer in the dawn's light." The description of the bell is "Recently polished and somehow, like you, it survived the night without a scratch."

After examining the bell for the first time:
	say italic type;
	say "The bell rings and your friends cheer as you and your new bride emerge from the church. Confetti showers you as you run down the stairs to the waiting limousine.[paragraph break]Once in the car, she immediately embraces you with a passionate kiss. When she releases you, you are able to return her smile. 'Heaven sent you to me, you know,' you whisper.";

Ringing is an action applying to one visible thing and requiring light.

Understand "ring [something]" as ringing.

Check ringing:
	if the noun is not the bell, say "You cannot ring [the noun]." instead.

Instead pushing or pulling the bell:
	try ringing the bell;
	
Instead of ringing the bell:
	say "As the bell tolls, its polished surface catches the sunlight in a fiery flash. Once. Twice. Again and again it rings and flashes. You keep tolling, not knowing exactly why. Maybe because... it's all you can do.[paragraph break]Then... Is it your imagination? No, it's not: One of the helicopters has broken rank and is heading for the church.[paragraph break][bold type]***[roman type][paragraph break]You're not certain how long it takes them to haul you into the helicopter, but after you clamber in, you're given headphones and one of the soldiers speaks to you. 'Be thankful you rang that bell and that we saw the flashes. We found you just in time.'[paragraph break]'In time for what?'[paragraph break]Your answer is a half-dozen lobs of light spiraling down from the sky. They plummet into the center of town, eradicating everything.[paragraph break]'That should do it for now,' the soldier says with satisfaction. 'We'll mop up the rest tonight.' He turns to you. 'Don't worry. We'll soon have you with the others.'[paragraph break]'Others?'[paragraph break]'The other survivors. There's only a few, and some of them are severely wounded. Some real nasty bites on them, but they'll live.'[paragraph break]'Yes, they'll live,' you whisper, as the helicopter drones toward the sun.";
	end the game saying "You survived the night.";
	
The distant helicopters are in the belfry. "A half-dozen dots swarm the skies along the perimeter of your town. Helicopters, judging by their tempestuous drone." The description of the distant helicopters is "They seem to be patrolling the outskirts of town."

The crater is scenery in the belfry. The description of the crater is "[italic type]It[roman type] came from the skies, from [italic type]up there[roman type]. What it was, you don't know. You never saw it. Everything started to change within hours of its landing. Every[italic type]one[roman type] started to change. Everyone except the two of you."

After examining the crater for the first time:
	say italic type;
	say "'Back from the honeymoon already?' your friend, who you happened to run into while you were out, asks.[paragraph break]'Just last night,' she answers from the passenger seat.[paragraph break]'Well, it's good to have you--What the Hell is that?'[paragraph break]Something drops from the heavens in a fiery rage, exploding in the center of town. The screams start immediately.";

The Nave is west of the Chancel. "Eerily silent now, not like last night, when the rafters echoed with the groans and howls that emanated from outside. Shadows rule here, lounging among the pews, free of the sunlight that cloaks the chancel to the east. Double doors to the west normally lead outside, but they are blocked by several heavy benches piled against them."

The distant chancel is scenery in the nave. Understand "sunlight", "sun", "light", "altar", "chancel" as the distant chancel.

The rafters are scenery in the nave. The description of the rafters is "Shadows play among them, flit to and fro." Understand "ceiling" as the rafters.

The shadows are scenery in the nave. The description of the shadows is "They coat the pews and rafters."

After examining the shadows for the first time:
	say italic type;
	say "'Dear God,' she nearly screams. 'Did you see that? Over there, in the alley.'[paragraph break]'No.' You're too busy driving, and the power has gone out, leaving everything is midnight shadows. You should be passing the church soon.[paragraph break]'I don't think... I don't think they're... human...'[paragraph break]Two shadows leap from the darkness into your headlights. You slam on the brakes... Too late... The windshield shatters...";

The double doors are a door. The double doors are west of the Nave. The double doors are closed. The double doors are locked. The double doors are scenery. The description of the double door is "They are blocked by several heavy benches. You and she put them there. To keep [italic type]them[roman type] out.";

After examining the double doors for the first time:
	say italic type;
	say "'Get in! Get in!' you scream.[paragraph break]With a cry of her own, she slips through the door. Out of the corner of your eye, you notice the left sleeve of her shirt is torn, but think nothing of it. You throw the latch just as something from outside crashes into the door.[paragraph break]'They won't hold,' she says, terrified.[paragraph break]Quickly, you look around. 'The pews. The benches,' you say, breathlessly. 'We'll use them.'";
	
Instead of opening the double doors:
	say "The benches are in the way.";

The heavy benches are scenery in the Nave. The description of the heavy benches are "They once formed the back few rows of the pews. Now they are piled high as a barricade against the doors.";

After examining the heavy benches for the first time:
	say italic type;
	say "'Help me,' you say. 'I can't move them on my own.'[paragraph break]Together, you and she manage to move several of the pews across the floor and pile them against the double doors, which continue to shudder in a metronomic beat.[paragraph break]'I think it will hold,' you say, facing her. That's when you notice. 'What happened to your arm?'"; 

Instead of pushing the heavy benches:
	say "They're too heavy to move by yourself. You needed her help last night to form the barricade.";
	
The pews are scenery in the nave. The description of the pews is "Row upon row extend from the back of the nave to the altar. They are empty, save for where she sits. At the end of one row is a holy water font."

Instead of pushing the pews:
	try pushing the heavy benches;

The holy water font is scenery in the nave. The holy water font can be twisted. The holy water font is not twisted. The description of the holy water font is "A small, wooden half-bowl fixed to the end of the pew. It's usually filled with holy water. Empty now. It also seems a little loose.";

After examining the holy water font for the first time:
	say italic type;
	say "'I'm thirsty,' she says. She sounds tired. She's breathing heavily, too.[paragraph break]'Here,' you say. 'I found this. Remember, there's the wine.'[paragraph break]'No. I'd much rather have this.' She drinks the water from your cupped hands, water you found in the font on the pews. Her lips feel damp, clammy. 'Augh,' she says. 'Wretched. I can only imagine how long that's been sitting around.'";
	
Instead of taking or pulling the holy water font:
	say "You pull on it, but it doesn't move outward. You may be able to turn it.";

Instead of pushing the holy water font:
	try turning the holy water font;
	
Instead of turning the twisted holy water font:
	say "It doesn't seem to want to move anymore.";
	
Instead of turning the holy water font:
	say "It takes some effort. You twist the bowl clockwise, revealing a small nook in the pew... from which drops a brass key. The font slides back into place.";
	move the brass key to the nave;
	now the holy water font is twisted;
	
The brass key is a thing. The brass key unlocks the oak door. The description of the brass key is "A large brass key."

The silent woman is woman in the nave. "She sits silently in the front row, hands serenely folded upon her lap." Understand "woman", "her", "she", "wife", "hair", "skin", "my wife" as the woman. The description of the silent woman is "It's barely been hours, yet death has started to rob her of her beauty. Her skin, once vibrant, now pale and taunt. Her long hair, once luxurious, now seems waxy. There's a wound beneath the tattered sleeve of her left arm, and a congealed dot mars her forehead."

The congealed dot is part of the silent woman. The description of the congealed dot is "It's not a dot. It's a hole. The wound where the bullet entered her head." Understand "forehead", "brow", "hole" as the congealed dot.

After examining the congealed dot for the first time:
	say italic type;
	say "She holds your hand. Your hand holds the revolver.[paragraph break]'Please don't make me do this,' you whisper. The barrel of the gun trembles against her forehead. [paragraph break]'I can't do it alone,' she says, a tear dotting her cheek. 'And I don't want to become one of them.' She gently guides your index finger to the trigger. 'Please do this for me.'";

The wound is part of the silent woman. The description of the wound is "Teeth marks. Possibly human. It's difficult to tell. Congealed rivulets stream from where the teeth punctured the skin." Understand "arm", "left arm", "sleeve", "tattered sleeve", "marks", "teeth marks", "rivulets", "congealed rivulets" as the wound.

After examining the wound for the first time:
	say italic type;
	say "'They bit me or clawed me,' she says, as you inspect the wound. It seems worse than before. Her skin... so cold. 'I'm infected, aren't I? I'm going to become one of them.'[paragraph break]'You don't know that,' you say.[paragraph break]'I do. I can feel it. You can, too, can't you?'[paragraph break]You say nothing, but yes, yes you can.";
	
The silent woman's hands are part of the silent woman. The description of the silent woman's hands is "They are folded peacefully on her lap, just as you left them."

The revolver is a thing in the Nave. "Lying next to her is a discarded revolver." The description of the revolver is "There are no bullets in the chamber." Understand "chamber" as the revolver.

After examining the revolver for the first time:
	say italic type;
	say "'I never understood why you had that thing in the car,' she says, collapsing on the pew. 'Now I'm glad you have it.'[paragraph break]'It was my father's,' you say. You inspect the weapon's chamber. 'One bullet,' you note, miserably. 'Not going to do us a whole lot of good if they get in here.'[paragraph break]She reaches out and touches you. 'They won't get in,' she insists, then winces. 'My arm,' she murmurs. 'It feels funny.'";
	
The player is on the altar. The player is wearing your wedding ring. The description of your wedding ring is "A solid band of gold. There's an inscription on the interior, which you can't see while you are wearing it, but you know what it says: 'Heaven sent her to me.'";

After examining your wedding ring for the first time:
	say italic type;
	say "She clutches your hand while staring up at the stained-glass windows. Her grip is tight--you can feel your wedding band digging into your flesh.[paragraph break]'Why didn't we change?' she wonders. 'Why didn't we change like everyone else?'[paragraph break]'I don't know. Maybe, maybe it's because we picked up some kind of bug while we were away in the Caribbean. Maybe it's just in our DNA. I don't know.'[paragraph break]'I don't want to become like that,' she says. 'Promise me that I won't become like them.'[paragraph break]'I promise,' you say, squeezing her hand.";
	
Instead of taking off your wedding ring:
	say "No, you don't want to. It's probably the only memento you will have of her when this is all over.";
	
Instead of examining yourself:
	try taking inventory;
	
