"Der kleine Halbling" by Ingo Frick und Frank Gerbig


Volume Introduction

The story headline is "Ein Remake des Grafik-Adventures für den VC-20 aus dem Jahre 1985".
The story genre is "Fantasy".
The story creation year is 1985. 
The story description is "Du bist der kleine Halbling. Du musst ein sagenhaftes Land bereisen, Rätsel lösen, Gefahren bestehen und schließlich dem Drachen gegenübertreten."
The release number is 14. 


Book Options and Includes 

Part (common)

Use no scoring. 
Use skip libcheck.
[Use no deprecated features.]

Release along with cover art, a "german" website, an interpreter, the private source text, a solution, a file of "Story File" called "Der kleine Halbling.zblorb", a file of "Karte" called "Karte.pdf", and the library card.

Include German by Team GerX.
Include German Exit Lister by Team GerX.
Include Punctuation Removal by Emily Short.

Use Yoda command clarification.

A thing is usually privately-named. 
A room is usually privately-named.

Danger is a number that varies.
	

After reading a command (this is the remove-stray-punctuation rule): 
	remove stray punctuation. 
		

Part (for Glulx only)

Use DICT_WORD_SIZE of 12.

Include Simple Graphical Window by Emily Short.
Include Location Images by Emily Short.
Include Graphical Window Animation by Erik Temple.

Figure of End 01 is the file "2-7a.png".
Figure of End 02 is the file "2-7b.png".
The end reel is a list of figure-names that varies.
The end reel is { Figure of End 01, Figure of End 02 }.

To display the end animation:
	now the current reel is the end reel;
	animate the current reel at 3 fps, looping.
	

Part (for Z-Machine only) 

Use memory economy. 

[* dummy definitions for the not included Glulx extensions *]
[* for 'Simple Graphical Window by Emily Short' *]
Currently shown picture is a figure-name that varies. 
Current graphics drawing rule is a rule that varies. 
The current graphics drawing rule is the standard placement rule.
This is the standard placement rule: do nothing.

[* for 'Location Images by Emily Short' *]
A room has a figure-name called room illustration.
This is the image-setting rule: do nothing.

[* Z-Machine has no animations *]
To display the end animation: do nothing.


Part Debug - Not for Release

Include Object Response Tests by Juhana Leinonen.
Use MAX_VERBSPACE of 8192.

After reading a command (this is the ignore beta-comments rule): 
	if the player's command matches the regular expression "^\*": 
		say "(Noted.)"; 
		reject the player's command.


Book When Play Begins

When play begins:
	now nowhere is mapped west of the dense forest;
	now all things are unknown;
	say "Eigentlich hattest du dich auf einen ruhigen Morgen gefreut: ein zweites Frühstück, ein bisschen Zeitung lesen. [run paragraph on]";
	say "Dann vielleicht ein drittes Frühstück und vor der Höhle in der Sonne gepflegt ein Pfeifchen rauchen. [run paragraph on]";
	say "Aber dann kommt alles anders.[paragraph break]";
	say "Du bist der kleine Halbling, der die Aufgabe hat sich in einem sagenhaften Land durchzusetzen.";
	say "Dabei musst du viele Gefahren meistern...[paragraph break]";
	say "Viel Glück!!![paragraph break][paragraph break]";


Book Parser Problems

[* Der "Spalt" im Abgrund wird vom Parser für das Verb "spalten" gehalten.
   Da "spalt" ein synonym für "schneid" ist, wird dies am Beginn der Eingabe ersetzt *]

Understand the command "spalt" as something new.

After reading a command (this is the replace spalt durch schneid rule):
	let T be indexed text;
	let T be the player's command;
	replace the regular expression "^spalt" in T with "schneid";
	change the text of the player's command to T.
	

Book Additional Actions

Part Help 

[* adapted from "Metagame and Fixes" by Jason Catena *]
A room has some text called hint. 
A thing has some text called hint.
no-destination is a room.
A thing has a room called destination. The destination of a thing is usually no-destination.

Definition: a text is empty if it is "".	
		
To clear the destination of (object - a thing):
	now the destination of the object is no-destination.

To clear the hint of (object - a thing):
	now the hint of the object is "".

	
Chapter Hint

Understand "hint" as a mistake ("[hinting explanation]").
Understand "tipp" as a mistake ("[hinting explanation]").
Understand "hinweis" as a mistake ("[hinting explanation]").
Understand "hilf" as a mistake ("[hinting explanation]").
Understand "hilfe" as a mistake ("[hinting explanation]").
Understand "hilf mir" as a mistake ("[hinting explanation]").
Understand "helf mir" as a mistake ("[hinting explanation]").
Understand "anleitung" as a mistake ("[hinting explanation]").
Understand "erklaerung" as a mistake ("[hinting explanation]").

To say hinting explanation:
	say "Mit 'hilfe über <Gegenstand>' oder 'hilfe über <Raum>' kannst du dir einen Hinweis geben lassen.";
	say "[looking for explanation]".


Chapter Item Hinting

Item hinting is an action out of world, applying to one visible thing. 
Understand "hint [any thing]" as item hinting.
Understand "hint ueber/zu [dativ] [any thing]" as item hinting.
Understand "tipp ueber/zu [dativ] [any thing]" as item hinting.
Understand "hinweis ueber/zu [dativ] [any thing]" as item hinting.
Understand "hilfe [dativ] [any thing]" as item hinting.
Understand "hilfe mit/ueber/zu [dativ] [any thing]" as item hinting.
Understand "hilf mir mit/bei [dativ] [any thing]" as item hinting.
Understand "helf mir mit/bei [dativ] [any thing]" as item hinting.

Report item hinting:
	[* where to go *]
	if the destination of the noun is not no-destination and the location is not the destination of the noun:
		if the location of the noun is visited and the noun is not unknown and the destination of the noun is visited:
			if the hint of the noun is empty:
				say "Geh [destination name of the destination of the noun] und versuch es dort." instead;
			otherwise:	
				say "[hint of the noun] Aber dazu solltest du [destination name of the destination of the noun] gehen." instead;
		otherwise:
			if the noun is unknown:
				say "Bei Fragen zu [dem noun] kann ich dir nicht helfen." instead;
			else:
				if the hint of the noun is empty:
					say "Hier wirst du damit nichts erreichen." instead;
				otherwise:	
					say "[hint of the noun] Aber hier wirst du damit nichts erreichen." instead;
	[* what to do *]
	if the noun is unknown or the hint of the noun is empty:
		say "Bei Fragen zu [dem noun] kann ich dir nicht helfen.";
	otherwise:
		say "[hint of noun][paragraph break]".
		

Chapter Location Hinting

Location hinting is an action out of world, applying to one visible thing. 
Location hinting is allowing wide scope. [ so hinting the location works ]
Understand "hint [room]" as location hinting.
Understand "hint ueber/zu [dativ] [room]" as location hinting.
Understand "tipp ueber/zu [dativ] [room]" as location hinting.
Understand "hinweis ueber/zu [dativ] [room]" as location hinting.
Understand "hilfe mit/ueber/zu [dativ] [room]" as location hinting.
Understand "hilf mir mit/bei [dativ] [room]" as location hinting.
Understand "helf mir mit/bei [dativ] [room]" as location hinting.

Report location hinting:
	if the hint of the noun is empty:
		say "Bei Fragen zu [dem noun] kann ich dir nicht helfen.";
	otherwise:
		say "[hint of the noun][paragraph break]".


Part Looking For

Looking for is an action applying to one visible thing and requiring light. 
Understand "such" as looking.
Understand "such [any thing]" as looking for. 
Understand "such [nach] [Dativ] [any thing]" as looking for.
Understand "wo [any thing]" as looking for. 
Understand "wo ist/sind [any thing]" as looking for. 
Understand "wo" as a mistake ("[looking for explanation]").
Understand "wo ist/sind" as a mistake ("[looking for explanation]").

To say looking for explanation:
	say "Mit 'wo ist <Gegenstand>' oder 'such nach <Gegenstand>' kannst du dir anzeigen lassen, wo du etwas zuletzt gesehen hast.".

Check looking for something: 
	if the noun is the player:
		say "Du bist hier." instead;
	otherwise if the player wears the noun:
		say "Du hast [den noun] an." instead;
	otherwise if the player encloses the noun:
		say "Du hast [den noun] bei dir." instead;
	otherwise if the noun is not the key:
		if the noun is in the location:
			say "[Der noun] [ist] hier." instead;
		otherwise:
			if the noun is known:
				if the noun is a backdrop:
					let direction-to-go be the best route from the location to the holder of the noun through visited rooms;
					say "Wenn du [einen noun] suchst, kannst du [if direction-to-go is not nothing]Richtung [direction-to-go] [end if][destination name of the found in of the noun] gehen." instead;
				if the location of the noun is not nothing and the location of the noun is visited:
					let direction-to-go be the best route from the location to the location of the noun through visited rooms;
					say "Wenn du [den noun] suchst, musst du [if direction-to-go is not nothing]Richtung [direction-to-go] [end if][destination name of the location of the noun] gehen." instead;
			say "Darüber weißt du nichts." instead.

Carry out looking for something:
	if the key is lost:
		if the location is the dense forest:
			say "Hier hattest du den Schlüssel zum letzten Mal. Falls ihn niemand anders gefunden hat, müsste er hier noch sein.";
		otherwise:
			say "Soweit du dich erinnerst hattest du den Schlüssel das letzte Mal im Wald.";
	otherwise if the troll has the key:
		say "Der Troll hat den Schlüssel.";
	otherwise:
		say "Hast du den Schlüssel etwa schon wieder verbummelt?".

Part Attracting

Understand "lock [someone alive]" and "lock [someone alive] an" and "koeder [someone alive]" as a mistake ("Womit willst du [den noun] ködern?").
Understand "lock mit [dativ] [something]" and "lock mit [dativ] [something] an" and "koeder mit [dativ] [something]" as a mistake ("Wen willst du mit [dem noun] ködern?").

Attracting it with is an action applying to two visible things and requiring light.
Understand "lock [someone alive] mit [dativ] [something]" as attracting it with.
Understand "lock [someone alive] mit [dativ] [something] an" as attracting it with.
Understand "lock mit [dativ] [something] [someone alive]" as attracting it with (with nouns reversed).
Understand "lock mit [dativ] [something] [someone alive] an" as attracting it with (with nouns reversed).
Understand "koeder [someone alive] mit [dativ] [something]" as attracting it with.
Understand "koeder mit [dativ] [something] [someone alive]" as attracting it with (with nouns reversed).

Instead of attracting something with something:
	say "[Der noun] scheint kein Interesse an [dem second noun] zu haben.".

Part Following

Following is an action applying to one visible thing and requiring light. 
Understand "folg [dativ] [something]" as following.
Understand "verfolg [something]" as following.
Understand "geh [something] nach" as following.
Understand "folg" or "verfolg" or "geh nach" as a mistake ("Wem oder was willst du folgen?").

Check following:
	if the player can see the noun:
		if the noun is the player:
			say "Du hast dich nicht bewegt." instead;
		otherwise if the noun is alive:
			say "[Der noun] [hat] sich nicht bewegt." instead;
		otherwise: 
			say "Das geht nicht." instead;	
	otherwise:
		say "So etwas kannst du hier nicht sehen." instead.


Part Exiting/Entering

Understand "geh aus [something]" as exiting from.
Understand "geh aus [something] [weg]" as exiting from.
Understand "geh aus [something] [heraus]" as exiting from.
Understand "geh [something]" as entering.

Exiting from is allowing wide scope. [* so exiting from the location works *]

Check an actor exiting from something (called the surrounding)
	(this is the convert exiting from to exiting or location-leaving rule):
	if the actor is in the surrounding:
		convert to the exiting action on nothing;
	otherwise:
		if the surrounding is a backdrop:
			try location-leaving instead;
		otherwise:
			say "[Der actor] [ist] nicht in [dem surrounding].";
			rule fails.


Part Tying To

Understand "bind [something] an [something] fest" as tying it to.
Understand the commands "fessle" and "fessel" and "befestig" as "bind".

Rule for supplying a missing second noun when tying something to:
	say "Woran willst du [den noun] binden?".


Part Calling For

Understand the command "schrei" as something new.
Calling for help is an action applying to nothing.
Understand "schrei" as calling for help.

Carry out calling for help:
	say "'Hilfe!'"

Calling for is an action applying to one topic.
Understand "schrei [text]" as calling for.
Understand "schrei um/nach [text]" as calling for.

Carry out calling for:
	let T be indexed text; 
	let T be the topic understood; 
	if T is "hilfe" or T is "beistand":
		try calling for help instead;
	otherwise if T is "zwerg" and the player is in the swamp:
		try calling for help instead;
	otherwise if T is "smang" or T is "drache" or T is "drache smang" or T is "smang herbei" or T is "lindwurm" or T is "wurm" or T is "untier" or T is "tier" or T is "komm" or T is "hierher" or T is "komm hierher" or T is "bei fuss" and the player is in the desolation and the dragon is distant:
		say "'[T in title case]!'";
		bring the dragon near;
	otherwise:
		let T be the topic understood; 
		say "'[T in title case]!'".

Understand the commands "ruf", "bet", and "wein" as "schrei".
	
Helping it with is an action applying to two things. 
Understand "hilf [dativ] [someone alive] mit [dativ] [something preferably held]" as helping it with.
Understand "befrei [dativ] [someone alive] mit [dativ] [something preferably held]" as helping it with.

Understand "hilf [dativ] [someone alive]" as helping it with.
Understand "befrei [dativ] [someone alive]" as helping it with.

Rule for supplying a missing second noun when helping something with: 
	now the second noun is the hands.

Before helping the unicorn with the hands when the unicorn is trapped, say "Du versuchst mit bloßen Händen bis an das Horn des Einhorns heranzukommen. Aber alles was du erreichst ist, dass du dir die Arme und Hände zerkratzt." instead.

Check helping it with: 
	if the noun is not the unicorn, say "Wie könntest du [dem noun] helfen?" instead.

Carry out helping it with:
	if the unicorn is trapped:
		if the second noun is the sword:
			say "Vorsichtig schneidest du mit dem Schwert die Äste des Baumes zurück bis du an das Horn herankommst und es mit einem kurzen Ruck aus dem Stamm des Baumes ziehen kannst. Das Einhorn schüttelt seine Mähne und reibt seine Nase an deiner Schulter. Mit einem dankbaren Blick aus seinen großen Augen verschwindet es nach Süden.";
			now the unicorn is free;
			clear the hint of the unicorn;
			clear the hint of the unicorn tree;
			now the unicorn is distant;
			now the unicorn is in the dense forest;
			now the initial appearance of the unicorn is "";
			now the special indefinite article of the unicorn is DEFINITE ARTICLE;
			now the destination of the sword is the house;
			now the hint of the sword is "Manchmal muss man doch kämpfen.";
			now the room illustration of clearing is Figure of clearing-without-unicorn;
			follow the image-setting rule;
		otherwise:
			say "Du kannst [dem noun] nicht mit [dem second noun] helfen.";
	otherwise:
		say "Du hast [den noun] schon befreit."
	

Part Climbing

Understand "besteig [something]" as climbing.
Understand "kraxel auf [something] [darauf]" as climbing.	
Understand "halt dich an [something] fest" as climbing.


Part Riding

Understand "reit [someone alive] [hinueber]" as climbing.
Understand "reit auf [someone alive] [hinueber]" as climbing.

Riding it over is an action applying to two things.
Understand "reit [someone alive] ueber [something]" as riding it over.
Understand "reit auf [someone alive] ueber [something]" as riding it over.
Understand "spring auf/mit [someone alive] ueber [something]" as riding it over.

Check riding something over: say "Du kannst nicht auf [dem noun] über [den second noun] springen." instead.


Part Cutting vs Attacking

Cutting it with is an action applying to one thing and one carried thing. 

Understand the command "brich" as something new.
Understand "brich [something]" as cutting.
Understand "brich [something] ab/auf/entzwei/kaputt/auseinander" as cutting.
Understand "brich [something] auf/auseinander mit [dativ] [something preferably held]" as cutting it with.
Understand "brich [something] mit [dativ] [something preferably held] auf/auseinander " as cutting it with.
Understand "brich [something] mit [dativ] [something preferably held] um/ab/entzwei/kaputt/auseinander" as cutting it with.
Understand the command "brech" as something new.
Understand the command "brech" as "brich".

Understand "entfern [something]" as cutting.
Understand the commands "erleg" as "toet".

Understand "faell [something]" as cutting.
Understand "faell [something] mit [dativ] [something preferably held]" as cutting it with.

Understand "hack [something] um/ab/entzwei/kaputt" as cutting.
Understand "hack [something] mit [dativ] [something preferably held] um/ab/entzwei/kaputt" as cutting it with.

