"course correction" by Lucian Smith

The story headline is "An Interactive High Heist"

Release along with cover art and the source text and a file of "Rough outside map." called "Aerie map.png".

The release number is 1.

After printing the banner text, say "For more information, try ABOUT and CREDITS."

Include Response Assistant by Aaron Reed.
Include Version 7.1.1 of Hybrid Choices by AW Freyr.
Include Basic Screen Effects by Emily Short.

Use the American dialect, serial comma, and VERBOSE room descriptions.

[Include Rules and New Actions by Iron ChIF.]

[Rules and New Actions by Iron ChIF begins here.
Use authorial modesty.]

Book 0 Rules

To say i:
	say "[italic type]";
	
To say b:
	say "[bold type]";
	
To say r:
	say "[roman type]";

To say lb:
	say "[line break]";

To say pb:
	say "[line break][line break]";
	
To say nb:
	say "[run paragraph on]";

To say bstars:
	say "[lb]";
	center "*    *    *[pb]";

To say stars:
	center "*    *    *[pb]";



Chapter New Actions

Section Commenting

Commenting is an action out of world applying to one topic.

Report commenting:
	say "Noted.";[: [the topic understood].";]
	stop the action.

Understand "# [text]" as commenting.

To say comment_regex:
	say "<\p*#+=[']>"

After reading a command when the player's command matches the regular expression "^([comment_regex] ?)\S":
	let T be the "[player's command]";
	replace the regular expression "^[comment_regex] ?" in T with "# ";
	[say "(changed to '[T]')";]
	change the text of the player's command to T;

Section credits

Crediting is an action out of world applying to nothing.  Understand "credits" as Crediting.

Carry out Crediting:
	say "This game would not have been possible without the intense energy of @otistdog on the intfiction forums creating the idea of having an 'Iron ChIF' competition, nor without Ryan Veeder agreeing to be the aforementioned 'Iron ChIF Inform 7' to compete against.
	
	Particular thanks go to my betatesters, Sarah Willson (day 1), Stephen Granade (day 2), Allyson Gray (day 3), and Dan 'inky' Shiovitz (day 4).
	
	Thanks also to the official judges for this competition: Chandler Groover, Victor Gijsbers, J. J. McC, Brian Rushton, and N. Cormier, and technical advisor Zed Lopez.  You all have been great!

	The cover art image is courtesy Greg Hume (Greg5030)/CC BY-SA 3.0
	
	Apologies to N. Cormier for letting her cats out backstage.  I forgot to check the spotlights!"

Section about

Abouting is an action out of world applying to nothing.  Understand "about" as abouting.

Carry out abouting:
	say "First: a word about design philosophy.  The game has sub-optimal endings, but by design they are all avoidable with a single >UNDO.  There may be bugs that circumvent that design!  So keep multi-undo and/or save files at the ready.	
	
	This game was written in five days for Episode One of Iron ChIF, where I (as the challenger) wrote this game while Ryan Veeder (the 'Iron ChIF Inform 7') wrote his own game.  Extensive discussion and commentary from that episode can be found on the intfiction.org web site, at
	
	https://intfiction.org/t/iron-chif-season-one-episode-1-lpsmith-vs-afterward-using-inform-7/78122

	and
	
	https://intfiction.org/t/iron-chif-season-one-episode-1-audience-commentary/79065/

	The source code can be found at

	https://github.com/luciansmith/IronChIF/[lb]"

Section Summoning mist

A room can be cloudy or clear.  A room is usually cloudy.

The grey mist is a backdrop.  The description is "Grey mist swirls and surrounds you, covering you like a blanket."  Understand "cloud/clouds/gray/fog" as the grey mist.

When play begins:
    move the grey mist backdrop to all cloudy rooms.

The grey mist has a number called thickness.  The thickness of the grey mist is 1.

To say mist density:
	if the thickness of the mist is less than 4:
		say "thin ";
	otherwise if the thickness of the grey mist is less than 8:
		say "";
	otherwise if the thickness of the grey mist is less than 12:
		say "thickening ";
	otherwise:
		say "heavy ";

Summoning is an action applying to one thing.  Understand "summon [something]" as summoning.

Check summoning something:
	if the noun is not the grey mist and the noun is not the no_mist:
		say "You're a Bostrat: you can summon mist and clouds, but nothing else." instead.

Carry out summoning:
	if no_mist is in the location:
		now the location is cloudy;
		update backdrop positions;
		move no_mist to the Void;
		say "[one of]Calling on your heritage as a Bostrat, you summon moisture from the air, and it slowly coalesces into a creeping grey mist, obscuring you from sight.  In gentler times, you would be doing this to ensure the growth of the fields and forests; now you must use it to hide from prying eyes that would keep you from your quarry[or]You summon an obscuring grey mist to surround you and hide you from prying eyes[stopping].
		
		You stop at the natural inflection point for clouds given today's weather.  You could make it thicker still, but it would then start to dissapate.";
	otherwise:
		if the thickness of the grey mist is greater than 12:
			now the thickness of the grey mist is 15;
			say "That's as thick as you can make the mist--there's simply no more water to pull into the air.";
		otherwise:
			if the thickness of the grey mist is at least 10:
				now the thickness of the grey mist is 15;
			otherwise if the thickness of the grey mist is at least 7:
				now the thickness of the grey mist is 12;
			otherwise if the thickness of the grey mist is at least 4:
				now the thickness of the grey mist is 9;
			otherwise:
				now the thickness of the grey mist is 6;
			say "You draw even more moisture into the air, and feed it into the mist.  As it thickens, you feel safer, as you always do in the midst of clouds.";

Mist depletion is a recurring scene.  Mist depletion begins when the thickness of the grey mist is greater than one.  Mist depletion ends when the thickness of the grey mist is one.

Every turn during Mist depletion:
	decrease the thickness of the grey mist by one;
	if the thickness of the grey mist is one:
		say "Your summoned mist thins back to equilibrium.  Still thick enough to mostly obscure you.";
	otherwise if go go go is happening:
		decrease the thickness of the grey mist by one;
		say "The mist thins more rapidly than normal[if the thickness of the grey mist is one], back to equilibrium again[end if].";
	otherwise if the thickness of the grey mist is 3 or the thickness of the grey mist is 6 or the thickness of the grey mist is 9 or the thickness of the grey mist is 12:
		say "Your summoned mist thins slightly, on its way back to equilibrium.";
	[say "Thickness: [the thickness of the grey mist].";]

Diving is an action applying to nothing.  Understand "dive" as diving.
Before diving:
	Try going down;

Ascending is an action applying to nothing.  Understand "ascend" as ascending.
Before ascending:
	Try going up;

Descending is an action applying to nothing.  Understand "descend" as Descending.
Before Descending:
	Try going down;

Xyzzying is an action applying to nothing.  Understand "xyzzy" as xyzzying.
Report xyzzying:
	say "Legends say that the capsa of movement contained such a scroll, but it was lost years ago.  An itinerant troubador once told a tale at the royal court of a Magpie Clan woman who saw the open capsa materialize on her table one morning, and grabbed it just in time to be transported with it to its next location.  She had many fanciful adventures until, years later, it finally took her home again.  She opened the capsa and let it go, hoping that another would have adventures like hers."

[Understand "fly" as going something.] [Well!  An I7 'abject failure' bug!  Woo!]

Check jumping:
	say "Pfaugh!  Jumping is for fledglings!" instead;

[Rules and New Actions ends here.]

[Include Map by Iron ChIF.]

[Map by Iron ChIF begins here.
Use authorial modesty.]

Book Map

The Void is a room.  [I like having an 'off stage' room for stuff.]

Section High Above

High Above the Royal Aerie is a clear room.  "[if cloudy]Your summoned mist both obscures you and blocks you from seeing the Royal Aerie.  But you've already memorized its layout,[otherwise]You drift in lazy circles well above the Royal Aerie below, safely above your quarry.  Your acute eyesight lets you see the entire layout,[end if] and how it relates to today's air currents, winds, and thermals.  Royal Quarters to the north, well defended by circling Raven clan guards.  The librum to the east.  In the center of the Aerie (and directly below you) is the Great Hall.  Other royal aeries dot the forest in the distance, but this complex holds your quarry."

distant_aerie is scenery in high above.  The printed name is "Royal Aerie".  The description is "[if the grey mist is in the location]As you recall, the[otherwise]The[end if] Royal Aerie was grown and shaped by generations of Throckwrights, and now towers over the surrounding forest canopy.  Lush shades of browns and reds, often woven together in intricate patterns or pictures, cover every landing cradle, wall, and roof."  Understand "royal/aerie/lush/brown/browns/red/reds/woven/patterns/pictures" as distant_aerie.

distant_quarters is scenery in high above.  The printed name is "Royal Quarters".  The description is "[if the grey mist is in the location]As you recall, the[otherwise]The[end if] Royal Quarters is where the Queen and her family, servants, and certain privileged royalty live.  Every huge common room; every small or large individual apartment is awash in greenery that looks incredibly inviting and imperially homey, and is in reality subtly precisely hostile to the uninvited.  Every roof pitch is too steep; no branch nor ridge is graspable by talons of any size.  The single landing cradle in the middle of the gardens is surrounded by stern and beautiful tree crowns, beset with nooks and crevices for unseen guards and archers: attempting to land there would mean instant death for any but those who belong."  Understand "royal/quarters/queen/family/servants/royalty/common/room/apartment/small/large/roof/pitch/branch/ridge/landing/cradle" as distant_quarters.

distant_guards is scenery in high above.  The printed name is "circling guards".  The description is "The last time you were here, the aerie was not nearly on such high alert.  Now there's guards everywhere, but especially focused on circling the Royal Quarters.".  Understand "raven/circling/guards" as distant_guards.  Understand "raven clan" as distant_guards.

distant_librum is scenery in high above.  The printed name is "Librum".  The description is "[if the grey mist is in the location]As you recall, the[otherwise]The[end if] Librum was your target the last time out, and where you obtained the capsae you brought back with you. Its landing cradle is simply decorated, grown with interlocking redwood and pine in a way that suggests shelves of books.  The reading nooks grown into the sides of the main building proved a reasonable entrance for a creative supplicant; no doubt that method will have been shut down by now."  Understand "librum/landing/cradle/reading/nooks" as distant_librum.

distant_great_hall is scenery in high above.  The printed name is "Great Hall".  The description is "[if the grey mist is in the location]As you recall, the[otherwise]The[end if] Great Hall is by far the largest building in the Aerie complex, and indeed the largest building you've ever seen in your life.  If the stories are true, its planning took three years, and its growth was overseen by three [i]generations[r] of Throckwrights.  Every Royal Throckrite since has sought to put their own personal stamp on the Great Hall, leaving it more than a little haphazardly grown by now, but its current form is still impressive, even as it grows less coherent with every new modification."  Understand "great/hall/largest/building/growth/haphazard/haphazardly/coherent/incoherent" as distant_great_hall.

distant_others are scenery in high above.  The printed name is "other aeries".  The description is "[if the grey mist is in the location]As you recall, the[otherwise]The[end if] other aeries collectively make up the Royal Complex, each mostly grown by a single corps of Royal Throckwrights at some point in your people's history.  But this one is the most important.  The Scroll of Health is here. Somewhere."

no_mist is scenery in high above.  The printed name is "mist".  The description is "The cloud layer today is too high for a naturally obscuring mist; you'll have to summon it yourself.".  Understand "cloud/layer/mist/high/Heathcliff" as no_mist.

After dropping something in High Above:
	say "[The noun] twists away as it falls below you, towards the Great Hall.";
	Now the noun is in the Great Hall Landing Cradle.

Check dropping something during Everything Falls:
	if the gold capsa is enclosed by the location:
		if the noun is the gold capsa or the noun encloses the gold capsa:
			move the noun to the location;
			say "You let go of [the noun].  It remains floating in the air, exactly where you left it.  You push it to a slightly less conspicuous location." instead;
		otherwise:
			move the noun to the location;
			say "You let go of [the noun].  It falls towards the gold capsa and rests there." instead;
		stop the action;


Check going somewhere from High Above:
	if no_mist is in the location:
		say "[one of]If you get any closer to the aerie without summoning mist first, the guards would surely see you.  It's why, as a Bostrat, you were originally chosen to go on this mission[or]You'll need to SUMMON MIST first, to cloak your descent[stopping]." instead.

[Trivia:  'Bostrat' comes from 'Nimbostratus' clouds, aka rain clouds.]

After going from High Above:
	if Starting Off is happening:
		say "You descend in wide circles, pulling mist down with you in what you hope is a sufficiently unsuspicious manner, trusting your memorization of the air currents to tell you where you're going...";
	otherwise if the player contains an open gold capsa:
		say "You descend towards the Aerie, though it feels like you're flying upwards, against the pull of the scroll of down.";
	otherwise if go go go is happening:
		now Constance is super-fast;
		say "You dive blindingly fast towards the Aerie through the fog, and the mist swallows you with nary an eddy.";
	otherwise:
		now Constance is speeding;
		say "You tuck in your wings and dive down [if the noun is not down][noun][end if ] towards the Aerie, thrilling to the misty wind streaming through your feathers.";
	continue the action;

Starting Off is a scene.  Starting Off begins when play begins.  Starting Off ends when the player is not in High Above.

Instead of going nowhere from High Above:
	if the noun is up:
		if Being Chased is happening:
			say "You take to the skies even higher.";
			If the closeness of Being Chased is at least 3:
				Now the closeness of Being Chased is 2;
				Now the starting_line of Being Chased is the Void;
		Otherwise:
			say "You're already high enough to avoid being seen from below; there's no need to go higher.";
	otherwise:
		say "From here, you can descend straight down to the Great Hall, descend northward to the Royal Quarters and Gardens, or descend eastward to the Librum.";

Check opening a capsa when no_mist is in the location:
    say "Before you mess with powerful artifacts from the dawn of civilization, you should probably conceal yourself.  You're a Bostrat; the plan was to summon a mist." instead;


Section Great Hall

Great Hall Landing Cradle is below High Above.  "The Landing Cradle of the Great Hall spreads out over nearly a quarter of the vast building.  During your time here, you learned this was so that when a number of important guests and their retinues arrive at the same time, they can land simultaneously, instead of one after the other, which some would invariably take as meaning 'in order of importance'.  The [Great Hall doors] are on the west side of the landing cradle, and unguarded.

To the north is the Royal Quarters and Gardens, the Librum to the east, and as always, you can return to the skies or descend to the forest."

The Great Hall doors are a door in Great Hall Landing Cradle.  The printed name is "huge double doors of the Great Hall".  They are closed and locked.  They are inside from Great Hall Landing Cradle and outside from Upper Great Hall.  The description is "The huge double doors are canted hatches that lead from the giant landing cradle into the Great Hall itself.  They are adorned with fine scrollwork whose broad swoops and curls branch off into even finer swoops and curls, even down to the level of detail that only a Falcon Clan like yourself could see.  The Throckrian who grew this must have been an archmaster."  Understand "huge/door/double/canted/hatch/hatches/fine/scrollwork/broad/swoops/curls/branch/finer/giant/landing/cradle" as the Great Hall doors.

Check entering Great Hall doors during Being Chased:
	say "You fly through the door, and immediately regret your decision.  In an instant, the Raven Guard has followed you, and you simply don't have any room to maneuver.";
	end the story saying "You have been captured.";

Before going inside from Great Hall Landing Cradle:
	try entering Great Hall doors instead;

Instead of going nowhere from Great Hall Landing Cradle:
	if the noun is west, try entering the Great Hall doors;
	otherwise say "From here, you can go north to the Royal Quarters and Garden, east to the Librum, enter the Great Hall itself, or, as always, ascend to the skies or descend to the forest."

Upper Great Hall is a room. "There is a small platform just inside the [Great Hall doors], and that's it.  The platform is lined with a single elegant grown-mahogany branch that wraps around the whole platform.  It varies in size and thickness, so that all types of feet fit somewhere along it, so people can comfortably launch themselves into the air to glide down to the floor level, or grab it for stability as they return."

The platform is scenery in Upper Great Hall.  "The grown mahogany branch around the platform is a masterpiece of Throckwright engineering.  Not a single delegate or guest ever had problems looking regal as they launched themselves from an appropriate spot."  Understand "grown/mahogany/branch/masterpiece/spot/feet/grown-mahogany/elegant" as the platform.

Instead of going nowhere from upper great hall:
	if the noun is up:
		Try entering the Great Hall doors;
	otherwise if the noun is east:
		Try entering the Great Hall doors;
	otherwise:
		say "From here you can go down, or back out to the west.";


Down from Upper Great Hall is Lower Great Hall.

Report going down from Upper Great Hall:
	say "You step on to your favorite spot on the mahogany branch, and launch yourself downward in a graceful glide.";

Lower Great Hall is a room.  "When not prepared for a particular occasion, like now, the floor of the Great Hall is cleared of everything extraneous.  The exposed floor is absolutely exquisite, with swooping lines interspersed with starbursts, all in multicolored woods of all hues.  What doesn't change about the Great Hall floor is the display nooks along the sides: at least twenty nooks containing all manner of artifacts from around the world."

Various artifacts are scenery in Lower Great Hall.  The description is "Old things, new things, distant things, close things." Understand "old/things/new/distant/close/nooks/twenty" as various artifacts.

[LS DEBUG:  MAYBE allow 'various artifacts' to respond to 'cloaks' in case someone replaying the game tries to look for the cloaks before they show up.]

The two cloak posts are fixed in place in Void.   Understand "ancient/hunting/post" as two cloak posts.  [The description is "[what's on the posts]"]

Rule for printing a locale paragraph about the posts:
	say "In one of the nooks are two posts, designed for displaying ancient hunting cloaks";
	if the cloak is in the posts:
		if the cloak is purple:
			say ", with two purple hippotomai cloaks hung from them.";
		otherwise:
			say ".";
	otherwise:
		say ".";
	now the posts are mentioned;
	rule fails;


Check examining the posts:
[To say what's on the posts:]
	if the cloak is in the posts:
		if the cloak is purple:
			say "Two purple cloaks" instead;
		otherwise:
			say "Two posts for displaying cloaks." instead;
	otherwise:
		say "Two posts for displaying cloaks." instead;

Instead of touching the two cloak posts:
	if the hunting cloak is on the posts:
		snatch the cloak;
		rule fails;

Check taking the cloak:
	if the cloak is on the two cloak posts:
		snatch the cloak instead;

Check touching the cloak:
	if the cloak is on the two cloak posts:
		snatch the cloak;
		rule fails;

To snatch the cloak:
	if the cloak is on the two cloak posts:
		move the cloak to the player;
		if the cloak is invisible:
			say "You reach for the post, and feel the cloak you saw.  With a sense of wonderment, you pick it up.  Next to you, Horatio picks up the other, equally-invisible cloak.";
		otherwise:
			say "You reach out and pick up the cloak.  It seems none the worse for wear from having been invisible.  Next to you, Horatio picks up the other.";



The hunting cloak is a wearable on the cloak posts.  The hunting cloak can be purple or invisible.  The hunting cloak is purple.  The description is "[hunting cloak description]."  Understand "hippo/hippotomai/dark/purple/variegation/camoflage/cloaks" as the hunting cloak.  The printed name of the hunting cloak is "[if the hunting cloak is purple]purple[otherwise]invisible[end if] hunting cloak".

To say hunting cloak description:
	if the hunting cloak is on the cloak posts:
		if the hunting cloak is purple:
			say "A plaque by the cloaks claims that in prehistoric times, people made these cloaks out of hippotomai skins to mask their scent.  The dark purple variegation also helped with camoflage.  You couldn't fly with them on, but some prey had gotten extremely adept and spotting flying enemies, so hunters took to sneaking up on foot";
		otherwise:
			say "The cloak posts appear to be empty";
	otherwise:
		if the hunting cloak is purple:
			say "In prehistoric times, people made these cloaks out of hippotomai skins to mask their scent.  The dark purple variegation also helped with camoflage.  You couldn't fly with them on, but some prey had gotten extremely adept and spotting flying enemies, so hunters took to sneaking up on foot.  On foot!";
		otherwise:
			say "You can feel the supple folds of the cloak, but cannot see it at all";


Does the player mean doing anything with the hunting cloak:  it is very likely.

Check wearing the cloak:
	if the location is in_forest:
		say "You wouldn't be able to fly back up!" instead;
	if the location is High Above:
		say "Might I remind you that you can't fly with that cloak on?  And that you are currently [i]very high[r] in the air?" instead;

Section Librum

Librum Landing Cradle is east of Great Hall Landing Cradle.  "The Landing Cradle of the Librum is beautifully set with interlocking redwood and pine, suggesting shelves of books.  The [Librum Door] leads inward to the Librum itself.

To the west is the Great Hall, and to the northwest is the Royal Quarters and Gardens.  You can also re-ascend to the skies or descend to the forest below."

Up from Librum Landing Cradle is High Above.
Down from Librum Landing Cradle is in_forest.
East from High Above is Librum Landing Cradle.

Instead of going nowhere from Librum Landing Cradle:
	if the noun is east:
		try entering Librum Door;
	Otherwise:
		say "From here, the Great Hall is to the west and the Royal Quarters and Gardens are to the northwest.  You can also fly up again, or descend to the forest below."

Librum Door is a door in Librum Landing Cradle.  It is closed and locked.  It is inside from Librum Landing Cradle and outside from Librum Itself.  The description is "A canted [if open]open[otherwise]closed[end if] hatch to the Librum, on the east side of the landing cradle."

Check opening Librum Door:
	if the lone guard is in the location:
		say "The guard is entirely too watchful to let you do that." instead.

Check unlocking Librum Door with:
	if the lone guard is in the location:
		say "The guard is entirely too watchful to let you do that." instead.

Before going inside from Librum Landing Cradle:
	try entering Librum Door instead;

Check entering Librum Door during Being Chased:
	say "You fly through the door, and immediately regret your decision.  In an instant, the Raven Guard has followed you, and you simply don't have any room to maneuver.";
	end the story saying "You have been captured.";


Check entering Librum Door:
	if the lone guard is in the location:
		if Horatio is in the location:
			if Momentum is happening:
				say "Using the extra speed from your dive, you quietly plunge through the Librum door behind the distracted guard, pulling up sharply on the other side before crashing into anything.";
			otherwise if Super-Momentum is happening:
				say "With everything sped up, including (presumably) the guard's reactions, you try to be as precise as you can, entering exactly behind her, straight for the far corner of the door.  You needn't have bothered.  Horatio is talking a mile a minute, and his annoyingness level must have quintupled, as every feather on the guard's back is sticking out at various odd angles.  You swoop in and land inside with ease.";
			otherwise if the thickness of the grey mist is at least 10:
				say "The thicker mist conceals your gliding approach from the distracted guard, as you carefully glide in, tuck your wings in at the last second, and land quietly inside.";
			otherwise if Go go go is happening:
				say "Horatio's distraction patter has doubled in speed, which in and of itself is something to behold, but the guard's irritation factor seems to have quintupled in annoyance in response, which is, quite frankly, hilarious: every feather on the guard's back is sticking out at various odd angles.  You watch until the guard starts making a quiet keeing sound with her eyes closed, and you glide in from above and behind her, unseen.";
			otherwise:
				say "Horatio is distracting the guard by discussing [one of]the ethics of a monarchy[or]his grandchildren[or]regrettable fashion choices from the youth of today[or]whether the dot on the back of looks infected[or]how to get to moncrepistan (is that a real place?) from here[or]whether her mother was the Isabella he once knew[or]some meandering story about flying to the park[cycling], but you can't just [i]glide in[r]." instead;
		otherwise:
			say "The guard is entirely too watchful to let you do that." instead;
	otherwise if the location is Librum Itself:
		[*Leaving* the Librum.  We'll assume the guard and Horatio are still outside.  And, sigh, not make this a puzzle.]
		say "Listening to Horatio talk with the guard, you enter the shadows just inside the Librum door, where you can watch the guard but not be seen.  When the moment is right, you launch yourself through, and back up into the safety of the mist.";

Carry out entering Librum door during Being Chased:
	say "You fly through the door, and immediately regret your decision.  In an instant, the Raven Guard has followed you, and you simply don't have any room to maneuver.";
	end the story saying "You have been captured.";

Check closing the purple capsa of opening when the location is the Librum Itself:
	say "The guard would close the door again, and you'd be trapped!
	
	[i]Are you one of my testers?  It feels like you're one of my testers.  If you're not, you should be one of my testers.  Give me a call.  -LS[r][lb]" instead.

A lone guard is a woman in Librum Landing Cradle.  "A lone Raven guard stands in front of the door, dark eyes shifting as she watches the mist."  The description is "The raven guard wears the well-fitting uniform of the Queen's Guard, complete with a small red insignia on her shoulder.  The silvered knives on her talons are retracted while she stands, and golden razors line her beak[if the pile of tiny padlocks is in the Void].  Oddly, her uniform seems to be covered with... tiny closed padlocks?  That's not the insignia of any order you know[end if]."  Understand "raven/dark/eyes" as lone guard.

The well-fitting uniform is worn by the lone guard.  The description is "Her uniform consists of loose straps, designed to fit precisely under flagfeathers and provide support while not hampering movement nor flight.  The insignia on her shoulder reads 'Ikniq' under an icon of a tongue of fire: the logo of the fire warriors."  Understand "loose/straps/under/support/insignia/shoulder/ikniq/icon/fire/warrior/warriors" as well-fitting uniform.

Tiny closed padlocks are part of the well-fitting uniform.  The description is "Yes, those are definitely tiny padlocks, each attached to small leather loops stitched to her uniform.  You peer more intently.  The stitching where the loops attach is definitely newer than the stitching on the rest of the uniform.  They must have been added recently."

A small pile of tiny padlocks are in the Void.  "In the cradle next to the guard is a small pile of tiny padlocks, each open.";

Silvered knives are worn by the lone guard.  The description is "Silvered knives, retracted now, but extendable at will."  Understand "silver/retracted/retractable/extendable" as silvered knives.

Golden razors are worn by the lone guard.  The description is "The golden razors increase the Queen's Guard fighting abilities, allowing them to slash with their beaks as well as sharpening their bite."

answering the lone guard that something is talking your way past.
telling the lone guard about something is talking your way past.
asking the lone guard about something is talking your way past.
asking the lone guard for something is talking your way past.

instead of talking your way past:
	say "If you spoke at all, she would be on you in a heartbeat.";

Instead of attacking the lone guard:
	say "Against those talons?  Not a good idea.";

Instead of kissing the lone guard:
	say "You're not a huge fan of getting your beak slashed by razors.";

Instead of showing something to the lone guard:
	say "If you showed yourself at all, she would be on you in a heartbeat.";

Instead of giving something to the lone guard:
	say "If you showed yourself at all, she would be on you in a heartbeat.";

Instead of waking the lone guard:
	say "She's... not asleep?  I suppose you could awaken her to the idea of your presence, though that seems decidedly unhelpful.";


Librum Itself is a room.  The printed name is "Librum".  "The librum contains two levels of scrolls and books, with easy access to all of the curving shelves, and plenty of reading roosts with natural and artificial lighting.  You know from your childhood where the best roosts are, and what sections contain the most exciting stories.  In the center of the lower room is a lavish display case, now hastily boarded over, which three days ago held the purple, gold, and red capsae.  The [Librum door] is back up at the top level."

librum contents are scenery in Librum itself.  "The worst part about this room is the shadows of all the memories spent here in the company of the now-Queen."  Understand "two/levels/scrolls/books/access/curving/shelves/reading/roosts/natural/artificial/lighting/childhood/sections/exciting/stories/worst/shadows/memories/queen/now-queen" as the librum contents.

The lavish display case is scenery in Librum Itself.  "The boarded-over display case, like many of the shelves, was grown here as a permanent fixture.  It hasn't always displayed capsae, but there was always something to show off.  Well.  Until now."  Understand "boarded/over/boarded-over/display/case/grown/permanent/fixture" as the lavish display case.

Instead of going nowhere from the Librum Itself:
	If the noun is up:
		try entering the Librum Door instead;
	otherwise:
		say "You can exit the Librum by going up, out the door." instead;

Before going outside from the Librum Itself:
	try entering the Librum Door instead;

Instead of opening the display case:
	say "[one of]On a whim, you pull back a board to see if anything's in the display case.  There is.  Jewels and money.  At an estimate, maybe a quarter of the Queen's personal treasury.  You shake your head, disgusted.  Well, that's why this building was being guarded[or]You don't need [i]money[r].  What you're after is much more valuable to your community[stopping].";

Section Royal Gardens

Royal Gardens is a room. It is north of Great Hall Landing Cradle, and northwest of Librum Landing Cradle.  "The royal gardens is the most lavishly opulent and sensuous entrance to any aerie you've seen in your life.  Trees, vines, and flowers of every variety spring up from everywhere, each seemingly placed in it only appropriate spot.  The landing cradle next to the [garden door] to the Royal Quarters themselves is nestled between gracious arcs of poplar trunks, each bedecked with shaded and inviting roosts.  Which, as you know from your childhood days swooping and laughing through these gardens, invariably contain at least eight guards. 

From here, you can return to the skies or descend to the forest.  The Great Hall is to the south, and the Librum to the southeast."

Up from Royal Gardens is High Above.
Down from Royal Gardens is in_forest.
North from High Above is Royal Gardens.

Instead of going nowhere from Royal Gardens:
	say "From here, you can fly south to the Great Hall, or southeast to the Librum. The net prevents you from reaching the forest floor from here, but you can go straight up to the Great Hall, east (and up) to the Librum, or north (and up) to the Royal Quarters and Gardens."

The royal landing cradle is scenery in Royal Gardens.  The description is "The cradle's aesthetics have suffered somewhat from having to be re-grown every time the royal insignia changes, but it's still tastefully lavish."  Understand "aesthetics/insignia/opulent" as the royal landing cradle.

The poplar trunks are scenery in Royal Gardens.  The description is "The poplars around the landing cradle contain five guards that you can see (since you know where to look), and almost certainly another five that you cannot (since you know where you can't look)."  Understand "arcs/shaded/inviting/roosts/guards/eight/five/ten" as the poplar trunks.

garden door is a door in Royal Gardens.  It is closed and locked.  It is inside from Royal Gardens and outside from Palace.  The description is "A canted [if open]open[otherwise]closed[end if] hatch to the Royal Quarters, nestled in the center of the garden.  Absolutely surrounded by guards."

Check opening Garden Door:
	say "There are way too many guards for that to have any chance of working." instead.

Check unlocking Garden Door with:
	say "There are way too many guards for that to have any chance of working." instead.

Before going inside from Royal Gardens:
	try entering Garden Door instead;

Check entering Garden Door:
	If Sneaking is not happening:
		say "No way.  It wouldn't matter how fast you were, how thick the mist was, anything.  You just can't get in there without being spotted." instead;
	otherwise if the hunting cloak is purple:
		say "Not only would you be caught, but you'd be humiliated for your entire life for having to walk because you were wearing an ancient purple cloak." instead;
	otherwise:
		say "OK.  Walking.  Right.  You raise yourself up on the tips of your talons, feeling ridiculous, but not wanting to flatten the grass with your (shudder) footsteps and give yourself away.  You wait for one of the guards to pass, then carefully take cautious steps towards the door.  Nobody reacts.  Hardly daring to breathe, you proceed further, antsy and ready to take to the skies any second.  Which wouldn't work, because you have this damn cloak on.  Whatever.  Two more steps.  You reach the door.  You hop (shudder) across the lintel.
		
		You're in.
		
		A few more steps, and a voice behind you says 'We should take the second hallway.' You nearly yelp, but stop yourself.  You knew Horatio would be here.  You were expecting him.  Right.
		
		You take a deep breath.  'Lead on,' you whisper.
		
		'I can't; I'm invisible.  I will tell you where to go, and follow you,' he replies.  Right.[bstars]";
		wait for any key;
		clear the screen;
		say "You make your way, with Horatio's direction, through the Royal Quarters.  A time or two Horatio leads you to a place you'd have to fly to get past, but you know this place well, and even though you never walked anywhere, you still know the walking ways.  There's fewer guards to avoid than you expected, meaning that the Queen either has them all outside guarding the entrance, or she just doesn't have them to spare.
		
		As you get closer to your objective, a growing sense of unease forms in the pit of your stomach.  One by one, you pass all the places you pegged as most likely for it to be: the throne room, the vault, even storerooms.
		
		Then:  'This is it,' says Horatio.
		
		Oh no.";
		wait for any key;
		Move Horatio to Nursery_door; 
		Move the player to Nursery_door;
		stop the action;

Palace is a room.  "If you're seeing this, I either haven't finished writing the finale, or you found a bug.  Hopefully, you're a tester, and that's your job.  Thank you!  Come back for a later version with the finale!";

Nursery_door is a room.  The printed name is "Nursery Door".  "You're standing in a hallway, just south of the nursery door, to the west.  The door is open.  All the doors have been open.  You can't see inside yet.  Your heart pounds in your chest."

Instead of going nowhere from Nursery_door:
	say "The nursery is to the west.  The scroll of health is to the west.  [i]Health[r].  Taclor.";

Check going west from Nursery_door:
	if the hunting cloak is worn:
		say "'Horatio,' you whisper.  You feel a tap on your shoulder in response.  'I can't go in there wearing this cloak.  I just can't.'
		
		A pause.
		
		'Then take it off,' he replies." instead;

Carry out taking off cloak in Nursery_Door:
	say "Next to you, Horatio takes his own cloak off as well.";

Nursery_itself is a room.  It is west of Nursery_door.  the printed name is "Nursery".  "The Nursery is not exactly how you remember it.  It was set up to grow new walls and furniture over time, to keep any occupant engaged and growing.  But the rhythm of it is baked into your bones.  The place for the roosts, along the north wall.  The [desk], grown to the size of the user.  The endless parade of ropes and balls and other toys along the south, some grown and some brought in.  The giant [window] to the west, overlooking the beautiful, beautiful forest."

The roosts are scenery in Nursery_itself.  The description is "[You and aubrey] would swing from roost to roost, competing to see who could make the most jumps without opening your wings at all."  Understand "roost/north/wall" as roosts.

The_toys are scenery in Nursery_itself.  The description is "[You and aubrey] cycled through so many, many toys.  You would break one by accident, and she would imperiously demand new ones of the guards."  Understand "ropes/balls/rope/ball/south" as the_toys.

The window is an enterable supporter in Nursery_itself.  The description is "Absolutely the best view anywhere.  [You and aubrey] could watch a storm roll in across the sky for hours.  You learned how to enhance the storm to make it more dramatic based on Aubrey's excited trills." Understand "view/best/beautiful/forest" as the window.

The desk is a supporter in Nursery_itself.  The description is "It's smaller now than you ever remember it being.  You never knew her at that age." Understand "small/smaller/grown/user" as the desk.

[To see the capsa, see Pc and Rucksck.i7x!  Sigh.]

To say You and aubrey:
	say "[first time]You and the now-Quee--  No.  [only]You and Aubrey"



Section Forest Below

in_forest is a room.  It is below Great Hall Landing Cradle.  The printed name is "In the Forest".  "The trees below the Royal Aerie grow more closely together than in the rest of the forest, and include a wider variety, so that differently-colored woods could be incorporated into the buildings above.  This makes it harder to navigate down here--or it would if you weren't so amazing at navigation."

tree_varieties are scenery in in_forest.  The printed name is "trees".  The description is "Birch, pine, redwood, alder, ash, elm, poplar, and probably several other types as well."  Understand "Birch/pine/redwood/alder/ash/elm/poplar" as the tree_varieties.

A fine net is here.  It is fixed in place.  "Even through the mist, your sharp eyes spot a fine net, stretched between the trees.  It seems to be set to prevent anyone from coming up from the forest below."  The description is "A fine, strong net, stretched between and among the trees.  It wasn't here three days ago, which means they spent a lot of effort... to keep you on the Aerie-side of it.  You grin to yourself."

Check taking the net:
	say "Besides being way too large to carry, the net is attached firmly to the trees and branches, not allowing anything larger than a feathers-length through it[if cell door is open].  Though not, you notice, with knots that could be undone by the scroll of Opening.  Everything is just... folded.  Very deliberately[end if]." instead.

Up from in_forest is Great Hall Landing Cradle.
North from in_forest is Royal Gardens.
East from in_forest is Librum Landing Cradle.

Instead of going nowhere from in_forest:
	if the noun is down:
		say "The net prevents you from reaching the forest floor.  Fortunately, you're already where you want to be.";
	otherwise:
		say "The net prevents you from reaching the forest floor from here, but you can go straight up to the Great Hall, east (and up) to the Librum, or north (and up) to the Royal Quarters and Gardens.";

After going from in_forest:
	say "You gracefully flit between the trees back up [if the noun is north]north [otherwise if the noun is east]east [end if]above the canopy.";
	continue the action;

After going to in_forest:
	If Constance is super-fast:
		say "Your wings tighten close to your body as you rocket through the mist, your keen eyesight only barely sufficient to keep you from crashing into branches and trees[first time].
		
		It is, without a doubt, the most thrilling dive of your entire life.
		
		At the last second, you flare your wings, and feel like they're about to rip off of your shoulders.  You skim over the netting, your curved talons juddering across the lines, making your whole body tremble until you pull up again to dodge more tree trunks.  You allow yourself a triumphant cry, safe in the knowledge that nobody could catch you at these speeds.  Nobody[only].";
		continue the action;
	otherwise:
		if Constance is speeding:
			now Constance is super-fast;
		otherwise:
			now Constance is speeding;
			if go go go is happening:
				now Constance is super-fast;
				say "You dive into and through the forest, twisting expertly as you dodge trees and branches.  The fog closes behind you with a quiet 'shhhhmp', leaving no record of your passing.";
			otherwise:
				say "You tuck in your wings and dive down into the forest below the Aerie, dodging tightly-spaced trees with acrobatic precision.";
		continue the action;

[Map ends here.]

[Include PC and Rucksack by Iron ChIF.]

[PC and Rucksack by Iron ChIF begins here.
Use authorial modesty.]

Book Cast

Section Constance

Constance is a woman in High Above.  "Constance, a powerful Falcon Clan female, is here, her large black eyes watching you with fierce intensity."  The description of Constance is "As a member of the Falcon Clan, [your] most striking features are [your] large black eyes, offset with yellow, and slightly recessed under a grey-feathered scalp.  The grey blends from [your] head, mottling along [your] back and the backside of [your] wings, while [your] front, throat, and underwings are feathered white with brown striations[if the player is Constance].  A close encounter with a Raven during [your] previous mission left a few missing contour feathers and some down, but not enough to hinder movement or flight[end if]."  Understand "constance/powerful/falcon/clan/large/black/eyes/yellow/scalp/mottling/wings/throat/underwings/brown/striations/talons" as Constance.

To say your:
	if the player is Constance:
		say "your";
	otherwise:
		say "her";

[As might be predicted, the 'let's go with this for now' decision has been solidified in stone.]

The player is Constance.

[Note: I looked up 'famous falconers' and one of them was King Frederick II.  So I looked up his wife's name, found our there were at least four of them (!), and 'Constance' stood out to me as a good PC name.]

Constance can be wounded.  Constance is not wounded.

[The carrying capacity of Constance is 1.][Not sure about this--it would be strong motivation to turn off rezrov, though!]

A leather rucksack is a player's holdall worn by the Constance.  Understand "sack" as leather rucksack.

Section capsae and scrolls

A capsa is a kind of openable container.  A capsa is usually closed.  The plural of capsa is capsae.

Check taking something:
	if the noun is inside a capsa:
		say "Like all of the Ancient Scrolls, the scroll is inextricably tied to its capsa, and you can't extricate it." instead.

Check removing something from a capsa:
    say "Like all of the Ancient Scrolls, the scroll is inextricably tied to its capsa, and you can't extricate it." instead;

A scroll is a kind of a thing.  A scroll has a text called name.  The name of a scroll is usually "FOO".

Does the player mean doing something to a scroll:  it is likely.

Does the player mean opening or closing a capsa:  it is very likely.

The description of a scroll is "While '[name]' can be clearly read at the top of the scroll, the rest (or at least, the top few lines that you can see) is in some arcane script you [one of](and the people and sages of your village) were[or]are[stopping] unfamiliar with."

[LS DEBUG:  maybe change above to 'while you can see while it's rolled up', though then we'll need to implement 'roll/unroll scroll', so maybe later.]

Section rezrov

A purple capsa of opening is a capsa in the rucksack.  The description is "The purple capsa turned out to contain a scroll of opening[first time], as became evident when every buckle and lock in your village flew open when you opened the capsa to investigate[only].  It is [if the purple capsa of opening is closed]closed, preventing the power of the scroll from affecting the area[otherwise]open, allowing the scroll's power to open and hold open any closed object in the area[end if]."  Understand "rezrov" as the purple capsa of opening.

A scroll of rezrov is a scroll in the purple capsa of opening.  The name is "REZROV".  Understand "opening" as the scroll of rezrov.

Everything Is Open is a recurring scene.  Everything Is Open begins when the purple capsa of opening is open.  Everything Is Open ends when the purple capsa of opening is closed.

When Everything Is Open begins:
	carry out everything rezrovving;

To carry out everything rezrovving:
	say "As you open the purple capsa, an almost-palpable wave of force emanates from it, as the power of the revealed scroll of rezrov is released.[lb]";
	if the lone guard is in the location and the tiny closed padlocks are enclosed by the lone guard:
		say "As the shockwave of magic reaches the guard, the padlock on her uniform closest to you pops open.  Then in succession, all the other padlocks she's wearing pop open as well, in perfect concentric circles in order of how distant they are from the scroll.  As her eyes lock with yours, you realize, somewhat belatedly, that you've given her the ability to triangulate on your position.  Without hesitation, she breathes fire and leaps straight at you, before you even have time to let go of the capsa.
		
		The door behind her opens silently as she tackles you to the ground.";
		end the story saying "You have been captured.";
	Otherwise:
		repeat with item running through lockable things:
			if the item is locked:
				now the item is unlocked;
				if the player can see the item:
					say "[The item] clicks as it unlocks!";
		repeat with item running through openable things:
			if the item is closed:
				if the item is a capsa:
					if the player can see the item:
						say "The magic of [the item] prevents it from being opened.";
				otherwise:
					now the item is open;
					if the player can see the item:
						say "[The item] flies open!";
		if the rucksack is worn:
			say "The straps and buckles on your rucksack fly open and it falls!";
			now the rucksack is carried by the player;
			if Everything Falls is happening and the gold capsa is enclosed by the location:
				say "Fortunately, it hovers in midair due to the scroll of down, so you're able to immediately grab it again.";
			otherwise:
				try dropping the rucksack;
		If the reset state of the woodpeckers is 5:
			Now the woodpeckers are activated; [Starts the 'being chased' scene]
			Now the reset state of the woodpeckers is 0;

Check closing something openable during Everything Is Open:
	if the noun is not a capsa:
		say "Try as you might, a mystical force prevents you from closing [the noun]." instead.


Check locking something with during Everything Is Open:
	say "Try as you might, a mystical force prevents you from locking [the noun]." instead.

Check wearing the rucksack during Everything Is Open:
	say "A mystical force prevents you from fastening the buckles on the rucksack, and you are unable to put it on." instead.

Reset Sensors is a recurring scene.  Reset Sensors begins when Everything is Open ends.  Reset Sensors ends when the reset state of the woodpeckers is 5.

Every turn during Reset Sensors:
	if Everything Is Open is happening:
		now the reset state of the woodpeckers is 0;
	otherwise:
		increase the reset state of the woodpeckers by 1;
		if the reset state of the woodpeckers is 1:
			say "From everywhere in the Aerie, you hear the woodpeckers drumming in the Pounding dialect: 'Reset Locks!  Repeat!  Reset Locks!";
		if go go go is happening and the reset state of the woodpeckers is less than 5:
			increase the reset state of the woodpeckers by 1;
		
Doors Re-close is a recurring scene.  Doors Re-close begins when Everything Is Open ends.  Doors Re-close ends when cannot-close.

Every turn during Doors Re-close:
	if Being Chased is not happening:
		if the Librum door is open:
			now the Librum door is closed;
			if the player can see the Librum door:
				say "The guard closes the Librum door.";
		otherwise if the Librum door is unlocked:
			now the Librum door is locked;
			if the player can see the Librum door:
				say "The guard locks the Librum door.";
		[LS DEBUG:  revisit this if I implement other guarded doors at some point.]

To decide whether cannot-close:
    if Everything is Open is happening, decide yes;
    if the Librum Door is locked, decide yes;
    decide no.

Section down

The gold capsa of down is a capsa in the rucksack.  The description is "The gold capsa turned out to contain a scroll of Down[first time], as became evident in the disorienting moment when the sages first opened the capsa, and everyone and everything suddenly fell towards it[only].  It is [if the gold capsa is closed]closed, preventing the power of the scroll from affecting the area[otherwise]open, allowing the scroll's power to pull everything towards itself, instead of towards the ground[end if]."  Understand "rudenj" as the gold capsa.

A scroll of rudenj is a scroll in the gold capsa.  The name is "RUDENJ". Understand "down" as the scroll of rudenj.

Check dropping the gold capsa during Everything Falls:
	if Being Chased is happening:
		say "You could ditch the capsa and get away by using it as bait, but that would be just as bad as them catching you directly.  You need the power of this capsa to get the scroll of Health." instead;

Check dropping the rucksack during Everything Falls:
	if Being Chased is happening and the rucksack encloses the gold capsa:
		say "You could ditch the gold capsa and get away by using it as bait, but that would be just as bad as them catching you directly.  You need the power of this capsa to get the scroll of Health." instead;

['rudenj' from rudenį: 'fall' in Lithuanian.]

Everything Falls is a recurring scene.  Everything Falls begins when the gold capsa is open.  Everything Falls ends when the gold capsa is closed.

Cantedness is a kind of value.  The cantednesses are grounded and upended.

Everything falls has a cantedness.  The cantedness of Everything falls is upended.

When Everything Falls begins:
	if the gold capsa is enclosed by in_forest:
		now Everything falls is grounded;
		say "Immediately, 'down' now means 'towards the gold capsa' instead of 'towards the earth'.  Even being ready for it, it takes you a few flaps to reorient yourself, and you blink away the slight dizziness.  Then you pause.  No sounds from the Aerie.  Apparently, the new 'down' is close enough to the old 'down' that whatever sensors they have up there didn't detect a change.  Good.";
	otherwise:
		say "Immediately, 'down' now means 'towards the gold capsa' instead of 'towards the earth'.  After a brief moment of disorientation, you right yourself, wings pulling you 'up' with just enough force that you remain in one place.
		
		[i]Note: for convenience, 'down' and 'up' comands will continue to work as they did, referencing Earth-relative geography instead of gold capsa-relative geography[r].";
		now Everything Falls is upended;
		now the woodpeckers are activated;

Every turn during everything falls:
	if the gold capsa is enclosed by in_forest:
		now Everything falls is grounded;
	otherwise:
		now Everything Falls is upended;
		now the woodpeckers are activated;

When Everything Falls ends:
	if the woodpeckers are activated:
		say "You twist and right yourself as 'down' returns to its normal state[if the closeness of Being Chased is at least 2].  The Raven Guards struggle to right themselves again, but recover and continue their pursuit[end if].";
	otherwise:
		say "You steady yourself as 'down' returns to its normal state.";

Check taking when the player is Horatio:
	say "You don't need anything.  You just need to find the prodigal.";



[When Everything Falls begins:
	carry out everything rudenjing;
]
[To carry out everthing rudenjing:
	If the location is in_forest:
]

Section Hasten

The red capsa of hasten is a capsa in the rucksack.  The description is "The red capsa turned out to contain a scroll of hasten[first time], which you and the sages eventually determined when it became clear that everyone was acting as if they were high on guarana berries[only].  It is [if the red capsa is closed]closed, preventing the power of the scroll from affecting the area[otherwise]open, allowing the scroll's power to make everything happen much faster[end if]."  Understand "haste/quiste" as the red capsa.

A scroll of quiste is a scroll in the red capsa.  The name is "QUISTE".  Understand "haste/hasten" as the scroll of quiste.

[quiste: quick + haste]

Go go go is a recurring scene.  Go go go begins when the red capsa is open.  Go go go ends when the red capsa is closed.

When go go go begins:
	say "You speed up, and so does the wind.  You wriggle, feeling the delightfully fast responses from every muscle in your body.
	
	From everywhere in the Aerie, you hear the drumming of Woodpeckers in the Pounding dialect:  'Target is quick, repeat target is quick.  Remember you are too.'  Fortunately, it doesn't seem like they were able to triangulate on you.  Now you just have to be good at being faster than normal, against others who are also faster than normal, and who have had months to practice being fast.  No problem.";

When go go go ends:
	say "From everywhere in the Aerie, you hear the drumming of Woodpeckers in the Pounding dialect: 'Target is slow again, repeat, target is slow.'  Just in case they couldn't tell they were slow themselves.  Actually, you do recall some Raven Guards from your childhood that would have needed to be told.  Ah, poor James.";

Section Zork Grand Inquisitor Live Forever

A black capsa is a capsa in the Librum Itself.  "In the back of the lower level, in a storage cupboard, you find the black capsa, just as Horatio described to you.  You wonder how he managed to find out where it was, but suppose the man has his conversational tricks."  The black capsa can be explained.  The black capsa is not explained.  The description is "The black capsa contains a scroll of igram, [if the black capsa is explained]which apparently turns purple things invisible.  The only capsae you've heard of having an ability even vaguely like that, you assumed were jokes.  Now you're not so sure.[otherwise]but Horatio won't tell you what that means.[end if]  It is [if the black capsa is closed]closed, preventing the power of the scroll from affecting the area[otherwise]open, freeing the scroll's power[end if]."  Understand "igram" as the black capsa.

A scroll of igram is a scroll in the black capsa.  The name is "IGRAM".  Understand "make purple things invisible" as the scroll of igram.  Understand "invisible/invisibility" as the scroll of igram.

No More Purple is a recurring scene.  No More Purple begins when the black capsa is open.  No More Purple ends when the black capsa is closed.

When No More Purple begins:
	Now the hunting cloak is invisible;
	if the purple capsa of opening is visible:
		say "For a moment, the purple capsa seems to flicker.  But you look again, and nothing seems to have changed.";
	if the various artifacts are visible and the cloak posts are not in the location:
		Move the cloak posts to the location;
		say "Suddenly, two hunting cloaks in a display of ancient pre-historical artifacts disappear!";
	otherwise if the hunting cloak is on the cloak posts and the cloak posts are in the location:
		say "The hunting cloaks disappear again.";
	otherwise if the hunting cloak is visible:
		say "The hunting cloak disappears again.";

When No More Purple ends:
	Now the hunting cloak is purple;
	if the various artifacts are visible and the cloak posts are not in the location:
		Move the cloak posts to the location;
		say "Suddenly, two hunting cloaks in a display of ancient pre-historical artifacts appear!";
	otherwise if the hunting cloak is on the cloak posts and the cloak posts are in the location:
		say "The hunting cloaks appear again.";
	otherwise if the hunting cloak is visible:
		say "The hunting cloak appears again.";
	If the location is Nursery_Door:
		say "Horatio reappears, wearing the other cloak.";

A green capsa is an open capsa on the desk.  The description is "The green capsa of health contains a scroll of taclor.  It is [if the green capsa is closed]closed, preventing the power of the scroll from affecting the area[otherwise]open, allowing the scroll's power to heal to affect the area[end if]."  Understand "taclor/heal" as the green capsa.

A scroll of taclor is a scroll in the green capsa.  The name is "TACLOR".  Understand "make purple things invisible" as the scroll of taclor.  Understand "heal/health" as the scroll of taclor.


[PC and Rucksack ends here.]

[Include Lucian's Scenes by Iron ChIF.]

[Lucian's Scenes by Iron ChIF begins here.
Use authorial modesty.]

Book 0 Ongoing Effects

[Include Being Chased by Iron ChIF.]
[Being Chased by Iron ChIF begins here.
Use authorial modesty.]

Constance can be cruising, speeding, or super-fast.  Constance is cruising.

Momentum is a recurring scene.  Momentum begins when Constance is speeding.  Momentum ends when the time since Momentum began is two minutes.

When Momentum ends:
	if Constance is speeding:
		now Constance is cruising;
		say "The momentum you had from your dive wears off[if Being Chased is not happening].  Fun while it lasted![otherwise].[end if]";

Super-momentum is a recurring scene.  Super-momentum begins when Constance is super-fast.  Super-momentum ends when the time since Super-momentum began is three minutes.

When Super-momentum ends:
	if Constance is super-fast:
		now Constance is cruising.

Woodpeckers are people in the Void.  The description is "I dunno if you'll ever actually see these guys; they just sound the alarms from offstage."
Woodpeckers can be activated. Woodpeckers are not activated.
Woodpeckers have a number called reset state. The reset state of the Woodpeckers is 5.

The Raven Guard are people in the Void.  "Several members of the Raven Guard fly at you, as you dodge and circle to avoid them."  The description is "Black as night, apart from the silvered knives they wear on their talons, and the golden razors that line their beaks[if the librum landing cradle is visited].  It looks like the lone guard from the Librum has joined them: the [end if]."  Understand "guards/black/silvered/knives/talons/golden/razors/beaks/ravens/squad" as the raven guard.

answering the raven guard that something is talking your way out.
telling the raven guard about something is talking your way out.
asking the raven guard about something is talking your way out.
asking the raven guard for something is talking your way out.

instead of talking your way out:
	say "The Raven Guard will be happy to 'discuss things' with you after you are safely captured.";

Instead of attacking the raven guard:
	say "The Raven Guard are built for combat.  You are not.  You are built for speed and visual acuity.";

Instead of kissing the raven guard:
	say "The enemies-to-lovers trope works slightly better outside of an active combat scene.";

Instead of showing something to the raven guard:
	say "The Raven Guard will be happy to look at [the noun] after they've captured you and are going through your things.";

Instead of giving something to the raven Guard:
	say "The Raven Guard will be happy to look at [the noun] after they've captured you and are going through your things.";

Instead of waking the raven guard:
	say "They are [i]most decidedly[r] not asleep.";

Being Chased is a recurring scene.  Being Chased begins when the woodpeckers are activated.  Being chased ends when the woodpeckers are not activated.

Being Chased has a number called closeness.  The closeness of Being Chased is 0.
Being Chased has a room called starting_line.  The starting_line of Being Chased is the Void.

When being chased begins:
	Now the starting_line of Being Chased is the location;
	Move the lone guard to the Void;
	Move the tiny closed padlocks to the Void;
	say "From... well, from everywhere in the Aerie, it seems, Woodpeckers start drumming out messages in their Pounding dialect:  [if Everything Falls is happening and Everything Falls is not grounded]'Intruder!  The enemy is DOWN. Repeat!  The enemy is DOWN.'  You realize that creating a gravity well pointing straight at you might not have been the wisest move[otherwise]'Intruder! Estimated direction is...' and then each one individually seems to be telegraphing the direction from them to you.  You can't discern any one drummer from any other drummer, but you can at least tell that each seems to be drumming on sheets of metal that differ from each other, as the frequencies are all different from each other.  That makes the information somewhat useless to you, because you've not been trained to distinguish Pounding at different frequencies.  And because you already know where you are.  Sadly, the Raven Guards are indeed trained to distinguish Pounding frequencies.
	
	And if they didn't know where you were, they do now[end if].";

Constance can be quick-doing.  Constance is not quick-doing.

Before examining something during Being Chased:
	say "Lightning fast, you try to examine [the noun]:  [nb]";
	continue the action;

Every turn during Being Chased:
	If the current action is not examining:
		Increase the closeness of Being Chased by 1;
		[say "closeness: [the closeness of being chased].";]
		If the closeness of Being Chased is 1:
			If the thickness of the grey mist is at least 3:
				say "The mist you summoned begins to burn away.  Crap.  The queen must have Ikniq working for her now.[nb]";
				If the thickness of the grey mist is less than 7:
					now the thickness of the grey mist is 1;
					say "At least they can't burn it away past equilibrium.";
				Otherwise if go go go is happening and the thickness of the grey mist is less than 11:
					now the thickness of the grey mist is 1;
					say "At least they can't burn it away past equilibrium.";
				Otherwise:
					decrease the thickness of the grey mist by 6;
					if go go go is happening:
						decrease the thickness of the grey mist by 4;
					say "The mist is still thicker than it would be at equilibrium, but it's a lot less than it was.";
		If the closeness of Being Chased is 2:
			move the raven guard to the location;
			If the location is not the starting_line of Being Chased:
				If the starting_line of Being Chased is High Above:
					say "You've dived straight into a squad of Raven Guards, on their way up to accost you.  Fortunately, your speed helped you avoid most of them, but one guard's talon catches you on your side as you twist by them.";
					Now Constance is wounded;
				Otherwise if the starting_line of Being Chased is in_forest:
					say "Your ascent brings you right into a squad of Raven Guards, on their way to accost you.  You see them only barely before they see you, and it's just enough to mostly avoid them.  Still, a slash from a Raven Guard beak catches you in the side as you twist past.";
					Now Constance is wounded;
				Otherwise:
					say "You've barely left [the starting_line of Being Chased] when a squad of Raven Guards wheels in from behind, hot on your tail!";
			Otherwise:
				say "A squad of Raven Guards appears, and their war cries exalt as they spot you.  You weave through the air, tumbling and twisting as you try to avoid them.";
			Now the starting_line of Being Chased is the location;
		Otherwise if the closeness of Being Chased is at least 3:
			move the raven guard to the location;
			If the starting_line of Being Chased is not the location:
				Now the starting_line of Being Chased is the location;
				Now the closeness of Being Chased is 2;
				determine evasion;
			Otherwise if the closeness of Being Chased is 3:
				say "The guards charge, but you manage to evade their uncoordinated attack.";
			Otherwise if the closeness of Being Chased is 4:
				say "Two guards snap at you, and while both touch nothing but feathers, a third slashes you with his silvered talons.  They're about to overwhelm you.";
				Now Constance is wounded;
			Otherwise:
				say "You're faster and more maneuverable than they are, but there are more of them.  One charges you directly, and when you veer off to avoid her, another crashes into you.  The rest swarm you instantly.";
				end the story saying "Your luck has run out.";

[Note: 'Ikniq' actually means 'Fire' in Iñupiaq.  According to The Internet.]

To determine evasion:
	If Everything Falls is happening and Everything Falls is upended:
		say "You dodge and weave and almost get away from your pursuers, but when 'down' always points straight at you, even when they can't see you, they always know where you are.";
	Otherwise if Super-Momentum is happening:
		say "You expertly twist at breakneck speeds, weaving through three Ash trunks, over a branch, and around and behind a Redwood, where you halt, twist, and dive straight down the trunk, out of view of any stray Raven.";
		escape and recover;
	Otherwise if Momentum is happening:
		If the thickness of the grey mist is at least 10:
			say "You dive into the thickest spot of mist you can find, and put on a final burst of speed before changing direction and dropping like a stone.  It works:  your pursuers fly blindly into the mist where you used to be, cawing angrily when they realize they can't see you any more.";
			escape and recover;
		Otherwise if Everything Falls is happening and Everything Falls is grounded and the player does not enclose the gold capsa:
			say "As you dive, you use your knowledge of 'true down' to give yourself an edge, pulling around a tree at an angle that should be impossible; diving and twisting through gaps in the  branches that couldn't be done.  Your closest pursuer crashes into a branch, and the others peel off to avoid him.";
			escape and recover;
		Otherwise:
			say "Your speed puts more distance between you and your pursuers, but it's not quite fast enough, or the mist isn't thick enough, or both, and your pursuers manage to keep you in sight.";
	Otherwise:
		If the thickness of the grey mist is at least 13:
			say "The mist is too thick for the Raven Guard to pursue you far.  You dodge around a tree, and disappear.";
			escape and recover;
		Otherwise:
			say "The Raven Guard pursues you determinedly through the [mist density]mist.";

To escape and recover:
	Now the woodpeckers are not activated;
	Move the Raven Guard to the Void;
	Move the Lone Guard to the Librum Landing Cradle;
	Move the small pile of tiny padlocks to the Librum Landing Cradle;
	Now the closeness of Being Chased is 0;
	Now Constance is cruising;
	say "[lb]The Raven's frustrated caws echo in the mist.  In time, the woodpeckers cease their drumming, and the cawing fades as well.  Protocol would dictate that they return to guarding priority items.  If there were any reserves left, they would be called up, but the Red Plague has affected the Raven Guard as sorely as your own community.[lb]";
	if the rucksack is not enclosed by the player:
		say "You retrieve your rucksack and any fallen capsae, and plot a now-unseen course back to the familiar currents above the Aerie to ponder your next move.";
		move the rucksack to the player;
	otherwise:
		say "You plot a now-unseen course back to the familiar currents above the Aerie to ponder your next move.";
	if the purple capsa of opening is not enclosed by the player:
		move the purple capsa of opening to the rucksack;
	if the red capsa is not enclosed by the player:
		move the red capsa to the rucksack;
	if the gold capsa is open:
		now the gold capsa is closed;
	if the gold capsa is not enclosed by the player:
		move the gold capsa to the rucksack;
	move the rucksack to the player;
	move the purple capsa of opening to the rucksack;
	move the red capsa to the rucksack;
	Move the player to High Above, without printing a room description;

When Being Chased ends:
	if cell door is open:
		now Horatio is remembered;
	otherwise:
		try looking;

[Being Chased ends here.]



Not Recovering is a recurring scene.

Not recovering begins when Constance is wounded and the capsa of opening is open.
Not recovering ends when the capsa of opening is closed.

Not recovering has a number called timer.  The timer of not recovering is zero.

Every turn during Not Recovering:
	if the player is not Horatio and Horatio is not stage three:
		if the timer of not recovering is at least six:
			if go go go is happening:
				say "[one of]Your wound continues to bleed.  It's not a huge wound, but the blood is flowing rather quickly[or]Your wound aches.  You look down at it, and it's still open and a fast small trickle of blood drips down your side[or]Your open wound really should have closed by now, but it continues to bleed[stopping].";
			Otherwise:
				say "[one of]Your wound continues to lightly bleed[or]Your wound aches.  You look down at it, and it's still open and bleeding[or]Your open wound really should have closed by now, but it continues to lightly bleed[stopping].";
			now the timer of not recovering is 0;
		otherwise:
			increase the timer of not recovering by one;

[Above code courtesy of ideas from https://intfiction.org/t/every-third-turn/1443]

Actually Recovering is a recurring scene.
Actually Recovering begins when Constance is wounded and the capsa of opening is closed.
Actually Recovering ends when Constance is not wounded.

When Actually Recovering begins:
	[Perhaps eventually check to see if the capsa of Health is open, but the premise of the game is that it's open the entire time; we'd have to let the player close it and then get wounded for this to not happen.]
	now Constance is not wounded;
	say "You feel your skin prickle where you were wounded, and look down.  To your amazement, your wound has closed and the bleeding stopped.  As you watch, even the line from the cut disappears, and the feathers around it fluff out again.
	
	It's the scroll of Health.  It [i]has[r] to be.  It's actually here!  And active.  Hmm."
	[We'd need different text if the player gets wounded more than once, but right now, they can't even get wounded once, so let's just leave it for now.]

Sneaking is a recurring scene.  Sneaking begins when the player is wearing the hunting cloak.  Sneaking ends when the player is not wearing the hunting cloak.

Check going up during Sneaking:
	say "You can't fly with this damn cloak on!" instead.

Check going down during Sneaking:
	say "You can't fly with this damn cloak on!" instead.

Ash_chat is a scene.  Ash_chat begins when the player is in the Nursery_itself for the first time.

When Ash_chat begins:
	say "Perched on the open window looking out over the forest is a fledgling Red Wing Clan.  As you enter, they turn and their face and feathers light up with delight.  'Aunty Constance!' they chirrup, and dash across the room to bury their face in your downfeathers.
	
	You stroke the feathers on their head gently.  The feathers crackle worryingly.  'Hi, Ash,' you say.  It's good to see you, too.'
	
	Their face sufficiently smothered, Ash pops out again excitedly.  'It's been so long!  Did you know there's a whole new wing of the southwest aerie?  Momma took me there just the other day, and...'"

Every turn during Ash_chat:
	say "Ash prattles happily, telling you [one of]about how they're putting in a huge room just for sick people[or]about meeting a Throckwright, and getting to see his pouch of seeds[or]about a model treehouse they made out of sticks[or]a long convoluted story about drama between their stuffed animals[or]about a flock of wild birds that lived beneath her window for a whole season[or]that they secretly dislike dust baths[or]how they need to build another treehouse because Mr. Featherstick doesn't like the first one[or]about a song they're trying to learn[or]that Loudbeak Threewings can't go anywhere without her special stack of [cycling]."

Ash is a person in Nursery_itself.  "Ash doesn't look particularly healthy, but they're in high spirits."  The description is "Ash's flight feathers are starting to come in, though they won't be able to actually fly for at least another year.  Worryingly, the feathers are drooping and seem brittle; early signs of the Red Plague.  It's not a stage of the plague you've ever seen before; maybe the capsa halted the disease's progression, but didn't cure it?  How long have they been like this?"


answering the Ash that something is chit-chat.
telling the Ash about something is chit-chat.
asking the Ash about something is chit-chat.
asking the Ash for something is chit-chat.

instead of chit-chat:
	say "There's no way you're getting a word in edgewise in this chatterfall.";

Instead of attacking the Ash:
	say "You playfully bat Ash on the head.  They stick their tongue out at you.";

Instead of kissing the Ash:
	say "You give Ash a peck on the shoulder.  They preen.";

Instead of showing something to the Ash:
	say "You consider doing that, but are enjoying the chatter too much to break it up.";

Instead of giving something to the Ash:
	say "You'd never see it again, and you probably need it.  Maybe later.  If there's time.  If.";

Instead of waking the Ash:
	say "Hoo boy, if Ash fell asleep you definitely would not wake them up again.";

Instead of eating Ash:
	say "What is it about children that makes them seem so delicious?  You playfully peck at Ash's head, and they squeal in delight.";

Instead of taking Ash:
	say "You could take Ash with you.  When you go.  Maybe."

Finale is a scene.  Finale begins when the player encloses the green capsa.

When Finale begins:
	switch to cyoa at F1

F1 is a page.  The description is "[one of]You hold the capsa of health in your hands, turning it over and looking at it from all sides.  It's what you came here for.  To take it back home and save your mother.  Your people.  Is it still that simple?

'You are now the holder of the scroll of taclor' says Horatio, as Ash continues to tell you about what it was like to see a real jaguar that one time.  'Will you have me read it?'[or]Horatio looks at you expectantly.[stopping]"

F2a is a dead-end.  It is for F1.  It is one-off.
The cdesc is "'Ash was holding it before.  Why can't they make the decision?'"
The description is "Horatio looks at Ash, then looks at you.  Ash continues to tell you about having to get their desk grown twice in two months because they were growing [i]so fast[r].

Yeah, OK, fair."

F2b is a dead-end.  It is for F1.  It is one-off.
The cdesc is "'What will happen when you read it?'"
The description is "'I know not,' Horatio replies.  'I know that it will grant a power related to the scroll's effect to some percentage of all people.  Everywhere.  Regardless of class or heritage or clan.  My guess is that it will improve their health--perhaps make them immune, perhaps give them regeneration, perhaps grant them an immortality, of sorts.'

'Will it affect people right now?' you ask, 'Or just people in the future?  People hatched tomorrow?  Eggs laid tomorrow?'

'The stories do not say,' he replies.  'What difference is five years; twenty years to the march of history?'

'It makes a difference to me,' you say.

'Indeed,' he replies."

F2c is a dead-end.  It is for F1.  It is one-off.
The cdesc is "'Why not let the queen... let Aubrey decide?'"
The description is "The feathers on Horatio's neck ruffle.  'She has already denied me.  Every day, I ask, and every day, she sends her rejection.  If you leave, I will keep asking her.  She may change her mind.  She may not.  You may know her better than I.'"


F3 is a page.  It is for F1.
The cdesc is "Leave without the capsa."
The description is "'I can't do it,' you say.  'I can't condemn Ash for the sake of my people.  I can't condemn anyone for the sake of a fairy-tale promise.'  You stroke Ash's head one more time.  'I love you, kid,' you tell them.  'Say hi to your mom for me.'  

You place the capsa of taclor back on the desk, step onto the window ledge, and launch yourself into the mist."

A page-toggle rule for F3:
	end the story finally saying "You have learned much."

F4 is a page.  It is for F1.
The cdesc is "Leave with the capsa, and leave Ash behind."
The description is "'I can't do it,' you say.  'I can't take Ash away from their mother.  I can't condemn anyone for the sake of a fairy-tale promise.'  You stroke Ash's head one more time.  'I love you, kid,' you tell them.  'Say hi to your mom for me.'  

You and Horatio step onto the window ledge, and launch yourselves into the mist.  You hear the strangled cry of a familiar Red Wing behind you, but don't turn back."

A page-toggle rule for F4:
	end the story finally saying "You have accomplished what you set out to accomplish."

F5 is a page.  It is for F1.
The cdesc is "Leave with the capsa, and take Ash with you."
The description is "'I can't do it,' you say.  'I can't condemn Ash for the sake of my people.  I can't condemn my people for the sake of Ash.  I can't condemn both for the sake of a fairy-tale promise.'

'Kid,' you turn to Ash.  'Put this on.  We're going on a trip, and it's cold out there.'  Ash delights in putting on a genuine invisibility cloak, then hops on your back with anticipation when you tell them.  Horatio dons his own cloak as well, disappearing from view.

All three of you step onto the window ledge, and launch yourselves into the mist.  You hear the strangled cry of a familiar Red Wing behind you, but don't turn back."

A page-toggle rule for F5:
	end the story finally saying "You have done what you were sure would help the greatest number."


F6 is a page.  It is for F1.
The cdesc is "Let Horatio read the scroll of taclor."
The description is "'I can't do it,' you say.  'There's no good solution here.  Even the scroll itself only halts the disease; it doesn't cure it.  Nobody wins.'

You turn to Horatio.  'And maybe nobody I care about wins if you read this, but lots of people I don't know win.  And maybe we win anyway.  Or maybe you're just crazy.  It's a risk.  Life is risk.  In the balance, maybe that's enough.'

You take a deep breath, and hand him the scroll.  'Read it,' you tell him.

Horatio nods, pulls out a small key, inserts it into the side of the capsa, and begins to slowly turn it, exposing the rest of the writing as the scroll is rolled from one rod to the next.  He reads.

Or, rather, he sings.  You've never heard a buzzard sing like this before, but then again, you've never heard [i]anyone[r] sing like this before.  It's a deep, primal song of awakening; of understanding; of comfort.  Ash's beak drops open in amazement and wonder.

Then Aubrey, your friend, your love, your queen, your enemy, bursts through the door.  'Ash!' she cries, then, seeing them safe, turns to Horatio.  'No!' she gasps, and launches herself at him."

F6a is a page.  It is for F6.  It flips to F7.
The cdesc is "Get between Aubrey and Horatio."
The description is "You fling yourself across the room to stop her, but before she even reaches you, her head jerks back, she stops, then falls twitching to the floor."

F6b is a page.  It is for F6.  It flips to F7.
The cdesc is "'Aubrey, no!'"
The description is "You start to shriek at Aubrey to stop, that this is the only way, that you love her but she can't hoard this power for only herself, but before you even get a word out, her head jerks back, she stops, then falls twitching to the floor."

F7 is a page.  The description is "Horatio continues to sing.  Ash's face is a mixture of horror and delight."

F7a is a page.  It is for F7.  It flips to F8.
The cdesc is "Rush to her side."
The description is "You rush to the side of your love, cradling her head with your wing.  'Aubrey, darling, be all right.  Listen to me.  [i]Be all right[r].  I need you.  I need the true you.'".

F7b is a page.  It is for F7.  It flips to F8.
The cdesc is "Shield Ash from the sight."
The description is "'Ash!' you cry.  You wrench them physically so they stand facing Horatio and away from their stricken mother.  'Listen to the song.  Remember it!' you cry."

F7c is a page.  It is for F7.  It flips to F8.
The cdesc is "Tell Horatio to stop.".
The description is "'Horatio!  It's too much!  You have to stop!' you cry.  You might better yell at a waterfall.  The song tumbles from his mouth, filling the room, the Aerie, the world with sound."

F8 is a page.  The description is "The song reaches a crescendo.  The Aerie itself threatens to shake apart."


F8a is a page.  It is for F8.  It flips to F9.  It is cancelled by F7b and F7c.
The cdesc is "Hold Aubrey tight."
The description is "You close your eyes and wrap Aubrey with both wings, not to shield her from the song, which is everywhere, even your bones, but just to let her know she's not alone.  She can't be alone when she dies."

F8b is a page.  It is for F8.  It flips to F9.  It is cancelled by F7a.
The cdesc is "Turn to Aubrey."
The description is "You turn to see Aubrey's arched back, and she spasms again on the cold floor.  You dash to her side, just as her wing flails out sideways, knocking you off your feet.  You land heavily on the ground, in the perfect position to see Horatio's feet, lifted slightly off the ground, though his wings are tucked in tight."

F8c is a page.  It is for F8.  It flips to F9.  It is cancelled by F7a.
The cdesc is "Physically attack Horatio."
The description is "You rush at Horatio, but before you get within a wingspan, you hit some sort of wall of--energy?  Magic?  Sound?  You hammer futilely against it."

F8d is a page.  It is for F8.  It flips to F9.  It is cancelled by F7a.
The cdesc is "Wait for the inevitable."
The description is "You can do nothing to stop this.  You can do nothing to help.  But you can listen.  And you can remember.  The song burns its way into your memories."

F9 is a page.  The description is "You didn't expect the apocalypse to be this pretty.

The song is everywhere.  The song is everything.  It is morningsong.  It is evensong.  It is the tide, and the moons, and the stars.

And threading it together, it is life.  Health.  The roost.  The nest.  A bubble of comfort pushing back against the dark.

And then it's done.  The writing fades from the scroll, and Horatio gently rewinds it back to the title.  'TACLOR'.

Aubrey relaxes, wakes.  Looks into your eyes.  'I'm so sorry,' she whispers.  She glances at her child.  'Ash...' she explains.

'I'm sorry, too,' you answer.  'My mother,' you explain.  You both look at the other with glistening eyes.

Then Aubrey gets a strange expression on her face.  'I... I [i]remember[r],' she says.  'The... Ash.  Come here.'

Obediently, Ash comes and perches by her side.

Aubrey begins to sing.  It's not The Song.  Nothing will ever be The Song.  But it's an echo.

As she sings, Ash's pallor fades, and their feathers straighten.  A hunch you didn't realize they had straightens out.  'Oh!' they exclaim.  'OH!'  Their eyes shine.

You help Aubrey to her feet and she rises to her full height, full of queenly majesty.  The four of you look at each other.  'Come,' she says.  'We have work to do.'"

A page-toggle rule for F9:
	end the story finally saying "You have changed the world."

[Lucian's Scenes ends here.]

[Include Horatio by Iron ChIF.]

[Horatio by Iron ChIF begins here.
Use authorial modesty.]

Horatio's story is a scene.  Horatio's story begins when Horatio is remembered.  Horatio's story ends when the location is High Above.

Forgotten Brig is a room.  "A small but cosy cell, grown with austerity but basic comfort in mind.  Your now-open [cell door] leads west."

The cell door is a door.  It is west of Forgotten Brig and east of Disused Hallway.  It is closed and locked.

cell_contents is scenery in Forgotten Brig.  The printed name is "cell contents".  The description is "A straight roost by a desk for writing, and a scooped roost for sleeping.  Enough space to spread your wings.  A rope wall for excercise.  Not bad."  Understand "cell/contents/austerity/comfort/straight/scooped/roost/space/spread/rope/wall" as cell_contents;

Does the player mean examining cell_contents: it is likely;

Horatio is a man in Forgotten Brig.  "[Horatio room desc]."  The description is "[if the player is Horatio]You're a member of the Buzzard Clan, and fit the stereotype fairly well: bald red head and red talons, hunched shoulders, mottled black and brown feathers.  You've balded down past your neck now, betraying your advanced age.[otherwise]Horatio is an ancient Buzzard Clan sage of sorts, you suppose, given that he was jailed for heresy back in the day[end if]."

To say Horatio room desc:
	If the location is the Librum Landing Cradle:
		say "Horatio is talking [if go go go is happening]quickly[otherwise]slowly[end if] to the [lone guard] about [one of]the ethics of a monarchy[or]his grandchildren[or]regrettable fashion choices from the youth of today[or]whether the dot on the back of looks infected[or]how to get to zenostan (is that a real place?) from here[or]whether her mother was the Isabella he once knew[or]some meandering story about flying to the park[cycling], driving the guard quietly insane";
	otherwise:
		say "Horatio is here, watching you with quiet aplomb and patience"

Horatio can be remembered.  Horatio is not remembered.

The blue capsa of mist is a capsa carried by Horatio.  The description is "[If the player is Horatio]The blue capsa of mist contains a scroll of bostrat, but its power has long since faded, as the Gods intended[otherwise]You suppose that now that the scroll's power has been spread to Bostrat everywhere, that capsa itself is little more than a trinket; a curiosity.  But you can't help but think of it almost reverentially.  In a very real sense, it [i]made[r] you.  A part of you[end if]."  Understand "bostrat" as the blue capsa.

A scroll of bostrat is a scroll in the blue capsa.  The name is "BOSTRAT".  Understand "mist/water" as the scroll of bostrat.

The description of the scroll of bostrat is "While '[name]' can be clearly read at the top of the scroll, the rest of the script has faded away[if the player is Constance].  That power now lives, in part, within your own being[end if]."

Disused Hallway is a room.  It is east of Nope.  "The only time you ever saw anyone in this hallway was when Georg came to give you your meals, or clean the cell.  The living walls, still elegantly patterned, even here, self-replenish, and the floor carries away shed bark through the [grate].  It leads west into the living area, and your old [cell door] leads east.";

A grate is a closed openable enterable container in Disused Hallway.  The description is "The grate conveys unneeded materials to the outside, and the forest floor.  'Rezrov' has done its job there, too: it lies open.";

Check going west from Disused Hallway:
	say "Your place is not with the denizens of this Aerie, but with the prodigal daughter, now returned, and the capsa she seeks." instead.

Carry out opening grate:
	say "You grasp the grate with your talons and carefully fold it upward, allowing access.";
	continue the action;

Before taking the grate:
	try opening the grate;

Before attacking the grate:
	try opening the grate;

Instead of going nowhere from Disused Hallway:
	if the noun is down:
		try entering the grate instead;
	if the noun is inside:
		try entering the grate instead;
	otherwise:
		say "The hallway runs east to west, and there's a grate on the floor you could enter.";

Check entering the grate:
	say "You flatten yourself to the floor and, hearing your bones creak, roll into the space behind the grate.  Using your minimal throck ability, you whisper to the veins of this place: 'I am extra.  I am not needed.  Take me from this place, which will renew itself through my absence.'
	
	After a few moments, you feel an undulation in the slick rippled floor beneath you, and you are compressed even further, as its peristalsis slides you slowly, and then more rapidly, away from your only home for the last ten years.  Then with a sudden >plop<, you're ejected into space.
	
	You try to spread your wings, but your reaction time is not what it was, and you hit wirey netting before fully stopping yourself.
	
	No matter.";
	Move Horatio to in_forest;
	Now cell door is open; [Just in case]
	rule fails;

When Horatio's story begins:
	say "[bstars]";
	wait for any key;
	clear the screen;
	say "You wait, expectantly.";
	wait for any key;
	say "[lb]Silently, your cell door unlocks, then swings open.";
	wait for any key;
	say "[lb]Well above your cell, you sense rezrov, rudenj, and quiste settle in their movements until they make lazy circles, high above the Aerie. Igram and taclor remain in place, quiet.
	
	It is time.";
	Now the player is Horatio;
	Try looking;

When Horatio's story ends:
	say "[bstars]";
	wait for any key;
	clear the screen;
	switch to cyoa at H1.

Section The Chat

H1 is a page.
The cdesc is "Start a new conversation with Horatio."
The description is "'Good job, Constance,' you say as you approach to fly adjacent to her broad circling.

She peers at you, and you know she can make out every barb on each of your feathers.  Patiently, you wait.

'You're Horatio,' she finally says.  'Didn't the queen... imprison you for heresy?'

'Indeed,' you reply.

'And I just unlocked your cell,' she says.

'Indeed,' you reply.

'They wouldn't tell me what the heresy was.  I guess that's the point of trying to suppress dangerous ideas.'

This time, you just wait, and slightly incline your head.  Saying 'Indeed' again might make her self-conscious about her babbling.

There's a pause.

'What was it?' she asks."

H2 is a page.  It is for H1 and H3a and H3b.
The cdesc is "Tell her about capsae."
The description is "'I believe that the gods gave us the capsae to benefit everyone,' you say.

Constance frowns.  'That's not... a dangerous idea.  I mean, people may not truly believe in the gods much today, but they're generally seen as having been... nice?  I guess?'".

H2a is a page.  It is for H2.
The cdesc is "Explain."
The description is "'When I say everyone, I mean everyone.  In the whole world.  As far as the Clans extend.'

Constance chuckles.  'A little hard for the capsae to do [i]that[r].  Longest range I know of is, like, two miles.'

'Indeed,' you reply.

Constance locks her wings so she can turn and look at you intently for several seconds as she glides.  She probably thinks she's being tested.  Which would be good, because she is.  You wait.

'So.  You believe that the capsae are being misused.  That the kingdoms hoarding them should instead... share them?  Move them around?  Shuffle them, so each kingdom gets a bit of their power every so often?'

'Misused, yes,' you reply.  'And, yes, it would be in the spirit of that initial gift to share them more.  But what I proposed to your queen, and to other queens and kings of other realms, goes beyond this.'

Constance thinks for a bit.  [if H3 is not previously displayed]Then she rolls her eyes.  'OK, yeah, I have no idea what you're talking about.'[otherwise]Then her eyes widen.  'You want to read the scrolls!' she exclaims.[end if]"

H2b is a page.  It is for H2a.  It is cancelled by H3.
The cdesc is "Ask her about scrolls."
The description is "'What do you do with scrolls?' you ask.

Constance scoffs.  'Read them!' she exclaims, then laughs, as another thought occurs to her. 'Which is the one thing you [i]can't[r] do with the scrolls in the capsae, because nobody knows...'  She trails off, and gives you another look.  'Wait, really?  You?'";

H2c is a page. It is for H2a.  It is cancelled by H3.
The cdesc is "Tell her about scrolls."
The description is "'The scrolls were meant to be read, not hoarded', you say.

Constance thinks.  'Hmm.  So, you want to research the dead language on the scrolls?  Figure it out again?  Do some sort of cross-Kingdom research project, where everyone agrees to send the texts of their capsae to everyone else?  That seems reasonable, but again, it's not a particularly dangerous idea.'"

H3 is a page.  It is for H1, H2b, and H2c.
The cdesc is "Tell her what you can do."
The description is "'You've seen the scrolls themselves?  The writing on them?'

'[apostrophe]Indeed,[apostrophe]' Constance replies, raising an eyebrow.  You grin.

'What you may not know is that those symbols are not found in any other form of known writing.  There are fragments of writing from before the capsae.  They differ.  Some say it is the language of the gods themselves.'

'Woo, fancy,' says Constance.  'In other words, they're gibberish.'

'No,' you reply.  'I can read them.'

'Oh?  What do they say?' Constance asks."

H3a is a page. It is for H3.
The cdesc is "Tell her the truth."
The description is "'I don't know,' you tell her.

Constance sputters.  'But you--' she begins, then cuts herself off, looking at you askance again.  She's a clever woman.  You wait, tipping your wings synchronously with hers as you turn into another circuit.

'So.  You learned the language from somewhere.'  She thinks.  You wait.  'No, you said the symbols matched no other writing.  You were born knowing the language.  It's your heritage, as I was born knowing how to summon mist.'

You let her think, the lack of any contradiction from you enough of an encouragement.

'Which means you've either just never seen an actual scroll--which seems unlikely; the queen didn't get mad at you until several days had passed--or,' she slows down, but continues, 'or you were born with the ability to read, but not understand.'

'Inde--'  Constance shoots you warning look.  'Yes.  That's it exactly.  Congratulations.'  You bob your head and splay your wingfeathers in a grin of approval.

[if H2 is not previously displayed]'So I assume this is some sort of backstory for what your heresy actually is?' Constance asks[otherwise]'So, you want to read a capsa's scroll.  And you won't know what you're reading.' says Constance[end if]."

H3b is a page. It is for H3.
The cdesc is "Wax poetical a bit."
The description is "'I have read and felt what it was like to thunder across the plains as a gazelle from the scroll of izyuk.  I have read and felt the desperate yen of attraction from the scroll of obidil. From the scroll you now hold in your posession, I have read and felt what it is to be the very earth itself, spinning through the cosmos.'

Constance looks at you.  A beat.  'So you don't know.'

'I don't know,' you agree.

Constance waits.  OK, you can give her this one.

'I don't know because reading is my heritage, as the ability to summon mist is yours.  But understanding is not part of that gift.'

'Well that sucks,' Constance says.

'It is a touch of the language of the gods,' you say, simply.  'It is enough.'

The two of you make another circuit.  The mist streams off the ends of your outstretched wings in curled eddies.

[if H2 is not previously displayed]'So I assume this is some sort of backstory for what your heresy actually is?' Constance finally asks[otherwise]'So, you want to read a capsa's scroll.  And you won't know what you're reading.' says Constance, after a bit[end if]."

H4 is a page.  It is for H3a, H3b, and H2a.  It needs H2 and H3.
The cdesc is "Share your speculation."
The description is "'I will not know what it is I'm saying, but I have a guess about what will happen.

And no capsae holder I have yet met will risk such a thing,' you say."

C1a is a page.  It is for H4.
The cdesc is "[if the player is Horatio][i]{Switching to Constance}: [r][end if]Scoff at 'capsae holder'."
The description is "You scoff.  'No Queen or King, you mean.'

'You personally currently hold three capsae, more than some kingdoms,' replies Horatio, 

You laugh.  '[apostrophe]Cause I stole [apostrophe]em!  And they weren't even the one I wanted; I just didn't know what color I was after!'

'Nevertheless,' you tell her, 'you are their holder. If you told me you wanted me to read one, I then could."

A page-toggle rule for C1a:
	now the player is Constance;


C2 is a page.  It is for C1a.
The cdesc is "He needs instructions?"
The description is "'Wait.  So, I could order you to read a capsa?  And the magic would compel you to do it?' you ask, incredulously.

'No.  I will not read one without the holder's permission, but I may refuse any order,' Horatio replies.

'[apostrophe]Will not.[apostrophe]  So you're not compelled to do anything.  It's just a personal choice,' you say.

Horatio winces slightly.  'I suppose, technically, you are correct.  It is a tradition among the Readers who know the history.'"

C2a is a page.  It is for C2.  It flips to C3.
The cdesc is "Getting information out of this guy is like pulling mist out of the desert.  Say nothing."
The description is "You say nothing, and wait expectantly."

C1b is a page.  It is for H4 and C1a.  It flips to C3.
The cdesc is "[if the player is Horatio][i]{Switching to Constance}: [r][end if]Ask about his guess."
The description is "'So, what's your guess?' you ask.  'Is that your heresy?'"

A page-toggle rule for C1b:
	now the player is Constance;

C3 is a page.
The description is "In response, Horatio offers you the blue capsa he's holding.  It's closed, and you cock your head questioningly at him.  'It safe.  Nothing will happen when you open it.'

Weird trap if it was a trap.  Fine.  You open the blue capsa, bracing yourself... and nothing happens.  You look at the scroll, which seems to have no symbols on it at all apart from the title:  'BOSTRAT'."

A page-toggle rule for C3:
	move the blue capsa to the rucksack;

C3b is a page.  It is for C3.
The cdesc is "Is that real?"
The description is "Horatio shrugs.  'I cannot prove it is so.  Many have chosen not to believe.  But I can sense capsae, and I can sense this.'";

C3a is a page.  It is for C3 and C3b.
The cdesc is "Wow."
The description is "'Wow,' you say, amazed by the implication.

'Indeed,' Horatio replies.  'At one time, if my research and the ancient tales I have collected are correct, this capsa, when activated, would bring rain to the land around it.'

'And now... any Bostrat anywhere in the world can bring rain,' you conclude.  'If they work together,' you amend.

Horatio nods, seriously.  'In the past, this scroll could alter its surroundings.  When it was finally read, it [i]changed the world[r].

You gaze in wonder at the capsa.  Your heritage.  You can't say for sure it's genuine any more than Horatio can, but you feel the stirrings of some sort of pull towards it."

C4a is a page.  It is for C3a.
The cdesc is "Ask about the other abilities."
The description is "'And the Throckwrights?  The Ikniq?' you ask.

Horatio nods.  'From the stories I have collected, I believe 'throck' was the first of the scrolls to be read out and gifted to the people, and a renaissance of agriculture and architecture resulted.  When civilization pushed into the barren boundaries of the known world, bostrat was next, and spread our people across the desert.'

He stops.  There's an obvious Part Three, but you'll be damned if he makes you ask for it.  You wait.  You make another complete circuit together, and you realize there's a tear in his eye.  You're suddenly glad you gave him space to be emotionally ready to finish the story, though you're worried you already know where this is going.

Finally, with a deep breath, he speaks.  'Yes.  The first two gifts benefitted the herbivore clans more than the carnivore clans, or so they claimed.  Ikniq was next chosen, and hunting did indeed become easier.'  He pauses.

'But so did hunting each other,' you conclude, quietly.  Horatio nods.  The Great Wars.  Entire clans wiped out.  Whole swaths of countryside burned to the rock, where still nothing grows, a thousand years later."


C4b is a page.  It is for C3a and C4a.
The cdesc is "Pull everything together."
The description is "'So that's your heresy,' you conclude.  'You want to read a capsa's scroll.  And change the world again.'

'Not just any capsa.  The scroll of health.  Taclor.  Ten years ago, I would have been happy to read any.  Now, it must be that one.  But I will not make that choice on my own.  Every Reader like myself has the innate ability to Read a single scroll, and I will yield to the will of its holder, as my predecessors swore to do in the aftermath of the Great War.  But I will not waste my ability on anything else.'"

C5a is a page.  It is for C4b and C5b.
The cdesc is "He can't have the scroll."
The description is "'You can't read that scroll,' you say.  'I need it to save my mother.  To save the village.'

'The whole world,' Horatio turns his head to face to you, 'could say the same.'

'But [i]I'm here[r]!' you shout.  'I have [i]three capsae[r].  I didn't start any wars!  I didn't force people to live with their livestock and kickstart the Red Plague!  The Queen's hoarding the capsa for gods-know-what reason, probably so the selfish bastard could ensure she doesn't come down with it herself...'

Horatio flinches.  That's right, he knew you when you and the now-Queen were... closer.  Inseparable.

'I'll take it around the world!' you declare.  'I'll take it to every village in this kingdom; wherever the need is greatest.  I'll take it to other kingdoms!'

Horatio nods.  'When you are the holder, you may do as you wish,' he says, simply.  'But first, you must become the holder.  And for that, you will need igram.  It's in the librum."

C5b is a page.  It is for C4b.
The cdesc is "You need more details."
The description is "'So, what will happen?  What would it do if it was read?' you ask.

'I cannot say.  The gods created the scrolls with their local effects, I believe, to give people a taste of what was to come.  Throck, as a capsa, encouraged vegetation to grow.  Throckwrights push vegetation to grow in very specific ways.  Bostra, as a capsa, caused rain by itself, but the bostra must work together to do the same.  Ikniq... I can find no record of what it did as a capsa.  That information must have been purged.'  He pauses.  You let him collect his thoughts.

'My best guess is that it will give people the ability to heal themselves; perhaps even to regenerate.  Maybe it will make them immune to disease.  Maybe to death.  The gods only know.'"

C6 is an end-page.  It is for C5b and C5a.
The cdesc is "Figure out what's next."
The description is "'So, what do we do next?' you ask.

'I can sense the capsae.  Taclor, health, is in the Royal Quarters.  Igram is in the Librum.'

'I ransacked the Librum last time; there was only these three,' you protest.

'It was considered worthless, and was discarded.  With it, I can lead you to taclor,' Horatio tells you.

'What does it--you know, never mind, you obviously don't want to tell me.  How do I get it?' you ask.

'It is in the Librum,' he says, simply.  'Therefore, either you must go into the Librum, or the capsa must come out.  I will talk to the guard to distract her, if that helps,' Horatio offers.

Gods, yes, you can inflict this man on someone you hate.  'Perfect,' you say, grimly. You shake yourself, and turn to your new task."

Horatio can be distracting.  Horatio is not distracting.

A page-toggle rule for C6:
	now the player is Constance; [Just in case]
	now Horatio is distracting;

Section fooling around - not for release

become_constance is an end-page.  It is for H1, H2, H2a, H2b, H3, H3a, H3b, H4, H4a, H4b, C1a, C1b, C2, C2a, C3, C3a, C3b, C4a, C4b, C5a, C5b.  
The cdesc is "OK, I'm a tester and I need to skip ahead and be Constance, fiddling with scrolls and stuff."
The description is "Done!  Thank you for testing!  If you want to come back to this conversation at the start, just >TOUCH HORATIO.";

A page-toggle rule for become_constance:
	now the player is Constance;
	now the blue capsa is in the rucksack;
	now Horatio is distracting;

start_over is a page.  It is for H1, H2, H2a, H2b, H3, H3a, H3b, H4, H4a, H4b, C1a, C1b, C2, C2a, C3, C3a, C3b, C4a, C4b, C5a, C5b.
The cdesc is "I'm also a tester, and I just want to go back to the beginning of this conversation."
The description is "Done!  Thank you for testing![bstars]".
start_over flips to H1.

A page-toggle rule for start_over:
	repeat with X running through every page:
		now X is not previously displayed;

Instead of touching Horatio:
	switch to cyoa at H1.

Section Horatio in act 3

Horatio distracts the guard is a scene.  Horatio distracts the guard begins when Horatio is distracting.  Horatio distracts the guard ends when the black capsa is not enclosed by the Librum Itself.

When Horatio distracts the guard begins:
	Move Horatio to the Librum Landing Cradle;
	say "With a solemn nod to you, Horatio explains where the black capsa of igram should be, then banks to the east, and descends to the Librum.";

Horatio tries to make zgi less ridiculous is a scene.  Horatio tries to make zgi less ridiculous begins when Horatio distracts the guard ends.  Horatio tries to make zgi less ridiculous ends when the player encloses the hunting cloak.

Horatio can be stage one or stage two or stage three.  Horatio is stage one.

Every turn during Horatio tries to make zgi less ridiculous:
	If Horatio is stage one and the location is not Librum Landing Cradle:
		if the location is Royal Gardens:
			if a random chance of one in three succeeds:
				say "Where is Horatio?  Didn't he say to get the capsa of igram, and then you'd both go in the Royal Quarters?";
		otherwise:
			say "Horatio glides out of the mist and circles near you.  He nods at the black capsa.  'Excellent work.  Now, we need something from the Great Hall.'[lb]";
			Move Horatio to the Lower Great Hall;
			Now Horatio is stage two;
			if the location is the Great Hall Landing Cradle:
				say "Horatio glides through the open double doors of the Great Hall.";
			otherwise:
				say "Horatio glides away, heading towards the Great Hall.";
	Otherwise if Horatio is stage two and the location is Lower Great Hall:
		now Horatio is stage three;
		say "You circle down and land near Horatio.  'So.  [i]Now[r] will you tell me what igram does and why it's so important?' you ask.
		
		'It is better to show you,' he replies.  'Try it.'
		
		You sigh.  Fine."

When Horatio tries to make zgi less ridiculous ends:
	move Horatio to the void;
	Now the black capsa is explained;
	say "You turn to Horatio, questions bubbling in your head.  'So, nothing else here turned invisible.  Does the scroll work on cloaks?  Things for hunting?  Ancient materials?  Hides?'
	
	Horatio looks a little uncomfortable.  'No.  It works on... purple.'
	
	'Purple?!?' you exclaim/ask.
	
	'Purple,' he confirms.
	
	'It [i]turns purple things invisible[r]?  Purple things!  The gift from the gods, on a scroll written in their secret language!  To turn [i]purple things invisible[r]!'  You cackle in glee.
	
	Horatio looks uncomfortably affronted.  'The hippotomai were common in those days.  It made sense...'
	
	You continue to laugh, cutting him off, but unable to contain your utter delight.  'Herds of invisible hippotomai!  Grass on the marshy banks disappearing into nowhere!  Weird divots in the lakes!  I bet--wait!  The trickster god!  Ape, the trickster!  Stohleblanc!'  You laughter gets more hysterical and you nearly can't breathe.
	
	With as much dignity as he can muster, Horatio waits solemnly for you to finish laughing.  You fail to do so.  Finally he gets impatient and turns to go.  'We can enter the Royal Quarters cloaked.  I will follow you.'
	
	'Wait,' you sputter, trying to push down the hysteria.  'How will you follow me?  I'll be invisible!'
	
	'I can sense the capsae.  I will know where you are,' he replies, and with a deep breath, he gathers himself and flies up and out of the Great Hall.";

[Horatio ends here.]


When play begins:
	say "[i]Your mother needs you.  The whole village needs you.  You can do this.  You must do this.

[r]The mantra repeats in your head, pushing you on as you wheel in circles over the forest canopy, riding thermals to heights where none but other Falcon Clan members could see you.  And there's no more Falcon Clan in the Royal Aerie--you and the rest of your clan were all banished years ago.  Three days ago, approaching from underneath worked, as none were expecting it.  But while technically successful, you failed to snatch your intended quarry: the Scroll of Health.  The sages had been unable to tell you what color capsa would hold it: you now know that it's not purple, gold, nor red.

By tonight, you will know.  You're not leaving without it."

Chapter Testing - not for release

test summon with "d/n/summon mist/d/u/d/u".
test scenery with "x aerie/x royal quarters/x librum/x great hall".
test map with "d/u/n/u/e/u/d/e/nw/s/n/se/w/d/u/e/d/e/d/n/d/u/u".
test thicken_mist with "summon mist/g/g/g/g/g".
test chase_ustart with "open purple/e/nw/u".
test chase_dstart with "d/d/open purple/n/se/u".
test chase_mstart with "d/open purple/e/w/u".
test horatio_speedrun with "summon mist/d/u/open purple/d/d"