Understand the command "hau" as something new.
Understand "hau [someone alive]" as attacking.
Understand "hau [noun hinein]" as attacking.
Understand "hau [something]" as attacking.
Understand "hau auf [something] ein" as attacking.
Understand "hau auf [something] [darauf]" as attacking.
Understand "hau [someone alive] um/entzwei/kaputt" as attacking.
Understand "hau [something] ab/um" as cutting.
Understand "hau [something] entzwei/kaputt" as attacking.
Understand "hau in [something] [hinein]" as attacking.
Understand "hau mit [dativ] [something preferably held] gegen [something]" as attacking it with (with nouns reversed).
Understand "hau [something preferably held] gegen [something]" as attacking it with (with nouns reversed).
Understand "hau [something] mit [dativ] [something preferably held] um/ab/entzwei/kaputt" as cutting it with.

Understand "jag [someone alive] davon/fort/weg" as attacking.
Understand "jag [someone alive] mit [dativ] [something preferably held] davon/fort/weg" as attacking it with.

Understand "saebel [something] ab" as cutting.
Understand "saebel [something] mit [dativ] [something preferably held] ab" as cutting it with.

Understand the command "schlag" as something new.
Understand "schlag [someone alive]" as attacking.
Understand "schlag [noun hinein]" as attacking.
Understand "schlag [something]" as attacking.
Understand "schlag auf [something] ein" as attacking.
Understand "schlag auf [something] [darauf]" as attacking.
Understand "schlag [something] ab/um" as cutting.
Understand "schlag [something] mit [something preferably held] ab/um" as cutting it with.
Understand "schlag [something] ab/um mit [dativ] [something preferably held]" as cutting it with.
Understand "schlag [something] entzwei/kaputt/ein" as attacking.
Understand "schlag in [something] [hinein]" as attacking.
Understand "schlag [someone alive] mit [dativ] [something preferably held]" as attacking it with.
Understand "schlag [something] mit [dativ] [something preferably held]" as attacking it with.
Understand "schlag [something] mit [dativ] [something preferably held] ein" as attacking it with.
Understand "schlag mit [dativ] [something preferably held] gegen/in [something]" as attacking it with (with nouns reversed).
Understand "schlag [something preferably held] gegen [something]" as attacking it with (with nouns reversed).
Understand "schlag [something] auf" as opening.
Understand "schlag [something] zu" as closing.
Understand "schlag nach in [dativ] [something]" as examining.
Understand "schlag in [dativ] [something] [text] nach" as consulting it about.
Understand "schlag in [dativ] [something] ueber/unter/zu [text] nach" as consulting it about.
Understand "schlag [force nach in] ueber/unter/zu [text] nach in [dativ] [something]" as consulting it about (with nouns reversed).
Understand "schlag [force nach in] [text] nach in [dativ] [something]" as consulting it about (with nouns reversed).
Understand "schlag [force nach] [text] in [dativ] [something] nach" as consulting it about (with nouns reversed).
Understand "schlag [something] mit [dativ] [something preferably held] um/ab/entzwei/kaputt" as cutting it with.

Understand "schneid [something] ab/zurueck" as cutting.
Understand "schneid [something] mit [dativ] [something preferably held]" as cutting it with.
Understand "schneid [something] mit [dativ] [something preferably held] ab/zurueck" as cutting it with.

Understand "trenn [something] ab" as cutting.
Understand "trenn [something] mit [dativ] [something preferably held] ab" as cutting it with.

Understand "erschreck [someone alive]" as attacking.
Understand "erschreck [someone alive] mit [dativ] [something preferably held]" as attacking it with.
Understand the command "verjag" and "verscheuch" and "vertreib" as "erschreck".

Understand "ziel auf [someone alive] mit [dativ] [something preferably held]" as attacking it with.
Understand "ziel auf [someone alive]" as attacking.
Understand "ziel mit [something] auf [dativ] [someone alive]" as attacking it with (with nouns reversed).


Check cutting it with:
	if the second noun is not a weapon:
		say "Das kannst du mit [dem second noun] nicht machen." instead;
	otherwise if the player does not carry the sword:
		say "Dafür benötigst du ein passendes Werkzeug." instead;
	otherwise if the noun is not the unicorn tree:
		try cutting the noun instead;
	otherwise if the unicorn is free:
		say "Das hast du schon gemacht." instead.
		
Carry out cutting it with:
	try helping the unicorn with the second noun.


Part Unlocking

Understand "schliess [something] auf" as unlocking it with.

Rule for supplying a missing second noun when unlocking something with:
	if the noun is the chest and the player carries the key:
		say "(mit dem Schlüssel)"; 
		now the second noun is the key;
	otherwise:
		say "Womit willst du [den noun] aufschließen?".


Part Jumping

Understand "spring in [something] [hinein]" as entering.
Understand "huepf in [something] [hinein]" as entering.
Understand "hops in [something] [hinein]" as entering.
Understand "schnell dich in [something] [hinein]" as entering.

Jumping over is an action applying to one thing. 
Understand "spring ueber [something] [hinueber]" as jumping over.
Understand "huepf ueber [something] [hinueber]" as jumping over.
Understand "hops ueber [something] [hinueber]" as jumping over.
Understand "schnell dich ueber [something] [hinueber]" as jumping over.

Carry out jumping over something (called the hurdle):
	say "Du kannst nicht über [den hurdle] springen.".


Part Jumping Down

Jumping down is an action applying to nothing.
Understand "spring [herunter]" as jumping down.

Instead of jumping down when the player is on a supporter (called the riser):
	try getting off the riser instead.
	
Instead of jumping down:
	try going down instead.

Jumping down from is an action applying to one thing.
Jumping down from is allowing wide scope. [* so jumping down from the location works *]
Understand "spring von/vom [something] [herunter]" as jumping down from.
	
Instead of jumping down from a room:
	try going down instead.

Instead of jumping down from a backdrop:
	try going down instead.


Part Flying

Flying with is an action applying to one thing.
Understand "flieg mit/auf [dativ][something] [herunter]" as Flying with.

Instead of flying with something:
	say "Du kannst nicht mit [dem noun] fliegen."


Part Swimming

Swimming is an action applying to nothing. 
Understand "schwimm" as swimming.

Carry out swimming:
	say "Worin willst du schwimmen?".	
	

Swimming in is an action applying to one visible thing. 
Understand "schwimm in [dativ] [something]" as swimming in.

Carry out swimming in:
	say "In [dem noun] kannst du nicht schwimmen.".	


Swimming to is an action applying to one visible thing. 
Understand "schwimm nach [direction]" as swimming to.
Understand "schwimm [direction]" as swimming to.

Carry out swimming to:
	if the noun is a direction:
		say "Du kannst nicht nach [noun] schwimmen.";
	otherwise:
		say "Du kannst nicht zu [dem noun] schwimmen.".	


Part Rowing

Rowing is an action applying to nothing. 
Understand "ruder" as rowing.
Understand "ruder rueber/hinueber" as rowing.

Carry out rowing:
	say "Worin willst du rudern?".	

	
Chapter Rowing In

Rowing in is an action applying to one thing.
Understand "ruder [dativ] [something]" as rowing in.
Understand "ruder [dativ] [something] rueber/hinueber" as rowing in.
Understand "ruder in/mit [dativ] [something]" as rowing in.
Understand "ruder ueber [dativ] [something]" as rowing in.
Understand "ruder in/mit [dativ] [something] rueber/hinueber" as rowing in.

Rowing in it over is an action applying to two things.
Understand "ruder in/mit [dativ] [something] ueber [anything]" as rowing in it over.
Understand "ruder ueber [dativ] [something] in/mit [anything]" as rowing in it over (with nouns reversed).

Carry out rowing in:
	say "In [dem noun] kannst du nicht rudern.".	


Chapter Rowing To

Rowing to is an action applying to one visible thing. 
Understand "ruder nach [direction]" as rowing to.
Understand "ruder [direction]" as rowing to.

Carry out rowing to:
	say "Du kannst hier nicht nach [noun] rudern.".	

	
Rowing in it to is an action applying to one thing and one visible thing. 
Understand "ruder [dativ] [something] nach [direction] " as rowing in it to.
Understand "ruder in/mit [dativ] [something] nach [direction] " as rowing in it to.

Carry out rowing in it to:
	say "In [dem noun] kannst du nicht nach [second noun] rudern.".
		

Understand the commands "paddel", "pull" as "ruder".


Part Knocking

Knocking on is an action applying to one thing. 
Understand "klopf an/gegen [something]" as knocking on.
Understand "schlag an/gegen [something]" as knocking on.

Carry out knocking on:
	if the player can touch the noun:
		say "Du klopfst an [den noun].";
	otherwise:		
		say "Du kannst nicht an [den noun] klopfen.";


Part Taking

Does the player mean taking a person: it is unlikely.
Does the player mean taking something carried by the player: it is very unlikely.

Understand "halt dich an [someone alive] fest" as taking.

[ otherwise the player tries to implicitly take the object ]
Before eating something inedible that is fixed in place , say "[Den noun] kannst du nicht essen." instead.
Before eating an inedible backdrop, say "[Den noun] kannst du nicht essen." instead.
Before drinking something inedible that is fixed in place , say "[Den noun] kannst du nicht trinken." instead.
Before drinking a backdrop, say "[Den noun] kannst du nicht trinken." instead.
Before wearing or taking off a backdrop, say "Das macht keinen Sinn." instead.
Before eating an inedible scenery thing, say "[Den noun] kannst du nicht essen." instead.
Before eating a person, say "[Den noun] kannst du nicht essen." instead.


Part Taking All

Rule for deciding whether all includes something that is lost: it does not.


Part Vaguely Communicating
	
Vaguely communicating someone is an action applying to one thing.
Check vaguely communicating someone (this is the block vaguely communicating someone rule):
	say "Bitte gib auch an, was [du] [dem noun] sagen oder was [du] [ihn] fragen möchtest."
	
Understand "antwort [dativ] [someone alive]" as vaguely communicating someone.
Understand "antwort zu [dativ] [someone alive]" as vaguely communicating someone.
Understand "antwort [dativ] [something]" as vaguely communicating someone.
Understand "antwort zu [dativ] [something]" as vaguely communicating someone.

Understand "red [someone alive]" as vaguely communicating someone.
Understand "red [something]" as vaguely communicating someone.
Understand "red mit/zu [dativ] [someone alive]" as vaguely communicating someone.
Understand "red mit/zu [dativ] [something]" as vaguely communicating someone.
Understand "red [someone alive] an" as vaguely communicating someone.
Understand "red [something] an" as vaguely communicating someone.

Understand "erzaehl [dativ] [someone alive]" as vaguely communicating someone.
Understand "erzaehl [dativ] [something]" as vaguely communicating someone.

Understand "frag [someone alive]" as vaguely communicating someone.
Understand "frag [someone alive] aus" as vaguely communicating someone.
Understand "frag [something]" as vaguely communicating someone.
Understand "frag [something] aus" as vaguely communicating someone.

	
Instead of vaguely communicating:
	repeat with target running through persons in the location: 
		if the target is not the player:
			say "(mit [dem target])";
			try telling the target about;
			rule succeeds;
	say "Du redest ein bisschen mit dir selbst, verlierst aber schnell den Spaß daran.";



Part Asking

Understand "frag [someone alive] [text]" as asking it about.


Part Ground

Understand "Umwelt [f]" or "Boden [m]" as "[basic-room-synonyms]".


Part Diverse verbs

Understand the commands "taetschel" and "taetschle" as "kuess".


Part Distant Scenery

A thing can be distant or near. A thing is usually near.

Instead of doing anything other than examining or looking for to a distant thing:
	say "[Der noun] [ist] zu weit weg."

Instead of doing anything when the second noun is a distant thing:
	say "[Der second noun] [ist] zu weit weg."


Part Knowledge

A thing can be known or unknown. A thing is usually unknown.

Before printing the name of an unvisited room:
	repeat with item running through things in the location:
		if the item is unknown and the player can see the item:
			now item is known;
	continue the action.

After printing the name of something unknown (called the knowable thing):
	now the knowable thing is known;
	continue the action.
		
After doing anything to something unknown (called the knowable thing):
	now the knowable thing is known;
	continue the action.


Part Friendly

A person can be friendly. A person is usually friendly.
 

Part Weapon

A thing can be a weapon. A thing is usually not a weapon.

Dropping-or-attacking is an action applying to one carried thing and requiring light.
Understand "wirf [something]" as dropping-or-attacking.

Check dropping-or-attacking:
	if the noun is a weapon:
		let the target be a random visible person who is not the player;
		if the target is a person:
			say "(auf [den target])";
			try attacking the target with the noun instead;
	try dropping the noun instead.



Book Timer Scheduled?

[ from "Extended Timers" by Gavin Lambert ]
Include (-
[ GetI7TimerTurns R i t;
	for (i=1: i<=(TimedEventsTable-->0): i++) {
		if (R == TimedEventsTable-->i) {
			t = TimedEventsTable-->i;
			if (t < 0) { return (-t - 1); }
			return (t - the_time);
		}
	}
	return -1;
];
-).

To decide which number is the number of turns until (R - a rule):
	(- GetI7TimerTurns({R}) -).

To decide if scheduled (R - a rule):
	let turns be the number of turns until R;
	if turns is less than zero, no;
	yes.


Book Death

Figure of death is the file "0.png".
When play ends when the story has not ended finally: 
	say "[bold type]Du bist tot![roman type]";
	now the currently shown picture is Figure of death;
	follow the current graphics drawing rule.


Book Backdrops

A backdrop has a room called found in.
The found in property translates into I6 as "found_in". 


Part Sky
 
The sky is a distant backdrop with printed name "Himmel[-s][m]". The sky is in the mountains, in the peak, in the dense forest, in the chasm, in the highlands, in the lowlands, in the clearing, in the swamp, in the lonely tree, in the house, in the river, in the castle, and in the desolation. The description is "Die Sonne scheint hell vom [if the clouds are in location]mit kleinen Wölkchen durchzogenen[otherwise]klaren[end if] Himmel."
Understand "himmel [m]" or "sonne [f]" or "wetter [n]" as "[sky names]".
Understand "[sky names]" or "wolkig/klar" as the sky.

Instead of smelling when the sky is in the location and the location is not the house:
	say "Es riecht frühlingshaft nach Blumen und Gräsern."


Part Clouds

The clouds are a distant backdrop with printed name "Wolken[p]". The clouds are in the mountains, in the peak, in the chasm, in the lowlands, in the clearing, in the swamp, in the lonely tree, in the river, in the castle, and in the desolation. The description is "Kleine Wölkchen durchziehen den Himmel."
Understand "wolke [f]" or "wolken [p]" or "woelkchen [p]" as "[cloud names]".
Understand "[cloud names]" or "klein" as the clouds.


Part Mountains

The distant mountains are a distant backdrop with printed name "fern[^] Berge[-n][p]". The distant mountains is in the peak, in the chasm, in the highlands, in the lowlands, in the swamp, in the lonely tree, in the river, in the castle, and in the desolation. 
The description is "In der Ferne siehst du mehrere Berge."
Understand "[mountain names]" as the distant mountains.

Does the player mean doing something to the distant mountains: it is very unlikely.
Rule for clarifying the parser's choice of the distant mountains: do nothing.


Part Stones

The stones are a backdrop with printed name "Steine[p]". The stones are in the mountains, in the peak, in the dense forest, in the chasm, in the highlands, in the lowlands, in the clearing, in the lonely tree, in the river, in the castle, and in the desolation. 
The description is "Auf dem Boden liegen einige Steine."

Understand "stein [m]" or "steine [p]" or "steinchen [p]" or "geroell [n]" or "kiesel [p]" as "[stone names]".
Understand "[stone names]" as the stones.

Does the player mean doing something to the stones: it is unlikely.
Rule for clarifying the parser's choice of the stones: do nothing.

Instead of taking the stones, say "Du musst nicht jeden Dreck aufheben."


Part Tree

The tree backdrop is a backdrop. The printed name is "Baum[-es][m]". The tree backdrop is in the lowlands, and in the lonely tree. The description is "Ein einzelner etwas verkrüppelter Baum, an den kurzen Ästen hängen dunkelgrüne Blätter".
Understand "busch [m]" or "gebuesch [n]" or "strauch [m]" or "baum [m]" as "[tree names]".
Understand "[tree names]" or "gruen/rau" or "wurzel [f]" or "wurzeln [p]" or "stamm [m]" or "rinde [f]" or "holz [n]" or "ast [m]" or "aeste [p]" or "zweig [m]" or "zweige [p]" or "blatt [n]" or "blaetter [p]" or "einzeln/einsam/verloren/verkrueppelt/verwachsen/krumm/kurz/dunkelgruen" as the tree backdrop.

Instead of going up when the tree backdrop is in the location: try climbing the tree backdrop.
Instead of climbing the tree backdrop, say "Du kletterst nicht gerne in Bäumen herum."
Instead of cutting the tree backdrop, say "Da du kein Feuerholz brauchst, lässt du den Baum in Ruhe."
Instead of listening to the tree backdrop, say "Die Blätter rauschen leise im Wind."
Instead of looking under the tree backdrop, say "Unter dem Baum ist ein wenig Gebüsch."
Instead of pulling the tree backdrop, say "Du ziehst an dem Baum, aber er bewegt sich kein Stück."
Instead of pushing the tree backdrop, say "Du drückst gegen den Baum, aber er bewegt sich kein Stück."
Instead of searching the tree backdrop, say "Du findest nur alte Blätter und tote Zweige."
Instead of smelling the tree backdrop, say "Es riecht leicht modrig."
Instead of tasting the tree backdrop, say "Du leckst an der Rinde des Baumes. Es schmeckt nicht so gut."
Instead of touching the tree backdrop, say "Die Rinde des Baumes fühlt sich rau an."

 
Part Forest

The forest backdrop is a backdrop. The printed name is "Wald[-es][m]". The forest backdrop is in the dense forest, and in the house. The description is "Der Wald besteht aus hohen Bäumen mit knorrigen Wurzeln. An den langen Ästen befinden sich Unmengen von frühlingshaft hellgrünen Blättern.".
Understand "[tree names]" or "wald [m]" or "forst [m]" or "gehoelz [n]" or "baeume [p]" or "straeucher [p]" as "[forest names]". 
Understand "[forest names]" or "knorrig/hoch/lang/hellgruen/fruehlingshaft/dicht" or "unterholz [n]" or "staemme [p]" as the forest backdrop.

Instead of going up when the forest backdrop is in the location: try climbing the forest backdrop.
Instead of climbing the forest backdrop, say "Du kletterst nicht gerne in Bäumen herum."
Instead of cutting the forest backdrop, say "Da du kein Feuerholz brauchst, lässt du den Wald in Ruhe."
Instead of entering the forest backdrop, say "Du bist doch schon im Wald."
Instead of getting off the forest backdrop, say "Du bist gar nicht auf einem Baum."
Instead of listening to the forest backdrop, say "Die Blätter rauschen leise im Wind."
Instead of looking under the forest backdrop, say "Unter den Bäumen ist dichtes Unterholz."
Instead of pulling the forest backdrop, say "Du ziehst an einem Baum, aber er bewegt sich kein Stück."
Instead of pushing the forest backdrop, say "Du drückst an einem Baum, aber er bewegt sich kein Stück."
Instead of searching the forest backdrop, say "Du findest nur alte Blätter und tote Zweige."
Instead of smelling the forest backdrop, say "Es riecht leicht modrig."
Instead of tasting the forest backdrop, say "Du leckst an der Rinde eines Baumes. Es schmeckt nicht so gut."
Instead of touching the forest backdrop, say "Die Rinde der Bäume fühlt sich rau an."


Book Understand

Understand "hallo/hi/moin/tag/tagchen" or "guten tag" or "gruess gott" as "[hello names]".

Understand "ade/tschues/tschuess/ciao/lebwohl/lebewohl/servus/bye/wiedersehen" or "machs gut" or "bis/auf bald" or "auf wiedersehen" as "[bye names]".

Understand "selbst" or "du" or "dich" or "dir" as "[other names]".



Book Quipping

A quip is a kind of value.  The quips are defined by the Table of Quip Texts. 
The current quip is a quip that varies.

Quipping is an activity.  
The last for quipping rule (this is the basic quipping rule): say "[Der noun] [says]: '[quiptext of the current quip]'[paragraph break]";

To deliver the (q - quip) quip:
	change the current quip to q;
	carry out the quipping activity;
		
Table of Quip Texts
quip		quiptext
empty-quip	""

To say says:
	if the noun is a person:
		if the noun is friendly:
			say "[one of]antwortet[or]sagt[or]meint[at random]";
		otherwise:
			say "[one of]brummt[or]grummelt[or]knurrt[at random]";
	otherwise:
		if the second noun is a person:
			if the second noun is friendly:
				say "[one of]antwortet[or]sagt[or]meint[at random]";
			otherwise:
				say "[one of]brummt[or]grummelt[or]knurrt[at random]";
		otherwise:
			say "sagt".
					
		
Book Player

Part Description

The player is male. The description of the player is "Du bist ein Halbling: mit deinen 1,12 Metern bist du etwa halb so groß wie ein Mensch. Du hast rotbraunes Haar und ein kleines Bäuchelchen. Deine kurzen Arme enden in feingliedrigen Händen und deine stämmigen Beine in behaarten Füßen. Du bist mit einer Hose und einem Hemd bekleidet. Auf dem Kopf trägst du einen Strohhut."
Understand "halbling [m]" or "held [m]" or "abenteurer [m]" as "[halbling names]".
Understand "selbst" or "ich" or "mich" or "mir" as "[self names]".
Understand "[halbling names]" or  "[self names]" or "klein/kurz" as yourself.

Player-knows-dragons-weak-spot is a truth state that varies. Player-knows-dragons-weak-spot is false.


Part Parts

The hands are a part of yourself. The printed name of hands is "Hände[-n][p]".
The description is "Du siehst nichts Besonderes an deinen Händen."
Understand "mein/dein" or "hand [f]" or "haende [p]" as the hands.

Before doing anything other than examining with the hands, say "Das kannst du mit deinen Händen nicht machen." instead.
Before doing anything when the second noun are the hands, say "Das kannst du mit deinen Händen nicht machen." instead.

Does the player mean doing something with the hands: it is unlikely.

Part Rules

Instead of looking under yourself, say "Unter dir siehst du verschwommen deinen Schatten auf dem Boden."
Instead of searching yourself, try taking inventory.
Instead of listening to yourself, say "Du lauschst auf deinen Herzschlag und deinen Atem."
Instead of smelling yourself, say "Du riechst an dir und entscheidest dich spontan bald wieder ein Bad zu nehmen."
Before climbing or pulling or pushing or turning or opening or closing or switching on or switching off or wearing or taking off or eating or drinking or entering or getting off or dropping or taking or swimming in or rowing in yourself, say "Das geht nicht." instead.
Instead of waking yourself, say "Du bist schon wach."
Instead of kissing or touching or rubbing or squeezing or tasting yourself, say "Nein, das mache ich nicht."
Instead of attacking or burning or cutting or knocking on yourself, say "Du kommst gerade noch rechtzeitig zu Sinnen und lässt es bleiben."
Instead of waving yourself, say "Du winkst mit der Hand."
Instead of following yourself, say "Aber du folgst dir doch immer."




Volume 1 

Book 1 Cave

The cave is a room with printed name "Halblinghöhle[f]". "Du bist in deiner Wohnhöhle. Die Wände der Eingangshalle sind in ruhigen Blautönen gestrichen. Es ist ein lauer Tag und es duftet nach Frühling. Durch die offene Tür im Norden fällt warmer Sonnenschein."
Figure of cave is the file "1-1.png". The room illustration is figure of cave.
The destination name of the cave is "zur Halblinghöhle".
Understand "hoehle [f]" or "wohnhoehle [f]" or "halblinghoehle [f]" as "[cave names]". 
Understand "[cave names]" or "offen" or "warm" or "hell" or "kammer [f]" or "halle [f]" or "eingangshalle [f]" or "eingang [m]" or "zimmer [n]" or "tuer [f]" or "schein [m]" or "sonnenschein [m]"  as the cave.

The player is in the cave.

Instead of location-leaving the cave:
	try going north instead;
	rule succeeds.
 
Instead of smelling in the cave:
	say "Durch die Tür dringt der Geruch des Frühlings: es duftet nach Blumen und Gräsern."

Part Chest

In the cave is a chest with printed name "Truhe[f]". The chest is a locked container, fixed in place. 

The description of the chest is "Eine massive Holztruhe beschlagen mit Metallbändern und gesichert durch ein Schloss.[if the key is lost] Wenn du dich nur erinnern könntest, wo du den Schlüssel hin getan hast - oder hast du ihn gar verloren? Du hattest ihn noch als du im Wald warst...[end if]". The hint of the chest is "Du solltest den Truhenschlüssel suchen.".

Understand "truhe [f]" or "holztruhe [f]" or "kiste [f]" as "[chest names]".
Understand "[chest names]" or "massiv" or "schloss [n]" or "holz [n]" or "metall [n]" or "band [n]" or "metallband [n]" or "baender [p]" or "metallbaender [p]" as the chest.

Before wearing or taking off the chest, try taking the chest instead.
Instead of taking or pushing or pulling or turning the chest, say "Die Truhe ist zu schwer."
Instead of cutting the chest, say "Die Truhe ist zu stabil."
Instead of cutting the chest with something, try cutting the chest.
Instead of jumping over the chest, say "Du springst über die Truhe."

Instead of opening the locked chest when the player has the key:
	say "(Du schließt die Truhe mit dem Schlüssel auf)";
	try  unlocking the chest with the key.
	
After unlocking the chest with the key:
	clear the hint of the key;
	try opening the chest.

After opening the chest:
	clear the hint of the chest;
	continue the action.


Part Book

In the chest is a book with printed name "Buch[-es][n]".
The description of the book is "Ein altes Buch über Drachen. Leider kannst du die Schrift nicht lesen, es scheint aber um das Drachentöten im Allgemeinen und den Drachen 'Smang' im Besonderen zu gehen. [if player-knows-dragons-weak-spot is true]Björn konnte immerhin den Hinweis [italic type]'Ein blinder Fleck erfüllt den Zweck!'[roman type] entziffern[else]Vielleicht findest du ja jemanden, der das Buch lesen kann[end if]."
The destination of the book is the castle. The hint of the book is "Du musst jemanden finden, der das Buch lesen kann."
Understand "buch [n]" or "band [m]" or "schinken [m]" or "schmoeker [m]" as "[book names]".
Understand "[book names]" or "alt" or "schrift [f]" as the book.


Part Sword

In the chest is a sword with printed name "Schwert[-es][n]". The special indefinite article of the sword is yours. The sword is a weapon. The destination of the sword is the clearing. The hint of the sword is "Mit einem Schwert kann man nicht nur kämpfen."
The description of the sword is "Dein treues Schwert. Schon etwas abgenutzt, aber immer noch ziemlich scharf."
Understand "schwert [n]" or "waffe [f]" as "[sword names]".
Understand "[sword names]" or "dein/treu/abgenutzt/ziemlich/scharf" as the sword.



Book 2 Mountains

The mountains is a plural-named room with printed name "Berge[-n][p]". "Vor dir erstreckt sich ein gewaltiger Gebirgszug.[if the unicorn is in the chasm] Weiter im Osten wartet das Einhorn auf dich.[end if]".
Figure of mountains is the file "1-2.png". The room illustration is Figure of mountains. 
The destination name of the mountains is "zu den Bergen". 
The hint of the mountains is "Berge kann man besteigen.".

The mountain backdrop is a backdrop in the mountains with printed name "Gebirge[-s][n]". The description is "Die Berge sind schroff und abweisend - und sehr, sehr hoch."
Understand "berg [m]" or "berge [p]" or "huegel [p]" or "gebirge [n]" or "gebirgszug [m]" as "[mountain names]".
Understand  "[mountain names]" or "abweisend/fern/gewaltig/hoch/hohe/schroff" or "horizont [m]" as the mountain backdrop.

The hint of the mountain backdrop is "Berge kann man besteigen.".
Rule for clarifying the parser's choice of the mountain backdrop: do nothing.
		
The mountains are north of the cave.
Outside from the cave are the mountains.


Instead of entering or climbing the mountain backdrop, try going up.


After deciding the scope of the player while the location is the mountains: 
	if the unicorn is in the chasm:
		place the unicorn in scope.

Every turn when the player is in the mountains and the unicorn is in the mountains:
	now the unicorn is in the chasm;
	now the room illustration of chasm is Figure of chasm-with-unicorn;
	say "Als du das Einhorn fast eingeholt hast, läuft es nach Osten weiter.";
	continue the action.

Instead of following the unicorn in the mountains when the unicorn is in the chasm:
	try going east.

[* because chasm can be unvisited *]
Instead of looking for the unicorn in the mountains when the unicorn is in the chasm and the chasm is unvisited:
	say "Wenn du das Einhorn suchst, musst du zum Abgrund gehen.".
	


Book 3 Peak

The peak is a room with printed name "Gipfel[-s][m]". "Auf dem höchsten Berggipfel des Gebirgszugs."
Figure of peak is the file "1-3.png". The room illustration is figure of peak. 
The destination name of the peak is "auf den Gipfel".
Understand "gipfel [m]" or "berggipfel [m]" or "spitze [f]" or "bergspitze [f]" or "berg [m]" or "anhoehe [f]" or "erhebung [f]" or "huegel [m]" as the peak. 

The peak is up from the mountains.

Instead of going down from the peak, say "Der Aufstieg war schon schwer, aber für einen Abstieg ist der Berg viel zu steil[if the rope is held] - selbst mit dem Seil ist es zu gefährlich[end if]."

Instead of location-leaving the peak, try going down instead.


Part Rraven

The raven is an animal in the peak with printed name "Rab[^] Crac[m]".
The special indefinite article of the raven is definite article.
"Der Rabe Crac sitzt auf seinem Nest.[contents of nest]".

The description is "Crac ist ein mächtiger Rabe mit weiten Schwingen und kräftigen Krallen."

Understand "crac [m]" or "rabe [m]" or "vogel [m]" as "[raven names]".
Understand "[raven names]" or "maechtig/weit/kraeftig" or "tier [n]" or "fluegel [m]" or "schwinge [f]" or "schnabel [m]" or "kralle [f]" or "feder [f]" or "federn [p]" or "gefieder [n]" or "auge [n]" as the raven. 
The hint of the raven is "Crac ist ein sehr starker Vogel. Er kann dir bestimmt helfen den Gipfel wieder zu verlassen.".

Does the player mean searching the raven: it is very unlikely.
Instead of removing the raven from something: try taking the raven.

After going to the peak:
	clear the hint of the mountain backdrop;
	continue the action.

Every turn when the player is in the peak:
	if a random chance of 1 in 3 succeeds:
		say "Crac [one of]schaut dich aus seinen scharfen Augen prüfend an[or]schlägt ungeduldig mit den Flügeln[or]wetzt seinen Schnabel an seinen Krallen[at random]."

Instead of asking the raven about something:
	try telling the raven about.
	
Instead of telling the raven about something, say "Crac [says]: '[one of]Croac[or]Krah[or]Krah! Krah[or]Krächz[at random]!'."

Instead of kissing the raven, say "Crac wirft Dir einen fragenden Blick zu und hopst außer Reichweite."

Instead of flying with the raven:
	try taking the raven.

Instead of taking or climbing the raven:
	say "Du wirst dich nicht lange genug an Crac festhalten können. Du müsstest irgendwie verhindern, dass sich dein Griff in der Luft lockert."
		
Instead of tying the rope to the raven when the location is the peak:
	if the player is carrying the rope:
		say "Du schlingst das Seil mehrfach um deinen Leib und um Cracs Krallen, dann hältst du dich gut fest. Crac öffnet seine Schwingen und trägt dich zum Fuß des Berges.";
		move the player to the mountains;
		clear the hint of the raven;
		now the hint of the rope is "An einem Seil kann man etwas herausziehen.";
		now the destination of the rope is the swamp;
	otherwise:
		say "Du hast nichts, mit dem du dich an Crac festbinden könntest."
			
Instead of tying the raven to the rope when the location is the peak, try tying the rope to the raven.
Instead of tying the rope to the player when the location is the peak, try tying the rope to the raven.
Instead of tying the player to the rope when the location is the peak, try tying the rope to the raven.
Instead of tying the player to the raven when the location is the peak, try tying the rope to the raven.
Instead of tying the raven to the player when the location is the peak, try tying the rope to the raven.

Instead of attacking the raven, say "Crac flattert aufgeregt zur Seite und wirft dir einen irritierten Blick zu.".

Part Nest

The nest is an open scenery container in the peak. The printed name is "Nest[-s][n]". The description is "Das Nest besteht aus vielen ineinander verflochtenen Zweigen und Halmen." The hint of the nest is "Vielleicht ist etwas in dem Nest versteckt?".
Understand "nest [n]" or "horst [m]" as "[nest names]".
Understand "[nest names]" or "viel/verflochten" or "zweig [m]" or "halm [m]" as the nest.

To say contents of nest:
	if the nest contains something not lost:
		say " In dem Nest ";
		if the nest contains more than one not lost thing:
			say "liegen";
		otherwise:
			say "liegt";
		say " [a list of not lost things in the nest].".	
		
Instead of taking the nest, say "Crac krächzt aufgebracht und hackt mit dem Schnabel nach dir."


Part Rope

The rope is a thing in the nest with printed name "Seil[-es][n]". The description of the rope is "Das Seil ist stark genug um dich zu tragen.". The hint of the rope is "Mit einem Seil kann man Sachen zusammenbinden."

Instead of doing anything other than looking for to something lost:
	say "Du kannst hier [keinen noun] sehen.".

Understand "seil [n]" or "strick [m]" or "tau [n]" or "leine [f]" or "strippe [f]" or "kordel [f]" as "[rope names]". 
Understand "[rope names]" as the rope.

The rope can be found or lost. The rope is lost.
Does the player mean taking the rope when the rope is found: it is likely. 

Instead of examining or searching the nest when the rope is lost:
	say "[Description of the nest] Ein Zweig erregt deine Aufmerksamkeit. Du betrachtest den vermeintlichen Zweig genauer und stellst fest, dass es sich um ein Seil zu handeln scheint.";
	clear the hint of the nest;
	now the rope is found;
	now the rope is known.

Instead of tying the rope to the stones when in the peak, try tying the rope to the nest.
Instead of tying the rope to the nest, say "Das Seil ist zu kurz, um bis an den Fuß des Berges zu reichen."


Instead of inserting the rope into something:
	say "Lieber nicht, es könnte nochmal nützlich sein."
	
Instead of dropping the rope when the location is not the swamp:
	say "Lieber nicht, es könnte nochmal nützlich sein."



Book 4 Dense Forest

The dense forest is a room with printed name "Dicht[^] Wald[m]". "Dichter Wald umgibt dich.[if the unicorn is in the mountains] Im Osten kannst du das Einhorn erkennen.[end if]". 
Figure of dense forest is the file "1-4.png". The room illustration is figure of dense forest. 
The destination name of the dense forest is "in den dichten Wald". 

The dense forest is west from the mountains.


Part Track

In the dense forest is a track with printed name "Spur[f]". The track is fixed in place.
The description of the track is "Auf dem Boden siehst du [if the lowlands is visited]die Fußspur des Trolls.[otherwise]eine mysteriöse Fußspur. [one of]Wo die wohl hinführt?[or]Vielleicht solltest du der Spur folgen?[cycling][end if]".
The hint of the track is "Folge der Spur, sie führt dich durch den Wald.".
Understand "spur [f]" or "fussspur [f]" or "fussabdruck [m]" or "abdruecke [p]" or "fussabdruecke [p]" or "stapfen [p]" or "fussstapfen [p]" or "faehrte [f]" as "[track names]".
Understand  "[track names]" or "mysterioes" or "boden [m]" as the track.

Instead of going west in the dense forest when the lowlands have not been visited:
	say "Du irrst etwas durch den dichten Wald bis du wieder auf die Fußspur stößt.".

Instead of following the track:		
	say "Du folgst der Fußspur durch den dichten Wald und gelangst endlich auf eine weite Ebene.";
	clear the hint of the track;
	now the lowlands is mapped west of dense forest;
	move the player to the lowlands. 
	
After deciding the scope of the player while the location is the dense forest:
	if the unicorn is in the mountains:
		place the unicorn in scope. 

Every turn when the player is in the dense forest and the unicorn is in the dense forest:
	now the unicorn is in the mountains;
	say "Das Einhorn hat hier auf dich gewartet und läuft weiter nach Osten.";
	continue the action.
	
Instead of following the unicorn in the dense forest when the unicorn is in the mountains:
	try going east.



Book 5 Chasm

The chasm is a room with printed name "Abgrund[-s] ([if the swamp is visited]Südlich[else]Nördlich[end if] des Spalts)[m]". "Der Weg windet sich dicht an einem Abgrund entlang in [if the swamp is visited]nördlicher[else]südlicher[end if] Richtung. Du hältst dich nah an der Felswand, um nicht abzustürzen. Abrupt wird der Weg durch einen tiefen Spalt unterbrochen."
Figure of chasm-without-unicorn is the file "1-5a.png". Figure of chasm-with-unicorn is the file "1-5b.png". The room illustration is figure of chasm-without-unicorn. 
The destination name of the chasm is "zum Abgrund".


Part Chasm Backdrop

The chasm backdrop is a backdrop in the chasm with printed name "Abgrund[-s][m]". The description is "Der Weg wird auf der einen Seite von einer glatten Felswand und auf der anderen von einem gähnenden Abgrund gesäumt - dir wird schon vom bloßen Hinschauen schwindelig." 
The hint of the chasm backdrop is "Dein Problem ist nicht der Abgrund, sondern der Spalt im Weg.".
Understand "abgrund [m]" or "schlucht [f]" or "schlund [m]" as "[chasm names]".
Understand "[chasm names]" or "glatt/gaehnend" or "wand [f]" or "felswand [f]" or "fels [m]" or "felsen [p]" or "tiefe [f]" as the chasm backdrop.


Part Crack

The crack is a backdrop in the chasm. The printed name is "Spalt[-s][m]". The description is "Der Weg wird durch einen tiefen, mehrere Meter breiten Spalt unterbrochen." 
The hint of the crack is "Hier brauchst du Hilfe von jemandem der gut springen kann.".
Understand "spalt [m]" or "spalte [f]" or "erdspalt [m]" or "erdspalte [f]" as "[crack names]".
Understand "[crack names]" or "tief" or "weg [m]" or "pfad [m]" or "riss [m]" as the crack.

The chasm is east from the mountains.

Instead of tying the rope to the chasm backdrop:
	say "Du findest keine Stelle, an der du das Seil festmachen könntest.".
	
Instead of tying the rope to the crack:
	say "Du kannst das Seil nicht an den Spalt binden.".


Every turn when the player is in the chasm and the unicorn is in the chasm:
	if the unicorn is distant:
		now the unicorn is near;
		now the hint of the unicorn is "Einhörner können gut springen.";
	if a random chance of 1 in 2 succeeds:
		say "Das Einhorn [one of]wiehert auffordernd[or]tänzelt unruhig auf der Stelle[at random]."

Instead of jumping over when the noun is the chasm backdrop:
	say "Der Abgrund ist viel zu breit um darüber zu springen: du könntest ja noch nicht einmal über den Spalt im Weg springen!".

Instead of jumping over when the noun is the crack:
	say "Zu versuchen über den Spalt zu springen war keine gute Idee:[line break]Dein Sprung war nicht sehr weit, aber dein Fall sehr tief...";
	end the story.

Instead of entering or climbing the chasm backdrop:
	try entering the crack.
	
Instead of going down in the chasm:
	try entering the crack instead.
		
Instead of entering or climbing the crack:
	say "Das war keine gute Idee:[line break]Du rutschst ab und fällst sehr tief...";
	end the story.

Instead of riding the unicorn over the crack, try climbing the unicorn instead.
Instead of riding the unicorn over the chasm backdrop, say "Der Abgrund ist viel zu breit, aber vielleicht könnte das Einhorn über den Spalt im Weg springen?" instead.

Instead of climbing or entering the unicorn when the unicorn is not in the chasm:
	say "Das Einhorn tänzelt unruhig und lässt dich nicht aufsteigen."

Instead of climbing or entering the unicorn when the unicorn is in the chasm:
	say "Du kletterst mehr schlecht als recht auf das Einhorn und hältst dich an der Mähne fest. Das Einhorn nimmt einen kurzen Anlauf und springt mühelos über den Spalt. Du steigst ab und legst erschöpft eine kleine Pause ein. Das Einhorn wiehert dir aufmunternd zu und verlässt dich.[paragraph break]Nachdem du dich etwas erholt hast, machst du dich weiter auf den Weg nach Süden.";
	clear the hint of the unicorn;
	remove the unicorn from play;
	now the room illustration of chasm is Figure of chasm-without-unicorn;
	clear the hint of the chasm backdrop;
	clear the hint of the crack;
	now nowhere is mapped west of the chasm;
	now the swamp is mapped south of the chasm;
	now the chasm is mapped west of the swamp;
	move the player to the swamp.



Book 6 Highlands

The highlands is a room with printed name "Gebirge[n]". "Du befindest dich auf einer weiten Hochebene im Gebirge."
Figure of highlands-with-crystal is the file "1-6a.png". Figure of highlands-without-crystal is the file "1-6b.png". The room illustration is Figure of highlands-with-crystal. 
The destination name of the highlands is "ins Gebirge". 
Understand "weit" or "ebene [f]" or "gebirge [n]" or "hochebene [f]" as the highlands.

The highlands is east of the peak.


Part Crystal

In the highlands is a crystal with printed name "funkelnd[^] Kristall[-s][m]".
The description of the crystal is "Ein bunter Kristall. Er funkelt in allen Farben des Regenbogens."
The hint of the crystal is "Du hast für so etwas nicht viel übrig. Vielleicht gibt es jemanden, dem der Kristall mehr bedeutet.". 
Understand "kristall [m]" or "edelstein [m]" or "juwel [n]" or "diamant [m]" or "klunker [m]" as "[crystal names]".
Understand "[crystal names]" or "bunt/farbig/farben/funkelnd" or "in allen farben" or "in allen farben des regenbogens" as the crystal.

After taking the crystal for the first time:
	now the room illustration of highlands is Figure of highlands-without-crystal;
	follow the image-setting rule;
	continue the action.



Book 7 Lowlands

The lowlands is a room with printed name "Ebene[f]". "Vor dir erstreckt sich eine weite Ebene."
Figure of lowlands is the file "1-7.png". The room illustration is figure of lowlands. 
The destination name of the lowlands is "zur Ebene". 
Understand "ebene [f]" or "tiefebene [f]" as "[lowlands names]".
Understand "[lowlands names]" or "weit" as the lowlands.

The lowlands is west of the dense forest.


Part Troll

The troll is a man in the lowlands with printed name "Troll[-s]". "Du siehst hier [if the lowlands has been visited]den[else]einen[end if] Troll.[first time] Er sieht dich etwas verwundert an und grüßt mit einem freundlichen 'Hallo!'.[only]". 
The description of the troll is "Ein Troll. Er hat [a list of things carried by the troll with accusative]."
The hint of the troll is "Trolle mögen glitzernde Sachen."
Understand "troll [m]" or "gnom [m]" or "kobold [m]" as "[troll names]".
Understand "[troll names]" as the troll.

troll-knows-about-crystal is a truth state that varies. troll-knows-about-crystal is false.
troll-has-seen-crystal is a truth state that varies. troll-has-seen-crystal is false.


Part Key

The key is a thing with printed name "Schlüssel[-s][m]". The key unlocks the chest.
The description of the key is "Ein kleiner Messingschlüssel.".
The destination of the key is the cave.
The hint of the key is "Hast du den Schlüssel schon an der Truhe probiert?".
Understand  "schluessel [m]" or "messingschluessel [m]" or "metallschluessel [m]" or "truhenschluessel [m]" as "[key names]".
Understand "[key names]" or "metall/messing" as the key.

The key can be lost or found. The key is lost.

The troll carries the key.
After examining the troll: 
	now the key is found;
	now the key is known.

Instead of asking the troll for the key when the troll has the key:
	say "Der Troll entgegnet: 'Wenn du mir etwas für den Schlüssel gibst, kannst du ihn gerne haben.'".

Instead of answering the troll that something:
	try telling the troll about.

Instead of asking the troll to try giving the key to the player when the troll has the key:
	try taking the key instead.

Instead of taking the key when the troll has the key:
	say "Der Troll ruft: 'Hey - den habe [italic type]ich[roman type] gefunden!'".
	
Instead of giving the crystal to the troll: 
  say "Du gibst dem Troll den Kristall, der ihn mit leuchtenden Augen entgegen nimmt. Der Troll besinnt sich kurz und gibt dir dann den Schlüssel.";
  now troll-knows-about-crystal is true;
  now troll-has-seen-crystal is true;
  now the troll has the crystal;
  now the hint of the chest is "Vielleicht ist etwas Wichtiges in der Truhe.";
  clear the hint of the crystal;
  clear the hint of the troll;
  now the key is found;
  now the key is known;
  now the player has the key.

Instead of giving something to the troll: 
  say "Der Troll betrachtet [den noun] und sagt 'Danke, aber dafür habe ich keine Verwendung!'."


Instead of showing the crystal to the troll: 
  now troll-knows-about-crystal is true;
  now troll-has-seen-crystal is true; 
  say "Der Troll betrachtet den Kristall mit leuchtenden Augen und sagt '[one of]Oh, ist der aber schön[or]Wirklich schön[stopping]!'."

Instead of showing something to the troll: 
  say "Der Troll betrachtet [den noun] und sagt 'Nett, aber ich will [den noun] nicht!'."


Instead of telling the troll about "[crystal names]":
	now troll-knows-about-crystal is true;
	if troll-has-seen-crystal is true:
		if the troll has the crystal:
			say "Der Kristall ist wirklich schön! Danke, dass du ihn mir gegeben hast.";
		otherwise:
			say "[Der noun] [says]: 'Bitte gib ihn mir[one of][or]! Ich gebe dir auch den Schlüssel dafür[stopping]!'";
	otherwise:
		say "[Der noun] [says]: 'Dann zeig mir diesen wunderbaren Kristall doch mal!'."
  
Understand "was kann/soll ich dir geben" or "was willst/moechtest du"  or "was willst/moechtest du haben" or "was er will" or "was willst du für den schlüssel" or "was willst du für den schlüssel haben" as "[troll want names]".

Instead of asking the troll about "[troll want names]":
	if the troll has the crystal:
		say "[Der noun] [says]: 'Danke, ich bin mit dem Kristall zufrieden'.";
	otherwise:
		if troll-knows-about-crystal is true:
			if troll-has-seen-crystal is true:
				say "[Der noun] [says]: 'Der Kristall gefällt mir'.";
			otherwise:
				say "[Der noun] [says]: 'Dieser Kristall könnte mir gefallen'.";
		otherwise:
			say "[Der noun] [says]: 'Ich weiß nicht - vielleicht etwas Schönes?'.".

Instead of telling the troll about "[troll want names]": try asking the troll about.

Instead of telling the troll about:
	say "[Der noun] [says]: '[one of]Das interessiert mich nicht[or]So, so[or]Danke, kein Interesse[at random]!'.".	

Instead of asking the troll about "[crystal names]":
	if troll-knows-about-crystal is true:
		if the troll has the crystal:
			say "Der Kristall ist wirklich schön! Danke, dass du ihn mir gegeben hast.";
		otherwise:
			if troll-has-seen-crystal is true:
				say "[Der noun] [says]: 'Bitte gib ihn mir[one of][or]! Ich gebe dir auch den Schlüssel dafür[stopping]!'";
			otherwise:
				say "[Der noun] [says]: 'Dann zeig mir den Kristall doch mal!'.";
	otherwise:
		say "[Der noun] [says]: 'Welcher Kristall?'"

 
Instead of asking the troll about "[key names]":
	if troll-knows-about-crystal is true:
		if the troll has the crystal:
			say "[Der noun] [says]: 'Ich habe dir den Schlüssel doch gegeben.'";
		otherwise:
			if troll-has-seen-crystal is true:
				say "[Der noun] [says]: 'Wenn du mir den Kristall gibst, gebe ich dir den Schlüssel.'";
	otherwise:
		if the key is lost:
			say "[Der noun] [says]: 'Ich habe einen Schlüssel im Wald gefunden'.[line break]Er zeigt dir einen kleinen Messingschlüssel.";
			now the key is found;
			now the key is known;
		otherwise:
			say "[Der noun] [says]: 'Ich weiß nicht wofür der Schlüssel gut ist. Wenn du mir etwas dafür gibst, kannst du ihn gerne haben.'".
		
Instead of telling the troll about a topic listed in the Table of Troll Tell Results:
	repeat through Table of Troll Tell Results:
		if the topic understood includes topic entry:
			deliver the result entry quip;
			rule succeeds.		 

Instead of asking the troll about a topic listed in the Table of Troll Ask Results:
	repeat through Table of Troll Ask Results:
		if the topic understood includes topic entry:
			deliver the result entry quip;
			rule succeeds.	 

Table of Troll Ask Results
topic    	result
"[chasm names]"			ask-troll-chasm
"[cloud names]"   			ask-troll-weather
"[crack names]"				ask-troll-crack
"[desolation names]"		ask-troll-dragon
"[dragon names]"			ask-troll-dragon
"[dwarf names]"				ask-troll-dwarf
"[forest names]"				ask-troll-track
"[lowlands names]"		ask-troll-place
"[mountain names]"		ask-troll-place
"[other names]"				ask-troll-self	
"[rope names]"				ask-troll-rope
"[sky names]"   				ask-troll-weather
"[track names]"				ask-troll-track
"[tree names]"				ask-troll-place
"[troll names]"				ask-troll-self	
"[unicorn names]"			ask-troll-unicorn

Table of Troll Tell Results
topic		result
"[hello names]"				troll-hello
"[self names]"					tell-troll-self
"[halbling names]"			tell-troll-self
"[cave names]"				tell-troll-cave
"[chasm names]"			tell-troll-chasm
"[cloud names]"				tell-troll-weather
"[crack names]"				tell-troll-chasm
"[desolation names]"		tell-troll-desolation
"[dragon names]"			tell-troll-dragon
"[forest names]"				tell-troll-forest
"[sky names]"					tell-troll-weather
"[track names]"				tell-troll-track
"[unicorn names]"			tell-troll-unicorn
"[bye names]"				troll-bye

Table of Quip Texts (continued)
quip		quiptext
troll-hello					"Hallo!"
ask-troll-chasm		"Ein Zwerg hat mir mal erzählt, dass der Weg weitergeht, wenn man über die Erdspalte drüber kommt."
ask-troll-crack			"Ich bin zu klein um über die Spalte zu springen. Aber das Einhorn habe ich schon auf der anderen Seite gesehen."
ask-troll-dragon		"[one of]Von dem Drachen habe ich schon gehört[or]Der Drache soll ein großes Gebiet verwüstet haben[or]Hoffentlich befreit uns jemand von dem Drachen[at random]."
ask-troll-dwarf			"Ach, es ist schon einige Zeit her, dass ich ihn getroffen habe. Er hat erzählt, dass er von südlich des Abgrunds kommt."
ask-troll-place			"[one of]Ich komme gerne hierher.[or]Ich mag den Wald.[at random]"
ask-troll-rope			"Ein Seil ist immer praktisch: beim Bergsteigen oder im Moor, zum Beispiel."
ask-troll-self				"[one of]Ich mache einen Spaziergang[or]Ich vertrete mir ein bisschen die Beine[or]Ich bin öfter hier[at random]."
ask-troll-track			"Ich bin im Wald spazieren gegangen. Es kann gut sein, dass du meinen Fußabdrücken gefolgt bist."
ask-troll-unicorn		"Das Einhorn ist ein stattliches Tier. Ich sehe es manchmal auf einer Lichtung im Wald oder in der Nähe des Abgrunds."
ask-troll-weather		"Es soll noch wärmer werden."
tell-troll-cave			"Ach [italic type]du[roman type] wohnst da!"
tell-troll-chasm		"Den Abgrund kenne ich. Der Weg endet da an einer Erdspalte."
tell-troll-crack			"Über die Erdspalte bin ich noch nie rüber gekommen."
tell-troll-desolation	"Dass der Drache aber auch so ein großes Gebiet verwüstet hat. Ein richtiges Untier!"
tell-troll-dragon		"So ein gemeines Untier!"
tell-troll-forest			"Ich mag den Wald. Ich gehe dort gerne spazieren."
tell-troll-self				"[one of]Das ist interessant[or]Schön dich kennen zu lernen[at random]."
tell-troll-track			"Ach, dass können meine Fußabdrücke gewesen sein. Ich war im Wald spazieren."
tell-troll-unicorn		"Manchmal sehe ich das Einhorn im Wald."
tell-troll-weather		"Ja, das Wetter ist schön."
troll-bye					"Tschüss."

Instead of asking the troll about something: 
  say "Der Troll [says]: '[one of]Davon weiß ich nichts[or]Darüber weiß ich nichts[or]Da kann ich dir nicht weiterhelfen[at random]'."



Book 8 Clearing

The clearing is a room with printed name "Lichtung[f]". The description of clearing is "Eine kleine Lichtung im Wald.[if the unicorn is in the dense forest] Im Süden siehst du das Einhorn.[end if]".
Figure of clearing-with-unicorn is the file "1-8a.png". Figure of clearing-without-unicorn is the file "1-8b.png". The room illustration is figure of clearing-with-unicorn.
Understand "lichtung [f]" as the clearing.
The destination name of the clearing is "zur Lichtung". 

The clearing is north of the dense forest.


Part Unicorn

The unicorn is an animal in the clearing with printed name "Einhorn[-s][n]". "Ein Einhorn hat sich mit dem Horn in einem Baum verfangen.".
The description of the unicorn is "Ein weißes Einhorn mit roter Mähne.[if the unicorn is trapped] Es hat sich mit seinem Horn in einem Baum verfangen und schaut dich aus seinen großen Augen bittend an.[end if]". 
Understand "einhorn [n]" as "[unicorn names]".
Understand "[unicorn names]" or "weiss" or "huf [m]" or "stirn [f]" or "auge [n]" or "tier [n]" or "pferd [n]" or "pony [n]" as the unicorn.

The hint of the unicorn is "Du solltest das Einhorn aus dem Baum befreien.".

The unicorn can be free or trapped. The unicorn is trapped.

Chapter Horn

The horn is a part of the unicorn. The printed name is "Horn[n]". The description is "Das Horn des Einhorns ist lang und spitz und entspringt aus der Mitte seiner Stirn.[if the unicorn is trapped] Das Horn hat sich in einem Baum verfangen, so dass sich das Einhorn nicht befreien kann.[end if]".
Understand  "lang" or "spitz" or "horn [m]" as the Horn.

Chapter Mane

The mane is a part of the unicorn. The printed name is "Mähne[f]". The description is "Die Mähne des Einhorns ist leuchtend rot.".
Understand "leuchtend" or "rot" or "maehne [f]" or "haar [n]" or "fell [n]" as the mane.


Every turn when the player is in the clearing and the unicorn is in the clearing:
	if a random chance of 1 in 3 succeeds:
		say "Das Einhorn [one of]schaut dich aus seinen großen Augen bittend an[or]stampft wütend mit den Hufen[or]steht resigniert da[or]wirft seinen Kopf hin und her, kann sich aber nicht befreien[or]blickt dich ungeduldig an[at random]."

Instead of telling the unicorn about something:
	say "Das Einhorn [one of]blickt dich fragend an[or]wiehert irritiert[or]schnaubt fragend[at random].".

Instead of asking the unicorn about something, try telling the unicorn about.
Instead of asking the unicorn for something, try telling the unicorn about.
Instead of answering the unicorn that, try telling the unicorn about.
Instead of giving something to the unicorn, try telling the unicorn about.
Instead of showing something to the unicorn, try telling the unicorn about.

Instead of kissing the unicorn:
	if the unicorn is trapped:
		say "Du tätschelst dem Einhorn mitfühlend den Hals und versuchst es etwas zu beruhigen.";
	else:
		say "Du tätschelst dem Einhorn freundschaftlich den Hals."
		

Part Unicorn Tree

The unicorn tree is scenery in the clearing with printed name "Baum[-es][m]". The description is "Ein großer, alter Baum.[if the unicorn is trapped] Ein Einhorn hat sich mit seinem Horn in dem Baum verfangen, so dass es sich nicht befreien kann.[end if]".
The hint of the unicorn tree is "Um das Einhorn zu befreien solltest du die Äste des Baumes zurückschneiden.".
Understand "gross/alt" or "baum [m]" or "ast [m]" or "zweig [m]" or "busch [m]" or "gebuesch [n]" or "blatt [n]" or "aeste [p]" or "blaetter [p]" or "zweige [p]" as the unicorn tree. 


Instead of tying the rope to the horn when the unicorn is trapped:
	say "Du versuchst das Seil um das Horn des Einhorns zu schlingen, kommst aber nicht richtig an das Horn heran. Alles was du erreichst ist, dass du dir die Arme und Hände zerkratzt."
	
Instead of cutting the Horn when the unicorn is trapped:
	say "Du möchtest dem Einhorn nicht weh tun und wendest dich lieber dem Baum zu.";
	try cutting the unicorn tree.
	
Instead of cutting the Horn with something (called the tool) when the unicorn is trapped:
	say "Du möchtest dem Einhorn nicht weh tun und wendest dich lieber dem Baum zu.";
	try cutting the unicorn tree with the tool.

Instead of removing the Horn from something (called the box) when the unicorn is trapped:
	if the box is the unicorn tree:
		try pulling the Horn;
	otherwise:
		say "Aber das Horn ist gar nicht in [dem box]."

Instead of removing the unicorn from something (called the box) when the unicorn is trapped:
	if the box is the unicorn tree:
		try pulling the unicorn;
	otherwise:
		say "Aber das Einhorn ist gar nicht in [dem box]."

Instead of pulling the Horn when the unicorn is trapped:
	say "Es sind zu viele Äste im Weg. Du kommst zu schlecht an das Horn heran um es heraus zu ziehen."
	
Instead of pulling the unicorn when the unicorn is trapped:
	say "Du kannst das Einhorn nicht durch Ziehen befreien, sein Horn hängt zu fest."

Instead of attacking the unicorn tree with the sword:
	try cutting the unicorn tree with the sword.
	
Instead of cutting the unicorn tree:
	if the unicorn is trapped:
		try helping the unicorn with the second noun;
	otherwise:
		say "Du hast das Einhorn schon befreit."

After deciding the scope of the player while the location is the clearing: 
	if the unicorn is in the dense forest:
		place the unicorn in scope. 
	
Instead of following the unicorn in the clearing when the unicorn is in the dense forest:
	try going south.

[* if we see the unicorn in an adjacent room, we can't interact *]
Before doing anything other than examining or looking for or following to the unicorn:
	if the unicorn is distant:
		say "[Der noun] [ist] zu weit weg." instead;
	otherwise if the unicorn is in the chasm and the player is in the mountains:
		say "[Der noun] [ist] zu weit weg." instead.

Before doing anything when the second noun is the unicorn:
	if the unicorn is distant:
		say "[Der second noun] [ist] zu weit weg." instead;
	otherwise if the unicorn is in the chasm and the player is in the mountains:
		say "[Der second noun] [ist] zu weit weg." instead.	




Volume 2 

Book 1 Swamp

The swamp is a room with printed name "Moor[-es][n]". "[if the player wears the boots]Du bist im Moor. Die Stiefel bewahren dich davor im Morast zu versinken[else]Der Boden unter deinen Füssen fühlt sich sehr weich an[end if]."
Figure of swamp-without-dwarf is the file "2-1a.png". Figure of swamp-with-dwarf is the file "2-1b.png". The room illustration is figure of swamp-without-dwarf. 
The destination name of the swamp is "ins Moor". 
The hint of the swamp is "Das Moor ist nicht so einsam, wie es scheint.".

Part Swamp Backdrop

The swamp backdrop is a backdrop in the swamp with printed name "Moor[-es][n]". The description is "Der Boden besteht aus schlammigem Morast. Richtung Norden wird der Boden immer weicher, aber im Westen scheint er fester zu sein. [if the lonely tree is visited]Am Rande des Morasts siehst du die Fußabdrücke des Zwerges[else]Am Rande des Morasts bemerkst du viele kleine Fußabdrücke[end if]." 
The hint of the swamp backdrop is "Um Hilfe schreien?".
Understand "moor [n]" or "morast [m]" or "sumpf [m]" as "[swamp names]".
Understand "[swamp names]" or "schmutzig/dreckig/feucht/schlammig" or "schmutz [m]" or "schlamm [m]" or "dreck [m]" as the swamp backdrop.


Part Footprints

The footprints is a backdrop in the swamp. The printed name is "klein[^] Fußabdrücke[-n][p]".
The description of the footprints is "Auf dem Boden siehst du [if the lonely tree is visited]die Fußabdrücke des Zwergs.[otherwise]viele kleine Fußabdrücke; jemand scheint hier öfter vorbeizukommen.".
[* use [track names] instead of [footprint names] as they are the same *]
Understand "[track names]" or "klein/viel" or "abdruck [m]" or "boden [m]" as the footprints.

Instead of following the footprints:
	if the player wears the boots:
		say "Die Fußabdrücke bilden keine einheitliche Spur der du folgen könntest.";
	else:
		say "Du steckst im Moor fest.".

After going to the swamp:
	now the danger is 0;
	continue the action.
	
Every turn when the player is in the swamp:
	if the dwarf is in the swamp:
		if a random chance of 2 in 3 succeeds:
			say "Der Zwerg [one of]schaut dich ratlos an.[or]hüpft neben dem Moor auf und ab und ruft 'Was soll ich nur machen?'[or]läuft auf und ab und murmelt: 'Wie komme ich nur an dich heran?'[or]versucht dich herauszuziehen, kann dich aber nicht erreichen.[at random]";
	if the player does not wear the boots:
		increase danger by 1;	
		if danger is:
			-- 1: say "[italic type]Du beginnst im Moor zu versinken![roman type][paragraph break]";
			-- 2: say "[italic type]Du sinkst langsam immer tiefer![roman type][paragraph break]";
			-- 3: say "[italic type]Das Morast reicht dir bis an die Hose![roman type][paragraph break]";
			-- 4: say "[italic type]Langsam sinkst du bis zu den Waden ein![roman type][paragraph break]";
			-- 5: say "[italic type]Mittlerweile stecken auch deine Knie im Sumpf![roman type][paragraph break]";
			-- 6: say "[italic type]Langsam steigt das Moor bis zu deinem Bauch![roman type][paragraph break]";
			-- 7: say "[italic type]Das Moor steht dir jetzt bereits bis zur Brust. Langsam solltest du etwas unternehmen![roman type][paragraph break]";
			-- 8: say "[italic type]Das Moor reicht dir schon bis zu den Schultern![roman type][paragraph break]";
			-- 9: say "[italic type]Nur dein Kopf schaut noch aus dem Moor! - Irgendwelche letzten Worte?[roman type][paragraph break]";
			-- otherwise: 
				say "[italic type]Du bist im Moor versunken![roman type][paragraph break]";
				end the story.

Before going up in the swamp when the player does not wear the boots, try jumping instead.

Before going west in the swamp when the player does not wear the boots:
		say "Mit viel Mühe schaffst du es dich unendlich langsam auf festeren Boden Richtung Westen vorzuarbeiten.[paragraph break]"

Before going north in the swamp when the player does not wear the boots:
		say "Nach Norden wird der Boden nur noch weicher!" instead.

To swim up:
	say "Du schaffst es dich etwas hochzuarbeiten.";
	if danger > 2, now the danger is 2.
		
Instead of jumping over in the swamp, try jumping.
Instead of swimming when the player is in the swamp, try jumping.
Instead of swimming in the swamp backdrop, try jumping.
Instead of swimming to a direction (called the course) when the player is in the swamp:
	if the course is north:
		swim up;
		try going the course;
	otherwise if the course is up or the course is outside:
		swim up;
	otherwise if the course is down:
		now the danger is 9;
		say "Du tauchst noch tiefer in das Moor ein.";
	otherwise if the course is west:
		try going the course;
	otherwise:
		if danger > 2, now the danger is 2;
		say "Du kannst nicht in diese Richtung schwimmen, schaffst es aber dich etwas hochzuarbeiten."

Before exiting from the swamp backdrop, try jumping instead.
Before exiting when the player is in the swamp, try jumping instead.

Instead of jumping when the player wears the boots:
	say "Das geht nicht solange du Stiefel anhast."
	
Instead of jumping in the swamp when the player does not wear the boots:
	swim up.

After wearing the boots when the location is the swamp, say "Die Stiefel bewahren dich davor im Morast zu versinken."


Part Dwarf

The dwarf is a man. The printed name is "Zwerg[-es][m]". The description is "Ein stämmiger kleiner Zwerg".
The hint of the dwarf is "Zwerge sind stark, haben aber nur kurze Arme. Wie kann er dich erreichen um dich herauszuziehen?".
Understand "zwerg [m]" or "wicht [m]" or "wichtel [m]" or "wichtelmann [m]" or "wichtelmaennchen [n]" or "winzling [m]" as "[dwarf names]".
Understand "[dwarf names]" or "staemmig/klein" as the dwarf.

After calling for help in the swamp:
	say "Auf dein Rufen hin erscheint ein stämmiger kleiner Zwerg.[line break]Der Zwerg ruft aufgeregt: [if the lonely tree is visited]'Du schon wieder! Komm wirf das Seil rüber!'[else]'Ich kann Dich nicht erreichen! Oje, oje - wie soll ich Dich nur herausziehen?'[end if]";
	now the dwarf is in the swamp;
	clear the hint of the swamp backdrop;
	now the room illustration of swamp is figure of swamp-with-dwarf;
	follow the image-setting rule.
	
Instead of calling for help in the swamp when the player wears the boots:
	say "Auf dein Rufen hin erscheint ein stämmiger kleiner Zwerg.[line break]Der Zwerg schimpft: 'Warum rufst du mich, wenn du doch die Stiefel an hast?'. Aufgebracht geht der Zwerg wieder davon.".
	
Instead of telling the dwarf about something: try answering the dwarf that.
Instead of asking the dwarf about something: try answering the dwarf that.
Instead of answering the dwarf that: say "Der Zwerg [says]: '[one of]Jetzt ist keine Zeit zum Reden[or]Statt zu Reden lass dir lieber etwas einfallen[or]Du hast gerade ein wichtigeres Problem[at random]!'".

Instead of showing the rope to the dwarf: say "Der Zwerg ruft: 'Wirf es mir zu!'".

Instead of giving the rope to the dwarf: try dropping the rope.
Instead of throwing the rope at the dwarf: try dropping the rope.
Instead of tying the rope to the dwarf: try dropping the rope.
Instead of dropping the rope in the swamp when the dwarf is in the swamp:
	say "Du hältst das eine Ende des Seils fest und wirfst das andere Ende dem Zwerg zu. Der Zwerg fängt das Seil und zieht dich heraus. Nachdem du dich bedankt hast, machst du dich auf den Weg nach Norden.";
	clear the hint of the dwarf;
	remove the dwarf from play;
	clear the hint of the rope;
	clear the destination of the rope;
	now the room illustration of swamp is figure of swamp-without-dwarf;
	move the player to the lonely tree.


	
Book 2 Lonely tree

The lonely tree is a room with printed name "Einsamer Baum[-es][m]". The description is "Ein einsamer Baum steht verloren auf der weiten Ebene."
Figure of lonely-tree-with-boots is the file "2-2a.png". Figure of lonely-tree-without-boots is the file "2-2b.png". The room illustration is figure of lonely-tree-with-boots. 
The destination name of lonely tree is "zum einsamen Baum". 
Understand "einsam" or "baum [m]" or "ebene [f]" as the lonely tree.

The lonely tree is north of swamp.


Part Boots

In the lonely tree are the boots with printed name "Paar[-es] Stiefel[n]".
The boots are wearable.
The description of the boots is "Ein schon etwas abgetragenes Paar Stiefel."
Understand "stiefel [p]" or "paar stiefel [p]" or "schuh [m]" or "schuhe [p]" or "paar schuhe [p]" as "[boots names]".
Understand "[boots names]" or "etwas" or "abgetragen" or "paar [n]" as the boots.

After taking the boots for the first time:
	now the room illustration of lonely tree is figure of lonely-tree-without-boots;
	follow the image-setting rule;
	continue the action.



Book 3 House

The house is a room with printed name "Haus[-es] im Wald[n]". "Der Weg führt zu einem einsamen [if the front-door is closed]Häuschen[else]Hexenhaus[end if] im tiefen Wald."
Figure of house is the file "2-3.png". The room illustration is Figure of house. 
The destination name of house is "zum Haus im Wald". 
Understand "weg [m]" as the house.

The house is north of the northern river.

Instead of smelling when in the house, say "Es riecht stark nach Lebkuchen.".

Part House Backdrop

The house backdrop is a backdrop in the house with printed name "einsam[^] Haus[-es][n]". The description is "Die Wände des einsamen [if the front-door is closed]Häuschens scheinen aus Lebkuchen zu bestehen[else]Hexenhauses bestehen aus Lebkuchen[end if] und sind mit bunten Süßigkeiten verziert. Die Tür besteht aus einem einzigen großen Stück Lebkuchen und das Fenster ist aus durchsichtigem Zuckerguss.[if the front-door is closed] Wer da wohl wohnt?[end if][if the front-door is open and the witch is not in house and the location of the spear is nowhere] Vielleicht solltest du dich mal drin umsehen?[end if]".
Understand "haus [n]" or "hexenhaus [n]" or "kuchenhaus [n]" or "kuchen [m]" or "lebkuchenhaus [n]" or "lebkuchen [m]" or "haeuschen [n]" or "hexenhaeuschen [n]" or "kuchenhaeuschen [n]" or "lebkuchenhaeuschen [n]" or "huette [f]" or "hexenhuette [f]" or "haus in dem wald [n]" or "hexenhaus in dem wald [n]" or "kuchenhaus in dem wald [n]" or "lebkuchenhaus in dem wald [n]" as "[house names]".
Understand "[house names]" or "einsam/klein" or "suessigkeiten [p]" or "stueck [n]" as the house backdrop.
Understand "kram [m]" or "hexenkram [m]" or "zeug [n]" or "hexenzeug [n]" as the house backdrop when the front-door is open.
The hint of the house backdrop is "Vorsicht vor einsamen Häusern!"

Chapter Front Door
 
The front-door is a part of the house backdrop. The printed name is "Haustür[f]". The description is "Eine [if the front-door is closed]geschlossene[else]offene[end if] Haustür aus Lebkuchen.".
The front-door can be open or closed. The front-door is closed.
Understand "haustuer [f]" or "tuer [f]" or "kuchentuer [f]" or "lebkuchentuer [f]" as the front-door.

Chapter Window

The window is a part of the house backdrop. The printed name is "Zuckergussfenster[-s][n]". The description is "Ein Fenster aus Zuckerguss - sieht süß aus. Leider kannst du durch das Fenster nichts erkennen.".
Understand "suess" or "fenster [n]" or "zucker [m]" or "guss [m]" or "zuckerguss [m]" or "zuckergussfenster [n]" as the window.

Chapter Gingerbread

The gingerbread is a edible thing. The printed name is "Stück[-es] Lebkuchen[n]". The description is "Ein Stück Lebkuchen vom Lebkuchenhaus im Wald".
Understand "suess" or "lebkuchen [m]" or "kuchen [m]" or "stueck [n]" as "[gingerbread names]".
Understand "drachenfutter [n]" or "futter [n]" or "drachenkoeder [m]" or "koeder [m]" or "lockmittel [n]" or "lockspeise [f]" or "essen [n]" or "nahrung [f]" or "speise [f]" or "kost [n]" or "mahlzeit [f]" or "suessigkeit [f]" or "suessigkeiten [p]" as "[bait names]".
Understand "[gingerbread names]" as the gingerbread.
Understand "[bait names]" as the gingerbread.

The hint of the gingerbread is "Vielleicht mögen auch andere Lebkuchen gern?".

Instead of tasting or eating the gingerbread, say "Der Lebkuchen ist zu hart zum essen. Du leckst nur ein bisschen daran - er schmeckt ziemlich süß.".
Instead of smelling the gingerbread, say "Der Lebkuchen riecht sehr würzig."

Instead of dropping the gingerbread in the northern river:
	say "Der Lebkuchen fällt ins Wasser und treibt davon.";
	remove the gingerbread from play.
 
Instead of dropping the gingerbread in the southern river:
	say "Der Lebkuchen fällt ins Wasser und treibt davon.";
	remove the gingerbread from play.
 
Instead of dropping the gingerbread in the chasm:
	say "Der Lebkuchen fällt in den Abgrund und ward nicht mehr gesehen.";
	remove the gingerbread from play.
 
Instead of dropping the gingerbread in the swamp:
	say "Mit einem leisen 'Blubb' versinkt der Lebkuchen im Morast.";
	remove the gingerbread from play.
 

To say Bumm:
	say "'[one of]Bumm[or]Bumm! Bumm[or]Krach[at random]!'".

[* knocking *]
To schedule the witch:	
	if not scheduled the witch comes, the witch comes in one turn from now.

To knock on the front-door:
	say "Du klopfst an [den noun]: [Bumm]";
	if not scheduled the witch comes, the witch comes in one turn from now.
		
Instead of knocking on the house backdrop, knock on the front-door.
Instead of knocking on the window, knock on the front-door.
Instead of knocking on the front-door, knock on the front-door

[* attacking *]
Instead of attacking the house backdrop:
	schedule the witch;
	say "[Bumm]Das Häuschen scheint erstaunlich stabil zu sein."

Instead of attacking the front-door:
	schedule the witch;
	say "[Bumm]Obwohl die Tür nur aus Lebkuchen zu bestehen scheint, ist sie doch erstaunlich stabil."

Instead of attacking the window:
	schedule the witch;
	say "[Bumm]Obwohl das Fenster nur aus Zuckerguss zu bestehen scheint, ist es doch erstaunlich stabil."

[* cutting *]
Instead of cutting the house backdrop, say "Der Lebkuchen ist so hart, dass du es nicht schaffst auch nur ein Stück zu lösen."
Instead of cutting the front-door, try cutting the house backdrop instead. 
Instead of cutting the window, say "Der Zuckerguss ist so hart, dass du es nicht schaffst auch nur ein Stück zu lösen."

Instead of cutting the front-door with something (called the slicer), try cutting the house backdrop with the slicer instead. 
Instead of cutting the house backdrop with something (called the slicer):
	if the slicer is a weapon:
		if the location of the gingerbread is a room:
			say "Aber du hast doch schon ein Stück Lebkuchen genommen.";
		else:
			say "Mit [dem slicer] gelingt es dir ein Stück Lebkuchen zu lösen, das du mit nimmst.";
			move the gingerbread to the player;
	else:
		say "Mit [dem slicer] geht das nicht."

[* eating *]
Before eating the house backdrop, say "Der Lebkuchen ist zu hart zum essen. Du leckst nur ein bisschen daran - ziemlich süß." instead.
Before eating the front-door, try eating the house backdrop instead.
Before eating the window, try tasting the window instead.

[* taking *]
Instead of taking the house backdrop, try taking the front-door.
Instead of taking the front-door, say "Der Lebkuchen ist so hart, dass du es nicht schaffst ein Stück abzubrechen."

[* tasting *]	
Instead of tasting the house backdrop, say "Du leckst ein bisschen am Lebkuchen - ziemlich süß."
Instead of tasting the front-door, try tasting the house backdrop.
Instead of tasting the window, say "Du leckst ein bisschen am Zuckerguss. Er schmeckt süß."


Part Witch

The witch is a woman with printed name "alt[^] Hexe". The description is "Eine garstige alte Hexe.".
Understand "frau [f]" or "hexe [f]" or "kraeuterhexe [f]" or "magierin [f]" or "zauberin [f]" as "[witch names]".
Understand "[witch names]" or "garstig/alt" or "alte [f]" as the witch.
The hint of the witch is "Alte Frauen sind oft recht schreckhaft.".

At the time when the witch comes:
	if the front-door is closed:
		now the front-door is open;
		now the witch is in the house;
		now the danger is 0;
		if the player is in the house:
			say "Die Tür des kleinen Häuschens wird aufgerissen und eine alte Hexe steht vor dir. Sie sieht dich an und sagt: 'Oh - mein Mittagessen!'".

Does the player mean knocking on the front-door: it is likely.


Every turn when the player is in the house and the witch is in the house:
	increase danger by 1;	
	if danger is:
		-- 1: say "[italic type]Die Hexe kommt auf dich zu![roman type][paragraph break]";
		-- 2: say "[italic type]Die Hexe greift nach dir![roman type][paragraph break]";
		-- otherwise: 
			say "[italic type]Die Hexe hat dich erwischt![roman type][paragraph break]";
			end the story.

Instead of attacking the witch, say "Die Hexe lacht und meint: 'Vor dir habe ich doch keine Angst! Vielleicht wenn du eine Waffe hättest.'".

Instead of attacking the witch with something (called the weapon), say "Die Hexe lacht und meint: 'Ich habe doch keine Angst vor [dem weapon]!'.".

Instead of telling the witch about, say "Die alte Hexe lacht nur leise.".
Instead of answering the witch that, say "Die alte Hexe lacht nur hämisch.".


The spear is a thing with printed name "Speer[-es][m]". The description is "Ein spitz[^] Silberspeer[-es].". The spear is a weapon. 
Understand "speer [m]" or "silberspeer [m]" or "waffe [f]" as "[spear names]".
Understand "[spear names]" or "beruehmt/spitz" as the spear.
The hint of the spear is "Die Waffe eines Drachentöters!".
The destination of the spear is the desolation.

Instead of attacking the witch with the sword:
	remove the witch from play;
	now the hint of the house backdrop is "Vielleicht hat die Hexe etwas nützliches in ihrem Haus?";
	say "Als die Hexe sieht, dass du ernst machst, stößt sie einen schrillen Schrei aus und rennt vor Schreck auf und davon.".
	
Instead of showing the sword to the witch: try attacking the witch with the sword.

Instead of going inside in the house, try entering the house backdrop.

Instead of going north in the house: 
	try entering the house backdrop.
	
Instead of entering or searching the house backdrop when the front-door is closed:
	say "Die Haustür ist geschlossen."

Instead of entering or searching the house backdrop when the witch is in the house:
	say "Die Hexe lässt dich nicht herein."

Instead of opening the house backdrop, try opening the front-door.
Instead of opening the front-door, say "Die Haustür ist offenbar abgeschlossen.".

Instead of unlocking the front-door with the key, say "Der Schlüssel passt nicht." 

Instead of entering or searching the house backdrop when the front-door is open and the witch is not in the house:
	if the location of the spear is nowhere:
		say "Beim Durchsuchen des Hexenhauses fällt dir neben lauter unnützem Hexenkram ein silberner Speer ins Auge. Diese Waffe hat bestimmt einmal einem berühmten Drachentöter gehört. Du nimmst den Speer mit und gehst wieder nach draußen.";
		now the player has the spear;
		clear the hint of the house backdrop;
	otherwise:
		say "Du findest nur unnützen Hexenkram und verlässt das Häuschen wieder."


	

Book 4 River

The southern river is a room with printed name "Südufer des Flusses Kolg[n]". "Rauschend fließt hier [if unvisited]ein mächtiger Fluss[else]der Fluss Kolg[end if][first time] und versperrt dir den Weg nach Norden[only]."
Figure of southern river is the file "2-4a.png". The room illustration is figure of southern river. 
The destination name of the southern river is "zum Fluss Kolg". 

The southern river is west of the lonely tree.

The northern river is a room with printed name "Nordufer des Flusses Kolg[n]". "Rauschend fließt hier der Fluss Kolg."
Figure of northern river is the file "2-4b.png". The room illustration is figure of northern river. 
The destination name of the northern river is "zum Fluss Kolg". 

The northern river is south of the house.

The northern river is mapped north of the southern river.
Instead of going north from the southern river:
	say "Der Fluss ist zu tief um ihn zu durchwaten.".
Instead of going south from the northern river:
	say "Der Fluss ist zu tief um ihn zu durchwaten.".
	
[boat]
The boat is a enterable container in the southern river. "Du siehst hier ein kleines Ruderboot.[contents of the boat]". The printed name is "klein[^] Ruderboot[-es]". The description is "Ein vertrauenerweckend aussehendes Ruderboot.".
Understand "boot [n]" or "ruderboot [n]" or "paddelboot [n]" or "kahn [m]" or "ruderkahn [m]" or "paddelkahn [m]" or "schiff [n]" as "[boat names]".
Understand "[boat names]" or "klein/vertrauenerweckend/aussehend" or "ruder [p]" or "paddel [p]" as the boat.

To say contents of the boat:
	if the boat contains something:
		say " Im Boot ";
		if the boat contains more than one thing:
			say "liegen";
		otherwise:
			say "liegt";
		say " [a list of things in the boat].".	
		

Part River Backdrop

The river backdrop is a backdrop in the southern river and in the northern river. The printed name is "Fluss[-es][m]". The description is "Der Fluss ist breit, tief und fließt schnell. Die Ufer sind flach und sandig.".
Understand "kolg [m]" or "fluss [m]" or "bach [m]" or "strom [m]" as "[river names]".
Understand "[river names]" or "breit/tief/maechtig/schnell/fliessen/flach/sandig" or "sand [m]" or "wasser [n]" or "wasserlauf [m]" or "ufer [n]" or "fluten [p]" as the river backdrop.

Instead of taking the river backdrop, say "Das Wasser rinnt dir durch die Finger.".
Before drinking the river backdrop, say "Du erfrischst dich mit ein paar Schluck kühlem Wasser." instead.

Instead of taking the boat, say "Das Boot ist zu schwer."

Instead of pulling or pushing the boat, try entering the boat.

Instead of rowing when the boat is in the location:
	say "(im Ruderboot)";
	try entering the boat.

Instead of going into when the boat is in the location:
	say "(in das Ruderboot)";
	try entering the boat.

Instead of entering the boat:
	say "Du ziehst das Boot ins Wasser, steigst vorsichtig ein und ruderst über den Fluss.";
	if the boat is in the southern river:
		move the boat to the northern river;
		move the player to the northern river;
	else:
		move the boat to the southern river;
		move the player to the southern river.
		
Before going north from the northern river: 
	now the danger is 0.

Instead of swimming when the river backdrop is in the location, try swimming in the river backdrop. 
Instead of swimming to when the river backdrop is in the location, try swimming in the river backdrop. 
Instead of swimming in the river backdrop, say "Die Strömung ist zu stark zum Schwimmen."

Instead of jumping over the river backdrop, say "Der Fluss ist zu breit um darüber zu springen."
Instead of entering the river backdrop, try swimming in the river backdrop.

Instead of rowing when the location is the river, try entering the boat. 
Instead of rowing in the boat, try entering the boat. 
Instead of rowing in the river backdrop, try entering the boat. 
Instead of rowing to the north when the location is the southern river, try entering the boat. 
Instead of rowing to the south when the location is the northern river, try entering the boat. 
Instead of rowing in the boat to the north when the location is the southern river, try entering the boat. 
Instead of rowing in the boat to the south when the location is the northern river, try entering the boat. 

Instead of listening when the river backdrop is in the location:
	say "Du hörst den Fluss rauschen."
Instead of smelling when the river backdrop is in the location:
	say "Du riechst den frischen Geruch des Flusses."
		
	

Book 5 Castle

The castle is a room with printed name "Burg Finsterhof[f]". "Düster und drohend ragt [if unvisited]eine[else]die[end if] Burg vor dir auf."
Figure of castle is the file "2-5.png". The room illustration is figure of castle. 
The destination name of the castle is "zur Burg Finsterhof". 

The castle is east of the lonely tree.


Part Castle Backdrop

The castle backdrop is a proper-named backdrop in the castle with printed name "Burg Finsterhof[f]". The description is "Die Burg besteht aus grob behauenen Steinquadern. Auffällig ist die tiefdunkle Farbe der Steine. Über einen befestigten Weg und durch einen kurzen Tunnel gelangt man an ein großes Tor, welches [if the gate is open]offen[else]geschlossen[end if] ist. Oben auf der Burg weht eine Fahne im Wind.".
Understand "finsterhof [f]" or "burg [f]" or "fort [n]" or "kastell [n]" as "[castle names]".
Understand "[castle names]" or "duester/drohend/grob/behauen/tiefdunkel/dunkle/sicher" or "farbe [f]" or "behausung [f]" or "stein [m]" or "quader [m]" or "steinquader [m]" or "tunnel [m]" or "fahne [f]" or "turm [m]" or "wand [f]" or "waende [p]" or "weg [m]" or "strasse [f]" as the castle backdrop.

Before going inside in the castle, try entering the castle backdrop instead.

Chapter Gate

The gate is a part of the castle backdrop. The printed name is "Burgtor[-es][n]". The description is "Ein großes, aus rauen Balken fest gefügtes Burgtor. Das Tor [if the gate is open]steht weit offen[else]ist geschlossen und verriegelt[end if].". 
The gate can be open or closed. The gate is closed.
Understand "gross/rau/gefuegt" or "balken [m]" or "tor [n]" or "burgtor [n]" or "tuer [f]" as the gate.


Does the player mean knocking on the gate: it is likely.

Instead of knocking on the castle backdrop: try knocking on the gate.
Instead of entering the gate: try entering the castle backdrop.


Instead of knocking on the gate when the gate is closed:
	now the gate is open;
	now Bjoern is in the castle;
	say "Du klopfst an das Burgtor: 'Bumm! Bumm!' hallt das Geräusch wider.";
	say "Nach kurzer Zeit wird das schwere Tor geöffnet und ein Mann groß wie ein Bär tritt zu dir heraus. [Bjoerns greeting]".
	
Instead of knocking on the gate when the gate is open:
	say "Du klopfst an das Burgtor: 'Bumm, Bumm' - Dumpf hallt das Geräusch wider.";
	say "Björn sieht dich irritiert an.";
	

Part Bjoern

Bjoern is a man with printed name "Björn". The description is "Ein Mann, groß wie ein Bär. Er hat einen dichten scharzen Bart und schwarze struppige Haare".
Bjoern is not friendly.
Understand "bjoern [m]" or "mann [m]" or "baer [m]" as "[bjoern names]".
Understand "[bjoern names]" or "gross/dicht/scharz/struppig" or "bart [m]" or "haare [p]" as Bjoern.
The hint of Bjoern is "Ein schrecklicher Feind, aber ein treuer Freund wenn man ihn für eine gute Sache begeistert.".

To say Bjoerns greeting:
	if Bjoern is friendly:
		say "Er sieht dich freundlich an und sagt: 'Hallo mein Freund, hast du den Drachen schon erschlagen?'";
	otherwise:
		if Bjoern is in the castle for the first time:
			say "Er sieht dich etwas abschätzig an und sagt: 'Ich bin Björn, der Herr dieser Burg. Wer bist du und was willst du?'";
		otherwise:
			say "Er sieht dich ziemlich abschätzig an und sagt: 'Was willst du denn jetzt wieder?'".

After going from the castle when the gate is open:
	now the gate is closed;
	remove Bjoern from play;
	continue the action.


Every turn when the player is in the castle and Bjoern is in the castle:
	if a random chance of 1 in 3 succeeds:
		if Bjoern is not friendly:
			say "Björn [one of]kratzt sich ungeniert am Bart[or]sieht dich abschätzend an[or]spuckt auf den Boden[at random].";
		otherwise:
			say "Björn [one of]sieht dich erwartungsvoll an[or]nickt dir auffordernd zu[or]blickt dir gespannt zu[at random].";


Instead of entering the castle backdrop:
	if the gate is closed:
		say "Das Tor ist geschlossen.";
	otherwise:
		say "Björn steht dir im Weg.".

Instead of taking Bjoern when Bjoern is not friendly, say "Björn ruft: 'Was fällt dir ein, Kerl?'".
Instead of taking Bjoern when Bjoern is friendly, say "Björn sagt: 'Ich würde gerne mit dir gehen, aber ich bin zu alt für Abenteuer.'".

[* give => show *]
Instead of giving the book to Bjoern, try showing the book to Bjoern.
Instead of giving the spear to Bjoern, try showing the spear to Bjoern.
Instead of giving the sword to Bjoern, try showing the sword to Bjoern.

Instead of giving the gingerbread to Bjoern, try asking Bjoern about "lebkuchen".
Instead of showing the gingerbread to Bjoern, try asking Bjoern about "lebkuchen".


Instead of giving something to Bjoern: 
	if Bjoern is not friendly:
		say "Björn betrachtet [den noun] abschätzig und [says] 'Ich will nichts von dir haben!'.";
	otherwise:	
		say "Björn betrachtet [den noun] und [says] 'Das wirst du wahrscheinlich nötiger brauchen als ich.'."


Before showing a backdrop to Bjoern:
	say "Björn sagt: 'Aha - [Ein noun].'" instead.

Instead of showing something to Bjoern: 
	if Bjoern is not friendly:
		say "Björn betrachtet [den noun] abschätzig und sagt 'Das interessiert mich nicht!'.";
	otherwise:	
		say "Björn betrachtet [den noun] eingehend und sagt 'Leider kann ich dir damit nicht weiterhelfen.'."


Understand "hilf" or "hilfe" or "hilf mir" or "komm" or "komm mit" or "komm mit mir" or "geh mit" or "geh mit mir" or "kaempfe mit" or "kaempfe mit mir" or "drache toeten" or "drachen toeten" or "smang toeten" or "wie drache toeten" or "wie drachen toeten" or "wie smang toeten" or "held" or "drachentoeter" as "[bjoern help-me names]".


Instead of telling Bjoern about a topic listed in the Table of Bjoern Friendly Tell Results when Bjoern is friendly:
	repeat through Table of Bjoern Friendly Tell Results:
		if the topic understood includes topic entry:
			deliver the result entry quip;
			rule succeeds.		 

Instead of telling Bjoern about a topic listed in the Table of Bjoern Unfriendly Tell Results when Bjoern is not friendly:
	repeat through Table of Bjoern Unfriendly Tell Results:
		if the topic understood includes topic entry:
			deliver the result entry quip;
			rule succeeds.		 

Instead of asking the Bjoern about a topic listed in the Table of Bjoern Friendly Ask Results when Bjoern is friendly:
	repeat through Table of Bjoern Friendly Ask Results:
		if the topic understood includes topic entry:
			deliver the result entry quip;
			rule succeeds.	 
			
Instead of asking the Bjoern about a topic listed in the Table of Bjoern Unfriendly Ask Results when Bjoern is not friendly:
	repeat through Table of Bjoern Unfriendly Ask Results:
		if the topic understood includes topic entry:
			deliver the result entry quip;
			rule succeeds.	 

Table of Bjoern Friendly Ask Results
topic    	result
"[bjoern names]"			ask-bjoern-friendly-self
"[bjoern help-me names]"		ask-bjoern-friendly-help-me
"[boat names]"				ask-bjoern-friendly-boat
"[other names]"				ask-bjoern-friendly-self
"[castle names]"				ask-bjoern-friendly-castle
"[desolation names]"		ask-bjoern-friendly-dragon
"[dragon names]"			ask-bjoern-friendly-dragon
"[halbling names]"			ask-bjoern-friendly-halfling
"[sword names]"				ask-bjoern-friendly-sword
"[cloud names]"				ask-bjoern-friendly-weather
"[sky names]"					ask-bjoern-friendly-weather
"[forest names]"				ask-bjoern-friendly-forest
"[gingerbread names]"			ask-bjoern-gingerbread
"[bait names]"			ask-bjoern-gingerbread
"[house names]"				ask-bjoern-friendly-house
"[river names]"				ask-bjoern-friendly-river
"[witch names]"				ask-bjoern-friendly-witch
"[chasm names]"			ask-bjoern-chasm
"[crack names]"				ask-bjoern-chasm
"[dwarf names]"				ask-bjoern-friendly-dwarf
"[mountain names]"		ask-bjoern-mountain
"[unicorn names]"			ask-bjoern-friendly-unicorn

Table of Bjoern Unfriendly Ask Results
topic    	result
"[bjoern names]"			ask-bjoern-unfriendly-self
"[bjoern help-me names]"		ask-bjoern-unfriendly-help-me
"[boat names]"				ask-bjoern-unfriendly-boat
"[other names]"				ask-bjoern-unfriendly-self
"[castle names]"				ask-bjoern-unfriendly-castle
"[desolation names]"		ask-bjoern-unfriendly-dragon
"[dragon names]"			ask-bjoern-unfriendly-dragon
"[halbling names]"			ask-bjoern-unfriendly-halfling
"[sword names]"				ask-bjoern-unfriendly-sword
"[cloud names]"				ask-bjoern-unfriendly-weather
"[sky names]"					ask-bjoern-unfriendly-weather
"[forest names]"				ask-bjoern-unfriendly-forest
"[gingerbread names]"			ask-bjoern-gingerbread
"[bait names]"			ask-bjoern-gingerbread
"[house names]"				ask-bjoern-unfriendly-house
"[river names]"				ask-bjoern-unfriendly-river
"[witch names]"				ask-bjoern-unfriendly-witch
"[chasm names]"			ask-bjoern-chasm
"[crack names]"				ask-bjoern-chasm
"[dwarf names]"				ask-bjoern-unfriendly-dwarf
"[mountain names]"		ask-bjoern-mountain
"[unicorn names]"			ask-bjoern-unfriendly-unicorn

Table of Bjoern Friendly Tell Results
topic    	result
"[hello names]"				bjoern-friendly-hello
"[bjoern help-me names]"		tell-bjoern-friendly-help-me
"[halbling names]"			tell-bjoern-friendly-halfling
"[self names]"					tell-bjoern-friendly-halfling
"[gingerbread names]"			tell-bjoern-gingerbread
"[bait names]"			tell-bjoern-gingerbread
"[forest names]"				tell-bjoern-friendly-witch
"[house names]"				tell-bjoern-friendly-witch
"[river names]"				tell-bjoern-friendly-witch
"[witch names]"				tell-bjoern-friendly-witch
"[desolation names]"		tell-bjoern-friendly-dragon
"[dragon names]"			tell-bjoern-friendly-dragon
"[chasm names]"			tell-bjoern-chasm
"[crack names]"				tell-bjoern-chasm

Table of Bjoern Unfriendly Tell Results
topic    	result
"[hello names]"				bjoern-unfriendly-hello
"[bjoern help-me names]"		tell-bjoern-unfriendly-help-me
"[halbling names]"			tell-bjoern-unfriendly-halfling	
"[self names]"					tell-bjoern-unfriendly-halfling	
"[gingerbread names]"			tell-bjoern-gingerbread
"[bait names]"			tell-bjoern-gingerbread
"[forest names]"				tell-bjoern-unfriendly-witch
"[house names]"				tell-bjoern-unfriendly-witch
"[river names]"				tell-bjoern-unfriendly-witch
"[witch names]"				tell-bjoern-unfriendly-witch
"[desolation names]"		tell-bjoern-unfriendly-dragon
"[dragon names]"			tell-bjoern-unfriendly-dragon
"[chasm names]"			tell-bjoern-chasm
"[crack names]"				tell-bjoern-chasm

Table of Quip Texts (continued)
quip		quiptext
[* generic *]
bjoern-friendly-hello						"Hallo mein tapferer kleiner Freund."
bjoern-unfriendly-hello					"[one of]Hau ab[or]Verschwinde[or]Ich mag keine Landstreicher[or]*Grng*[at random]!"
[* ask generic*]
ask-bjoern-chasm						"Südwestlich des Moores ist ein tiefer Abgrund. Beim letzten Unwetter ist da der Weg abgerutscht."
ask-bjoern-mountain					"Wir sind im Gebirge, da gibt es eben viele Berge."
[* ask friendly *]
ask-bjoern-friendly-self				"Ich wohne schon lange hier in Burg Finsterhof."
ask-bjoern-friendly-boat				"Am Flussufer liegt ein Ruderboot. Ich weiß nicht, wem das Boot gehört, aber du kannst es bestimmt benutzen."
ask-bjoern-friendly-castle			"Hier in der Nähe des Drachen braucht man eine sichere Behausung."
ask-bjoern-friendly-dragon			"Ich drücke dir die Daumen, dass du es schaffst Smang zu erlegen!"
ask-bjoern-friendly-dwarf				"In der Nähe des Moores lebt ein hilfsbereiter Zwerg."
ask-bjoern-friendly-forest			"Der Wald ist nördlich des Fluss Kolg. Man munkelt, dass die Alte die dort wohnt eine Hexe ist."
ask-bjoern-friendly-halfling			"Scheinbar seid ihr Halblinge doch besser, als ich gedacht habe."
ask-bjoern-friendly-house			"Im Wald nördlich des Flusses Kolg wohnt eine Alte im Wald in einem Lebkuchenhaus. Die Leute erzählen, dass sie eine Hexe wäre."
ask-bjoern-friendly-river				"Der Fluss im Westen heißt 'Kolg' weil er weiter flussaufwärts gestaut wird. Da müsste auch noch ein altes Ruderboot liegen."
ask-bjoern-friendly-sword			"Ein Schwert ist keine Waffe um einen Drachen zu töten."
ask-bjoern-friendly-weather			"Es wird Frühling. Der Winter ging mir auch langsam auf die Nerven!"
ask-bjoern-friendly-unicorn			"Das Einhorn habe ich auch schon gesehen. Was für ein majestätisches Geschöpf!"
ask-bjoern-gingerbread			"Einen Köder, um den Drachen anzulocken? Angeblich sollen Drachen ganz wild auf Süßigkeiten sein."
ask-bjoern-friendly-witch				"[one of]Im Wald auf der anderen Seite des Flusses wohnt eine alte Frau in einem Lebkuchenhaus.[or]Du solltest vorsichtig sein: man erzählt sich, die Alte wäre eine Hexe![at random]"
ask-bjoern-friendly-help-me			"Um dem Drachen den Gar aus zu machen, braucht es einen Drachentöter. Ich bin zu alt für solche Sachen, jemand besseren als dich haben wir nicht. Ich fürchte du wirst genügen müssen. Ich wünsche dir alles Gute für dein Abenteuer."
[* ask unfriendly *]
ask-bjoern-unfriendly-self			"Ich habe dir gesagt, dass ich hier der Herr bin - und mehr hat dich nicht zu interessieren!"
ask-bjoern-unfriendly-boat			"Lass die Finger von Sachen, die dir nicht gehören - Landstreicher!"
ask-bjoern-unfriendly-castle		"Du willst hier wohl herumspionieren?"
ask-bjoern-unfriendly-dragon		"[one of]Der Drachen hat alles Land nördlich meiner Burg verwüstet und fast täglich kommt er näher an meine Burg.[or]Leider gibt es heute keine Helden mehr, die sich trauen würden es mit Smang aufzunehmen![at random]"
ask-bjoern-unfriendly-dwarf			"Ja, ich kenne Zwerge. Ich mag sie zwar nicht besonders, aber es sind immerhin keine Landstreicher."
ask-bjoern-unfriendly-forest		"Was willst Du denn im Wald? Alles Land um die Burg gehört mir - und ich dulde keine Landstreicher!"
ask-bjoern-unfriendly-halfling		"Ich kenne deine Sorte! Und ich mag euch nicht besonders!"
ask-bjoern-unfriendly-house		"Lass der Alten doch ihre Spinnerei! Wenn sie allein mitten im Wald in einem Lebkuchenhaus wohnen will - was geht es dich an?"
ask-bjoern-unfriendly-river			"Ja, im Westen ist ein Fluss - und?"
ask-bjoern-unfriendly-sword		"Schwerter taugen nur um alte Frauen zu erschrecken."
ask-bjoern-unfriendly-unicorn		"Ich glaube kaum, dass sich ein Einhorn mit einem Landstreicher wie dir einlassen würde!"
ask-bjoern-unfriendly-weather		"Du bist doch bestimmt nicht hier um mit mir übers Wetter zu reden!"
ask-bjoern-unfriendly-witch			"Du willst in den Wald zum Lebkuchenhaus? Nach Westen und über den Fluss. Dann kannst Du der Alten auf die Nerven fallen!"
ask-bjoern-unfriendly-help-me			"Ein vagabundierender Halbling? Du bist bestimmt kein Drachentöter! Wie käme ich denn dazu dir zu helfen?"
[* tell generic *]
tell-bjoern-chasm						"Ich kenne den Abgrund. Wie bist du über den Erdspalt gekommen?"
tell-bjoern-gingerbread						"Süßigkeiten sollen ja ein prima Drachenköder sein."
[* tell friendly *]
tell-bjoern-friendly-dragon			"Im Norden beginnt die Verwüstung in der der Drache haust."
tell-bjoern-friendly-halfling			"Ich hätte nicht geglaubt, dass ein Halbling so mutig sein könnte!"
tell-bjoern-friendly-witch				"Da solltest du besser nicht hingehen - die Alte frisst so was wie dich zum Mittagessen!"
tell-bjoern-friendly-help-me			"Ich verstehe, Dass du gerne Hilfe hättest. Was ich für dich tun kann, werde ich tun. Aber verlang nicht von mir, dass ich mit dir gehe - für solche Abenteuer bin ich zu alt."
[* tell unfriendly *]
tell-bjoern-unfriendly-dragon		"Ja, glaubst du denn ich kenne den Drachen nicht?"
tell-bjoern-unfriendly-halfling		"Ein Halbling! Wohl auch noch ein Drachenfreund! - Was?"
tell-bjoern-unfriendly-witch			"Lass mich doch mit der Alten im Wald in Ruhe!"
tell-bjoern-unfriendly-help-me			"Ein vagabundierender Halbling? Ich glaube dir, dass du Hilfe brauchst - aber warum kommst du zu mir?"

[* bye *]
Instead of answering Bjoern that "[bye names]":
	now the gate is closed;
	remove Bjoern from play;
	if Bjoern is not friendly:
		say "Björn gibt ein Grunzen von sich, dass man mit viel Mühe als Verabschiedung deuten könnte. Dann geht er wieder in die Burg und schließt das Tor hinter sich. Du hörst wie er das Tor verriegelt und innen noch einen schweren Balken quer legt.";
	otherwise:
		say "Björn nickt dir freundlich zu, wünscht dir nochmals viel Erfolg und geht dann wieder in seine Burg."


[* book *]
Instead of showing the book to Bjoern for the first time:
	now player-knows-dragons-weak-spot is true;
	if Bjoern is not friendly:
		say "Björn betrachtet [den noun] missmutig. Plötzlich wird er aber sehr aufgeregt und nimmt dir [den noun] aus den Händen. Er blättert [ihn] durch und sagt: 'Du bist also auf Drachenjagd? Respekt, dass hätte ich dir nicht zugetraut!'. Er fährt fort: 'Ich kann nicht alles entziffern, aber hier steht etwas, dass dir bei deinem Abenteuer vielleicht helfen wird: [italic type][apostrophe]Ein blinder Fleck erfüllt den Zweck![apostrophe][roman type]' Dann sagt er: 'Hättest du mir gleich gesagt, dass du auf dem Weg bist das Land vom Drachen zu befreien, hätte ich dich freundlicher empfangen.' Freundlich lächelnd gibt dir Björn [den noun] zurück.";
		now Bjoern is friendly;
	otherwise:	
		say "Björn betrachtet [den noun] eingehend. Er nimmt dir das Buch aus den Händen, blättert es durch und sagt: 'Ich kann nicht Alles entziffern, aber hier steht etwas, dass dir bei deinem Abenteuer vielleicht helfen wird: [italic type][apostrophe]Ein blinder Fleck erfüllt den Zweck![apostrophe][roman type]' Freundlich lächelnd gibt dir Björn [den noun] zurück."
	
Instead of showing the book to Bjoern:
	say "Björn betrachtet das Buch nochmals, schüttelt aber dann den Kopf: 'Ich kann leider nichts weiter entziffern, was dir helfen könnte.'".

Instead of telling Bjoern about "[book names]": try showing the book to Bjoern.

Instead of asking Bjoern about "[book names]":
	[if the player knows the dragons weak spot, Bjoern has seen the book]
	if player-knows-dragons-weak-spot is true: 
		say "Björn sagt: 'Du solltest den Hinweis aus dem Buch beherzigen!'.";
	otherwise:
		say "Björn sagt: 'Ich weiß nichts von einem Buch'.".

	
[* spear *]
Instead of showing the spear to Bjoern for the first time:
	if Bjoern is not friendly:
		say "Björn betrachtet [den noun] missmutig. Plötzlich wird er aber sehr aufgeregt, nimmt dir [den noun] aus den Händen und sagt: 'Du bist also auf Drachenjagd? Respekt, dass hätte ich dir nicht zugetraut!'. Freundlich lächelnd gibt dir Björn [den noun] zurück.";
		now Bjoern is friendly;
	otherwise:	
		say "Björn betrachtet [den noun] eingehend und sagt: 'Das ist die richtige Waffe um einen Drachen zu erlegen!'. Freundlich lächelnd gibt dir Björn [den noun] zurück."
	
Instead of showing the spear to Bjoern:
	say "Björn betrachtet den Speer und sagt: 'Ich wünsche dir viel Glück bei deinem Abenteuer.'.".
	

Instead of asking Bjoern about "[spear names]":
	if the player carries the spear: 
		try showing the spear to Bjoern;
	otherwise:	
		if Bjoern is not friendly: 
			say "Björn murmelt etwas, dass Speere zwar besser sind als Schwerter, dass es heute aber niemanden mehr gibt, der es wagt sich einem Drachen zu stellen.";
		otherwise:
			say "Björn sagt: 'Mit einem Speer kann man einen Drachen erlegen.'.".

[* sword *]
Instead of showing the sword to Bjoern:
	if Bjoern is not friendly:
		say "Björn betrachtet [den noun] missmutig und sagt: 'Dieses Schwert ist doch nur nutze um alte Frauen zu erschrecken.'";
	otherwise:	
		say "Björn betrachtet [den noun] eingehend und sagt: 'Mit dieser Waffe wirst du aber keinen Drachen erlegen! Der Drache hätte dich ja geröstet, bevor du nahe genug an ihn herangekommen wärst.'. Freundlich lächelnd gibt dir Björn [den noun] zurück."

Instead of answering Bjoern that something:
	try telling Bjoern about.

Instead of telling Bjoern about:
	say "[Der noun] [says]: '[one of]Das interessiert mich nicht[or]So, so[or]Danke, kein Interesse[at random]!'."	

Instead of asking Bjoern about something: 
	if Bjoern is not friendly:
		say "Björn murmelt etwas Unverständliches - es scheint aber nichts besonders Nettes gewesen zu sein.";
	otherwise:
		say "Björn [says]: '[one of]Davon weiß ich leider nichts[or]Da kann ich dir leider nicht weiterhelfen[at random].'."

	

Book 6 Desolation

The desolation is a room with printed name "Verwüstung[f]". "Die Landschaft ist öde und leer - der Drache hat alles verwüstet.".
Understand "verwuestung [f]" or "wueste [f]" or "leere [f]" as "[desolation names]".
Understand "[desolation names]" or "oede/leer" as the desolation.
Figure of desolation-with-dragon-distant is the file "2-6a.png". Figure of desolation-with-dragon-near is the file "2-6b.png". The room illustration is figure of desolation-with-dragon-distant. 
The destination name of desolation is "zur Verwüstung". 

The desolation is north of the castle.

Before going south from the desolation for the first time, say "In kopfloser Panik ziehst du dich nach Süden zurück. Im Schatten der Burg verschnaufst du erst mal."


Part Dragon

The dragon is a distant animal in the desolation with printed name "Drache[-n] Smang[m]". "[if desolation is unvisited]Vor dir siehst du den Drachen. Er scheint dich schon entdeckt zu haben! Er schlägt mit den Flügeln, schwingt sich in die Lüfte und speit Feuer! Zum Glück ist er noch zu weit weg, um dir Schaden zufügen zu können[else]Am Himmel über dir kreist Smang[end if].". The description is "Smangs Brust ist dicht mit undurchdringlichen Schuppen besetzt. [dragons-weak-spot].".

Understand "smang [m]" or "drache [m]" or "drachen [m]" or "drache smang [m]" or "lindwurm [m]" or "untier [n]" as "[dragon names]".
Understand "[dragon names]" or "schimmernd/kahl/undurchdringlich/blind" or "wurm [m]" or "panzer [m]" or "kettenpanzer [m]" or "stelle [f]" or "fleck [m]" or "fluegel [p]" or "schuppen [p]" as the dragon.

The hint of the dragon is "Drei Dinge benötigst du um den Drachen zu besiegen:[line break]Du musst eine geeignete Waffe besitzen, wissen wo seine schwache Stelle ist und dafür Sorgen, dass er dir nahe genug kommt.".

To say dragons-weak-spot:
	if player-knows-dragons-weak-spot is false:
		say "Du kannst dir beim besten Willen nicht vorstellen, wie du diesen Kettenpanzer mit irgendeiner Waffe durchdringen könntest";
	otherwise:
		say "Als du genau darauf achtest, kannst du [if the dragon is distant]un[end if]deutlich eine kahle Stelle zwischen seinen schimmernden Schuppen [if the dragon is distant]erahnen[else]erkennen[end if]".
		
Before going to the desolation:
	now the dragon is distant;
	now the room illustration of desolation is figure of desolation-with-dragon-distant;
	follow the image-setting rule;
	continue the action.
	
To bring the dragon near:
	now the danger is 0;
	now the dragon is near;
	now the room illustration of desolation is figure of desolation-with-dragon-near;
	follow the image-setting rule.
		
Every turn when the player is in the desolation:
	if the dragon is distant:
		if a random chance of 2 in 3 succeeds:
			say "Der Drache [one of]kreist am Himmel[or]stößt einen schrecklichen Schrei aus[or]stößt plötzlich hinab und versengt mit einem Feuerstoß den Boden neben dir[or]fliegt eine große Schleife[or]tut so, als würde er dich nicht weiter beachten[at random].";
	otherwise:
		increase danger by 1;	
		if danger is:
			-- 1: say "Der Drache geht in den Sturzflug über und landet dicht vor dir. Als er erkennt, dass du kein Held in strahlender Rüstung sondern nur ein Halbling bist, lächelt er amüsiert.[paragraph break]";
			-- 2: say "[italic  type]Der Drache kommt näher![roman type][paragraph break]";
			-- 3: say "[italic  type]Das Drache setzt sich genau vor dich![roman type][paragraph break]";
			-- 4: say "[italic  type]Das Drache öffnet sein riesiges Maul, so dass du seine messerscharfen Zähne siehst![roman type][paragraph break]";
			-- otherwise: 
				say "[italic  type]Der Drache hat dich mit einem kurzen Feuerstoß gegrillt![roman type][paragraph break]";
				end the story.

[* attract *]
After waiting in the desolation for three turns:
	bring the dragon near.

Instead of dropping the gingerbread in the desolation:
	say "Bevor du deinen Vorsatz ausführen kannst, hat Smang den würzigen Duft [des noun] schon gerochen und kommt heran. [run paragraph on]";
	bring the dragon near.
	
Instead of attracting the dragon with the gingerbread:
	say "Der Drache riecht den würzigen Lebkuchen und kommt heran.";
	bring the dragon near.
	

[* attack *]
Instead of attacking the dragon when the dragon is near, say "Mit bloßen Händen? Sei nicht albern!".

Instead of throwing the sword at the dragon, try attacking the dragon with the sword instead.
Instead of attacking the dragon with the sword when the dragon is near:
	say "Ein heroischer Einsatz, der leider nichts gebracht hat.";
	now danger is 4.

Instead of throwing the spear at the dragon, try attacking the dragon with the spear instead.
Instead of attacking the dragon with the spear when the dragon is near:
	if player-knows-dragons-weak-spot is false:
		say "Du weißt nicht, wohin du zielen sollst.";
	otherwise:
		say "Tief stößt du den Speer in die kahle Stelle zwischen den gepanzerten Schuppen. Der Speer dringt fast ganz in den weichen Körper des Drachen ein. Mit einem letzten Schrei bricht der Drache tot vor dir zusammen.[paragraph break][bold type]Du hast den Drachen getötet und damit das Land von einer großen Gefahr befreit![roman type]";
		display the end animation;
		end the story finally.




Volume TEST - Not for Release

test me with "n / hoch / x nest / nimm seil / o / nimm kristall / w / binde dich an Crac fest / w / folge spur / gib troll den kristall / e / e / s / schliess truhe auf / nimm schwert / nimm buch / n / w / n / schneide aeste mit schwert / s / e / e / besteig Einhorn / ruf zwerg / wirf seil / w / ruder / klopf an tuer / z / erschrecke hexe mit schwert / durchsuch haus / schneide lebkuchen mit schwert / s / e / e / klopf an / gib bjoern das buch / n / locke drachen mit lebkuchen / toete drachen mit speer" 

test debug with "transcript on / n / hoch / analyse crac / analyse nest / x nest / analyse seil / nimm seil / o / analyse kristall / nimm kristall / w / binde dich an Crac fest / w / analyse spur / folge spur / analyse troll / gib troll den kristall / e / e / s / analyse truhe / schliess truhe auf / öffne truhe / analyse schwert / nimm schwert / analyse buch / nimm buch / n / w / n / analyse einhorn / schneide äste mit schwert / s / e / e / besteig Einhorn / ruf zwerg / analyse zwerg / wirf seil / w / analyse boot / ruder / klopf an tür / z / analyse hexe / erschrecke hexe mit schwert / durchsuch haus / s / e / e / klopf an /  analyse björn / gib björn das buch / n / z / z / z / analyse drache / töte drachen mit speer"

test moor with "n / hoch / x nest / nimm seil / o / nimm kristall / w / binde dich an Crac fest / w / folge spur / gib troll den kristall / e / e / s / schliess truhe auf / öffne truhe / nimm schwert / nimm buch / n / w / n / schneide äste mit schwert / s / e / e / besteig Einhorn"

test hexe with "n / hoch / x nest / nimm seil / o / nimm kristall / w / binde dich an Crac fest / w / folge spur / gib troll den kristall / e / e / s / schliess truhe auf / öffne truhe / nimm schwert / nimm buch / n / w / n / schneide äste mit schwert / s / e / e / besteig Einhorn / ruf zwerg / wirf seil / w / ruder"

test schluessel with "n / hoch / o / nimm kristall / w / x nest / nimm seil / binde seil an Crac / w / folge spur / gib troll den kristall / o / o / s / x schlüssel / hint schluessel / öffne truhe"

test troll with "n / hoch / x nest / nimm seil / o / nimm kristall / w / binde seil an Crac / w / folge spur / x troll / frag troll nach schlüssel / erzähl troll von kristall / frag troll nach kristall / zeig troll den kristall / frag troll nach kristall / gib troll den kristall / frag troll nach kristall / x schlüssel "

test bjoern with "n / hoch / x nest / nimm seil / o / nimm kristall / w / binde dich an Crac fest / w / folge spur / gib troll den kristall / e / e / s / schliess truhe auf / öffne truhe / nimm schwert / nimm buch / n / w / n / schneide äste mit schwert / s / e / e / besteig Einhorn / ruf zwerg / wirf seil / w / ruder / klopf an tür / z / erschrecke hexe mit schwert / durchsuch haus / schneide lebkuchen mit schwert / s / e / e "

test crac with "n / u / nimm crac / x nest / nimm seil / nimm crac / u / binde seil an crac / u / binde crac an seil / u / binde seil an mich / u / binde mich an seil / u / binde mich an crac / u / binde crac an mich "

