"Drakulas Diamanten" by "Frank Gerbig" (in German)

Include German by Team GerX.

Use skip libcheck.
Use capitalised Du.

The story headline is "Eine Neuinterpretation des 'Adventures von C. Seibt für den Sinclair ZX-81'".
The story genre is "Fantasy".
The story creation year is 2023. 
The story description is "Tritt Graf Drakula gegenüber und beschaffe die gestohlenen Diamanten wieder.".
The release number is 14. 

Release along with cover art, a "german" website, an interpreter, the source text, a file of "Story File ohne Grafik" called "Drakulas Diamanten.zblorb", a file of "Artikel in der 'Homecomputer'" called "Homecomputer 10-1983.pdf", a file of "Lösung" called "Lösung.txt", and the library card.

A thing is usually privately-named.


Chapter Long words Z-Machine (for Z-Machine only)

Use memory economy.
Use compound heads.

Table of Compound Heads (continued)
head	n
"schrau"	0

Understand "schrau-", "be[f]" or "ben[p]" as the screws.
Understand "schrau-", "ber[m]", "benzieher[m]", "bendreher[m]" as the screwdriver.


Chapter Long words Glulx (for Glulx only)

Use DICT_WORD_SIZE of 12.


Chapter Beta-Testing messages (Not for release)

[ from Recipe Book §13.1, Ex. 413, "Alpha" ]
After reading a command (this is the ignore beta-comments rule):
	if the player's command matches the regular expression "^\p":
		say "(Noted - transcript is [currently transcripting].)";
		reject the player's command.

Include (-
[ CheckTranscriptStatus;
	#ifdef TARGET_ZCODE;
	return ((0-->8) & 1);
	#ifnot;
	return (gg_scriptstr ~= 0);
	#endif;
];
-).

To decide whether currently transcripting: (- CheckTranscriptStatus() -)

To say currently transcripting: if currently transcripting, say "on"; otherwise say "off".


Book Drakulas Diamanten


Part General

The description of yourself is "Du siehst übernächtigt aus. Und hast [du] nicht auch abgenommen? Eines Tages bringt [dich] dieser Job noch um."

[ "stell dich auf dentisch" wird als "setting yourself to 'dentisch'" verstanden ]
Instead of setting yourself to:
	say "So etwas kannst Du hier nicht sehen.".


Chapter Danger

Danger is a number that varies.


Chapter Climbing and going down from supporter

Instead of climbing a supporter (called the supporter):
	try entering the supporter instead.

Instead of going down when the actor is on a supporter (called the supporter):
	try getting off the supporter instead.


Chapter Blessed verb forms (Not for release)

Table of blessed verb forms (continued)
 Verb
 "atme"


Chapter Wearing the towel

Understand "Mund[m]", "Nase[f]", "Kopf[m]", "Gesicht[n]", "Mund und Nase[p]", "Nase und Mund[p]" as yourself.
Understand "den Mund", "Mund", "die Nase", "Nase", "den Kopf", "Kopf", "das Gesicht", "Gesicht", "Mund und Nase", "Nase und Mund" as "[yourself-synonyms]".
Understand "Atem[m]", "Luft[f]" as "[breath-synonyms]".

Understand "bind [dir] [something preferably held] um" as wearing.
Understand "bind [dir] [something preferably held] um [dativ] [yourself]" as tying it to.
Understand "bind [something preferably held] um [dativ] [something]" as tying it to.
Understand the command "wickel", "wickle" as "bind".

Protecting with is an action applying to one carried thing.
Understand "atme durch/in [something preferably held]" as protecting with.
Understand "deck [yourself-synonyms] mit [something preferably held] ab" as protecting with.
Understand "filter [breath-synonyms] durch/mit [something preferably held]" as protecting with.
Understand "filter Staub durch/mit [something preferably held]" as protecting with.
Understand "filter Staub durch/mit [something preferably held] aus" as protecting with.
Understand "halt [dir] [something preferably held] ueber/vor" as protecting with.
Understand "halt [dir] [something preferably held] ueber/vor [yourself-synonyms]" as protecting with.
Understand "hol [dir] [breath-synonyms] durch [something preferably held]" as protecting with.
Understand "hol [dir] durch [something preferably held] [breath-synonyms] " as protecting with.
Understand "leg [dir] [something preferably held] ueber [yourself-synonyms]" as protecting with.
Understand "schuetz [dich] durch/mit [something preferably held]" as protecting with.

Check protecting with something:
	say "Damit wirst [du] nichts erreichen." instead.
		
Instead of protecting with the towel:
	try wearing the towel.

Protecting it with is an action applying to one thing and one carried thing.
Understand "halt [something preferably held] ueber/vor [dativ] [something]" as protecting it with (with nouns reversed).
Understand "halt [something preferably held] ueber/vor [dativ] [yourself]" as protecting it with (with nouns reversed).
Understand "drueck [dir] [something preferably held] auf/vor [something]" as protecting it with (with nouns reversed).
Understand "drueck [dir] [something preferably held] auf/vor [yourself]" as protecting it with (with nouns reversed).

Check protecting something with something:
	say "Damit wirst [du] nichts erreichen." instead.

Instead of protecting yourself with the towel:
	try wearing the towel.

Instead of tying the towel to yourself:
	try wearing the towel.

Instead of tying the towel to the leaky gas pipes:
	say "Die Rohre sind so dicht an der Wand, dass [du] es nicht schaffst, das Handtuch darum zu wickeln.".


Chapter Opening the blood bottle

The block cutting rule is not listed in any rulebook.
Cutting it with is an action applying to one thing and one carried thing.

Understand "schneid [something] ab/auf/auseinander/entzwei/kaputt" as cutting.
Understand "schneid [something] ab/auf/auseinander/entzwei/kaputt mit [dativ] [something preferably held]" as cutting it with.
Understand "schneid [something] mit [dativ] [something preferably held]" as cutting it with.
Understand "schneid [something] mit [dativ] [something preferably held] ab/auf/auseinander/entzwei/kaputt" as cutting it with.
Understand the commands "hack", "meissel", "saebel", "stemm" as "schneid".
[ GerX: Understand the commands "trenn" and "spalt" and "teil" and "zertrenn" and "durchschneid" and "zerteil" and "zerschneid" as "schneid". ]

Understand "hau [something] ab/auf/auseinander/entzwei/kaputt mit [dativ] [something preferably held]" as cutting it with.
Understand "hau [something] mit [dativ] [something preferably held]" as cutting it with.
Understand "hau [something] mit [dativ] [something preferably held] ab/auf/auseinander/entzwei/kaputt" as cutting it with.

Instead of attacking a blood bottle (called the attacked):
	try cutting the attacked.

Instead of attacking a blood bottle (called the item) with something (called the tool):
	try cutting the item with the tool.

Instead of opening a blood bottle (called the item):
	try cutting the item.	
	
Instead of unlocking a blood bottle (called the item) with something (called the tool):
	try cutting the item with the tool.	
	
Check cutting something (called the item):
	if the item is a blood bottle:
		if the player carries the knife:
			say "(mit dem Messer)";
			try cutting the item with the knife instead;
		else:
			say "Womit willst [du] [den item] aufmachen?" instead;
	else:
		say "Es bringt nichts, [den item] zu zerschneiden." instead.
	
Check cutting something (called the item) with something (called the tool):
	if the item is a blood bottle:
		if the item is opened:
			say "Aber [der Item] ist doch schon offen." instead;
		else:	
			if the tool is the knife:
				say "Das Messer ist nicht stabil genug um damit eine Blechdose zu öffnen." instead;
			else:
				if the tool is the chisel or the tool is the leg of lamb:
					if the player carries the chisel and the player carries the leg of lamb:
						continue the action;
					else:
						if the tool is the chisel:
							say "Du hast nichts, das [du] als Hammer benutzen könntest." instead;
						else:
							say "Du hast nichts, das [du] als Meißel benutzen könntest." instead;
	if the item is a blood bottle and the tool is the screwdriver:
		say "Der Schraubenzieher ist nicht spitz genug." instead;
	if the item is a blood bottle:
		say "Es gelingt [dir] nicht [den item] mit [dem tool] zu öffnen." instead;
	say "Es gelingt [dir] nicht [den item] mit [dem tool] zu zerschneiden." instead.

Carry out cutting a blood bottle (called the item) with something:
	now the item is opened.

Report cutting a blood bottle (called the item) with something:
	say "Vorsichtig setzt [du] den Meißel an und hämmerst, mit der gefrorenen Lammkeule als Hammer, Löcher in den Deckel [des item], bis [du] [ihn] öffnen kannst[if the item is unknown]. Die Dose ist bis zum Rand mit Blut gefüllt[end if].";
	now the item is known;
	now the item is opened.


Chapter Using

Using is an action applying to one thing.
Using it with is an action applying to two things.

Using is allowing wide scope.

Understand "benutz [something preferably held]" as using.
Understand "setz [something preferably held] ein" as using.
Understand "wend [something preferably held] an" as using.
Understand "benutz [something] mit [dativ] [something preferably held]" as using it with.
Understand "setz [something] mit [dativ] [something preferably held] ein" as using it with.
Understand "wend [something] mit [dativ] [something preferably held] an" as using it with.
Understand the commands "benuetz", "gebrauch", "nutz", "verwend" as "benutz".

Check using:
	say "Das macht keinen Sinn." instead.

Check using something with something:
	say "Das macht keinen Sinn." instead.


Section Using a device

Instead of using a device (called the item):
	try switching the item instead.


Section Using a door

Instead of using a door (called the doorway):
	if the doorway is locked:
		say "[Der doorway] scheint abgeschlossen zu sein." instead;
	if the doorway is closed:
		try opening the doorway;
	try entering the doorway. 

Instead of using a door (called the doorway) with something (called the item):
	if the doorway is locked:
		try unlocking the doorway with the item;
		if the doorway is locked:
			stop the action;
	if the doorway is closed:
		try opening the doorway;
	try entering the doorway. 

Instead of using something (called the item) with a door (called the doorway):
	try using the doorway with the item instead.
	

Section Using the basin

Instead of using the basin:
	try switching on the basin.

	
Section Using the bench

Instead of using the bench:
	try entering the bench.


Section Using the chisel

Instead of using the chisel with something (called the item):
	try cutting the item with the chisel instead.

Instead of using something (called the item) with the chisel:
	try cutting the item with the chisel instead.


Section Using the coffin key

Instead of using the coffin key with something (called the item):
	try unlocking the item with the coffin key instead.

Instead of using something (called the item) with the coffin key:
	try unlocking the item with the coffin key instead.


Section Using the cross

Instead of using the cross:
	say "Du sprichst ein kurzes Gebet." instead.
	
Instead of using the cross with the count:
	try showing the cross to the count instead.
	

Section Using the hook

Instead of using the hook with something (called the item):
	try pulling the item with the hook instead.
	

Section Using the kitchen

Instead of using the kitchen:
	say "Du bist nicht hungrig." instead.
	

Section Using the knife

Instead of using the knife with the stone:
	try pulling the stone with the knife instead.
	
Instead of using the knife with something (called the item):
	try cutting the item with the knife instead.

Instead of using the stone with the knife:
	try pulling the stone with the knife instead.
	
Instead of using something (called the item) with the knife:
	try cutting the item with the knife instead.


Section Using the lavatory

Instead of using the lavatory:
	say "Du musst gerade nicht." instead.
	

Section Using the leaky gas pipes

Instead of using the leaky gas pipes with something (called the item):
	try using the leaky gas pipes instead.

Instead of using something (called the item) with the leaky gas pipes:
	try using the leaky gas pipes instead.


Section Using the leg of lamb

Instead of using the leg of lamb:
	try eating the leg of lamb instead.


Section Using the mirror

Instead of using the mirror:
	try examining the mirror instead.


Section Using the note

Instead of using the note:
	try examining the note instead.


Section Using the pack of matches

Instead of using the pack of matches:
	try burning the pack of matches instead.

Instead of using the pack of matches with something (called the item):
	try burning the item with the pack of matches instead.

Instead of using something (called the item) with the pack of matches:
	try using the pack of matches with the item instead.


Section Using the piece of paper

Instead of using the piece of paper:
	try examining the piece of paper instead.


Section Using the pliers

Instead of using the pliers with something (called the item):
	try pulling the item with the pliers instead.

Instead of using something (called the item) with the pliers:
	try using the pliers with the item instead.


Section Using the screwdriver

Instead of using the screwdriver with something (called the item):
	try pulling the item with the screwdriver instead.

Instead of using something (called the item) with the screwdriver:
	try using the screwdriver with the item instead.


Section Using the sink

Instead of using the sink:
	try switching on the sink.


Section Using the stove

Instead of using the stove:
	try switching on the stove instead.

Instead of using the stove with something (called the item):
	try switching on the stove instead.

Instead of using something (called the item) with the stove:
	try switching on the stove instead.


Section Using the toilet

Instead of using the toilet:
	try using the lavatory instead.


Section Using the towel

Instead of using the towel:
	if the player does not carry the towel:
		carry out the implicitly taking activity with the towel;
	if the player carries the towel:
		if the player is in the closed cellar coffin:
			try wearing the towel instead;
		else:
			say "Du wischst [dir] den Schweiß von der Stirn." instead.

Instead of using the towel with yourself:
	try wearing the towel instead.

Instead of using something (called the item) with the towel:
	try using the towel with the item instead.


Section Using the vacuum cleaner

Instead of using the vacuum cleaner with something (called the item):
	try vacuuming the item.

Instead of using something (called the item) with the vacuum cleaner:
	try vacuuming the item.


Chapter Figures Z-Machine (for Z-Machine only)

To say show commands:
	say "Der Befehl '[fixed letter spacing]info[variable letter spacing]' zeigt zusätzliche Informationen.".

To say Ghost:
	say "Von draußen klingen dumpf zwölf Schläge einer Uhr an [dein] Ohr: Mitternacht, Geisterstunde![paragraph break]";
	say "Die Luft vor [dir] beginnt zu flimmern und zwei große, fahle Augen blicken [dich] stumpf an.";
	say "Ahhh, ein Geist!".

To say Count arrives:
	say "Au­weia, der Graf schlief im Sarg. Nun will er [dich] beißen. Hilfe, was tun?".
	
To say Count leaves:
	now the count is nowhere;
	now the pile of ash is in the tower coffin;
	now the pliers is in the tower coffin;
	say "Der Graf stöhnt gequält auf und verbrutzelt in ein Aschehäufchen. Das war knapp.".


Chapter Figures Glulx (for Glulx only)

A room has a figure name called default room figure.
A room has a figure name called c64 room figure.
A room has a figure name called spectrum room figure.

Graphics mode is a kind of value. The graphics modes are default, c64, spectrum, and off.
The current graphics mode is a graphics mode that varies.

Figure of darkness is the file "darkness.png".


Figure of living room default is the file "living room.png".
Figure of living room c64 is the file "living room_c64.png".
Figure of living room spectrum is the file "living room_spectrum.png".

The default room figure of living room is figure of living room default.
The c64 room figure of living room is figure of living room c64.
The spectrum room figure of living room is figure of living room spectrum.


Figure of kitchen default is the file "kitchen.png".
Figure of kitchen c64 is the file "kitchen_c64.png".
Figure of kitchen spectrum is the file "kitchen_spectrum.png".

The default room figure of kitchen is figure of kitchen default.
The c64 room figure of kitchen is figure of kitchen c64.
The spectrum room figure of kitchen is figure of kitchen spectrum.


Figure of tower room default is the file "tower room.png".
Figure of tower room c64 is the file "tower room_c64.png".
Figure of tower room spectrum is the file "tower room_spectrum.png".

Figure of tower room Drakula default is the file "tower room drakula.png".
Figure of tower room Drakula c64 is the file "tower room drakula_c64.png".
Figure of tower room Drakula spectrum is the file "tower room drakula_spectrum.png".

Figure of tower room rip default is the file "tower room rip.png".
Figure of tower room rip c64 is the file "tower room rip_c64.png".
Figure of tower room rip spectrum is the file "tower room rip_spectrum.png".

The default room figure of tower room is Figure of tower room default.
The c64 room figure of tower room is Figure of tower room c64.
The spectrum room figure of tower room is Figure of tower room spectrum.


Figure of lavatory default is the file "lavatory.png".
Figure of lavatory c64 is the file "lavatory_c64.png".
Figure of lavatory spectrum is the file "lavatory_spectrum.png".

The default room figure of lavatory is figure of lavatory default.
The c64 room figure of lavatory is figure of lavatory c64.
The spectrum room figure of lavatory is figure of lavatory spectrum.


Figure of cellar default is the file "cellar.png".
Figure of cellar c64 is the file "cellar_c64.png".
Figure of cellar spectrum is the file "cellar_spectrum.png".

The default room figure of cellar is figure of cellar default.
The c64 room figure of cellar is figure of cellar c64.
The spectrum room figure of cellar is figure of cellar spectrum.


Figure of ghost default is the file "ghost.png".
Figure of ghost c64 is the file "ghost_c64.png".
Figure of ghost spectrum is the file "ghost_spectrum.png".


The current graphics mode is default.

To say current graphics mode:
	if current graphics mode is default:
		say "Default";
	else if current graphics mode is c64:
		say "C64";
	else if current graphics mode is spectrum:
		say "Spectrum";
	else if current graphics mode is off:
		say "aus";

Requesting the current graphics mode is an action out of world.
Understand "grafik" as requesting the current graphics mode.
Understand the command "grafikmodus" as "grafik".

Report requesting the current graphics mode:
	say "Du kannst die Grafik '[fixed letter spacing]an[variable letter spacing]' oder ";
	say "'[fixed letter spacing]aus[variable letter spacing]' schalten und die Art der Grafiken aus ";
	say "'[fixed letter spacing]Default[variable letter spacing]', ";
	say "'[fixed letter spacing]C64[variable letter spacing]' und ";
	say "'[fixed letter spacing]Spectrum[variable letter spacing]' wählen.";
	say "Der aktuelle Grafikmodus ist '[current graphics mode]'.".


Setting the current graphics mode is an action out of world applying to one topic.
Understand "grafik [text]" as setting the current graphics mode.

Check setting the current graphics mode:
	let T be indexed text;
	let T be the topic understood;
	if T is not "an" and T is not "aus" and T is not "default" and T is not "c64" and T is not "spectrum":
		say "Du kannst die Grafik nur 'an' oder 'aus' schalten und die Art der Grafiken aus 'Default', 'C64' und 'Spectrum' wählen.";
		stop the action;
	continue the action.		
		
Carry out setting the current graphics mode:
	let T be indexed text; 
	let T be the topic understood;
	if T is "aus":
		now current graphics mode is off; 
	if T is "an" or T is "default":
		now current graphics mode is default; 
	if T is "c64":
		now current graphics mode is c64;
	if T is "spectrum":
		now current graphics mode is spectrum.
	
Report setting the current graphics mode:
	say "O.K., der Grafikmodus ist nun '[current graphics mode]'.";
	try looking.


The image-setting rule is listed before the room description body text rule in the carry out looking rules. 

This is the image-setting rule:
	if current graphics mode is not off:
		if in darkness:
			display figure of darkness;
		else:
			if the default room figure of the location is not figure of cover: [ d.h. es ist ein Wert gesetzt ]
				if current graphics mode is default:
					display the default room figure of the location;
				else if current graphics mode is c64:
					display the c64 room figure of the location;
				else if current graphics mode is spectrum:
					display the spectrum room figure of the location.

To say show commands:
	say "Der Befehl '[fixed letter spacing]info[variable letter spacing]' zeigt zusätzliche Informationen, ";
	say "'[fixed letter spacing]grafik[variable letter spacing]' wählt den Grafikmodus.".

To say Ghost:
	if current graphics mode is not off:
		if current graphics mode is default:
			display the Figure of ghost default;
		else if current graphics mode is c64:
			display the Figure of ghost c64;
		else if current graphics mode is spectrum:
			display the Figure of ghost spectrum;
	say "Von draußen klingen dumpf zwölf Schläge einer Uhr an [dein] Ohr: Mitternacht, Geisterstunde![paragraph break]";
	say "Die Luft vor [dir] beginnt zu flimmern und zwei große, fahle Augen blicken [dich] stumpf an.";
	say "Ahhh, ein Geist!".

To say Count arrives:
	now the default room figure of tower room is Figure of tower room Drakula default;
	now the c64 room figure of tower room is Figure of tower room Drakula c64;
	now the spectrum room figure of tower room is Figure of tower room Drakula spectrum;
	say "Au­weia, der Graf schlief im Sarg. Nun will er [dich] beißen. Hilfe, was tun?";
	try looking.
	
To say Count leaves:
	now the default room figure of tower room is Figure of tower room rip default;
	now the c64 room figure of tower room is Figure of tower room rip c64;
	now the spectrum room figure of tower room is Figure of tower room rip spectrum;
	now the count is nowhere;
	now the pile of ash is in the tower coffin;
	now the pliers is in the tower coffin;
	say "Der Graf stöhnt gequält auf und verbrutzelt in ein Aschehäufchen. Das war knapp.";
	try looking.


Chapter Time

Brightness is a kind of value. The plural of brightness is brightnesses. The brightnesses are bright, twilight, dusk, nightfall, and darkness.
Brightness of day is a brightness that varies.

To say brightness of day:
	if brightness of day is bright:
		say "hell"; 
	if brightness of day is twilight:
		say "dämmrig";
	if brightness of day is dusk:
		say "duster";
	if brightness of day is nightfall:
		say "finster";
	if brightness of day is darkness:
		say "dunkel".
 
The time of day is 4:00 PM.
The brightness of day is bright.

To say capitalised location:
	(- RunCapitalised(WithoutArt, location, Nom); -).

When play begins:
	now the left hand status line is "[if in darkness]Im Dunkeln[else][capitalised location] ([brightness of day])[end if]";
	now the right hand status line is "[time of day] Uhr".

This is the fast time rule:
	increment the turn count;
	increase the time of day by 5 minutes.

The fast time rule is listed before the timed events rule in the turn sequence rules.
The advance time rule is not listed in the turn sequence rules.

[ looking or taking inventory doesn't use up time ]
Looking is acting fast. Taking inventory is acting fast.
The take visual actions out of world rule is listed before the every turn stage rule in the turn sequence rules.
This is the take visual actions out of world rule: if acting fast, rule succeeds.

At 05:00 pm:
	say "Es beginnt zu dämmern.";
	now brightness of day is twilight.

At 06:00 pm: 
	say "Der Abend dämmert.";
	now brightness of day is dusk.

At 07:00 pm: 
	say "Die Dunkelheit bricht herein.";
	now brightness of day is nightfall.

At 08:00 pm: 
	now brightness of day is darkness;
	now all rooms are dark; [ gibt "Es ist nun stockfinster hier!" aus, wenn keine Lichtquelle da ist ]
	if the player is not in a dark room:
		say "Es ist dunkel geworden.".

At 00:00 am:
	say "[Ghost]";
	if the player carries the vacuum cleaner:
		say "Beherzt ziehst [du] den 'Ghostsucker': ein Druck auf den Einschalter und ein kurzes 'BRRRRRRRR...' später ist von dem Geist nichts mehr zu sehen.";
	else:
		say "Du bist völlig entgeistert.";
		end the story finally saying "Du bist tot".
	
At 03:00 am:
	say "Plötzlich überkommt [dich] eine große Schwermut und [du] brichst vor Heimweh zusammen.";
	end the story finally saying "Du bist tot".


Chapter Smelly rooms

A room can be smelly or fresh. A room is usually fresh.


Chapter List Writer

The list writer internal rule response (V) is "[regarding list writer internals][liegt-liegen bezogen auf Liste]".
To say liegt-liegen bezogen auf Liste: (- if (prior_named_list > 1 ) print "liegen"; else print "liegt"; -).


Chapter Pulling it with

Pulling it with is an action applying to one thing and one carried thing.
Understand "zieh [something] mit [something preferably held]" as pulling it with.
Understand "zieh [something] mit [something preferably held] heraus/raus" as pulling it with.
Understand "zieh an [dativ] [something] mit [something preferably held]" as pulling it with.
Understand "mach [something] mit [something preferably held] ab/los" as pulling it with.
Understand "entfern [dativ] [something] mit [something preferably held]" as pulling it with.
Understand the commands "locker" or "loes" as "zieh".

Check pulling something (called the pulled) with something (called the tool):
	if the pulled is the painting and the safe is not in the living room: [ das Bild ist noch an der Wand ]
		if the tool is the pliers:
			say "Mit der Beißzange entfernst [du] nach und nach die Nägel. Hinter dem Bild entdeckst [du] einen kleinen Tresor.";
			now the painting is not fixed in place;
			now the painting is not scenery;
			now the player carries the painting;
			now the safe is in the living room;
		else:
			say "Mit [dem tool] kannst [du] die Nägel nicht entfernen.";
			stop the action;
	else:
		if the pulled is the stone and the cavity is not in the tower room: [ der Stein ist noch in der Wand ]
			if the tool is the knife or the tool is the chisel:
				say "Vorsichtig lockerst [du] den Stein und kannst ihn bald vorziehen. Mit einem dumpfen Geräusch fällt er auf den Boden und gibt eine Höhlung frei.";
				now the cavity is in the tower room;
			else:
				say "Mit [dem tool] kannst [du] den Stein nicht lockern.";
				stop the action;
		else:
			if the pulled is the screws and the player is in the cellar coffin:
				if the tool is the screwdriver:
					try unlocking the cellar coffin with the screwdriver;
				else:
					say "Mit [dem tool] bekommst [du] die Schrauben nicht heraus.";
					stop the action;
			else:
				try pulling the pulled instead.
		

Chapter Vacuuming

Vacuuming is an action applying to one thing.
Understand "saug [things]" as vacuuming.
Understand "saug [any room]" as vacuuming. ["a room" funktioniert nicht]
Understand "saug [things] ab/auf/durch/ein" as vacuuming.
Understand "saug [any room] ab/durch" as vacuuming.
Understand the command "staubsaug" as "saug".

Vacuuming it with is an action applying to two things.
Understand "saug [things] mit [something preferably held]" as vacuuming it with.
Understand "saug [any room] mit [something preferably held]" as vacuuming it with.
Understand "saug [things] mit [something preferably held] ab/auf/ein" as vacuuming it with.
Understand "saug [other things] von/vom [something]" as vacuuming it with.
Understand "saug [other things] von/vom [something] [herunter]" as vacuuming it with.

Check vacuuming something (called the item):
	if the player does not carry the vacuum cleaner:
		say "Du hast nichts, um damit Staub zu saugen.";
	else:
		say "(mit dem Staubsauger)";
		try vacuuming the item with the vacuum cleaner;
	stop the action.

Check vacuuming a room (called the room):
	if the room is not the location:
		say "So etwas kannst Du hier nicht sehen." instead;
	if the player does not carry the vacuum cleaner:
		say "Du hast nichts, um damit Staub zu saugen.";
	else:
		say "(mit dem Staubsauger)";
		try vacuuming the room with the vacuum cleaner;
	stop the action.
	
Check vacuuming something (called the item) with something (called the tool):
	if the item is the tool:
		say "Das macht keinen Sinn.";
		stop the action;
	if the tool is the vacuum cleaner and the vacuum cleaner is not carried by the player:
		say "Du hast nichts, um damit Staub zu saugen.";
		stop the action;
	if the tool is the vacuum cleaner and the item is the player:
		say "Normalerweise wäscht man sich zwar, aber ok: BRRRRRRRR - Du bist jetzt etwas sauberer.";
		stop the action;
	if the tool is the vacuum cleaner and the item is dust:
		now dust is nowhere;
		say "BRRRRRRRR - Der feine Staub verschwindet im Staubsauger.";
		stop the action;
	if the tool is the vacuum cleaner and the item is the pile of ash:
		now the pile of ash is nowhere;
		say "Ein kurzer Druck auf den Einschalter und 'BRRRRRRRR...' ist von den Überresten des Grafen nichts mehr zu sehen.";
		stop the action;
	if the tool is the vacuum cleaner and the player carries the item:
		continue the action;
	if the tool is the vacuum cleaner and the item is portable:
		if the item is the tower key and the tower key is scenery: [key was not found yet]
			say "Ein seltsames Geräusch beim Saugen des Teppichs macht [dich] auf einen Schlüssel aufmerksam, den [du] mitnimmst.";
			now the tower key is not scenery;
			now the player carries the tower key;
			stop the action;
		try silently taking the item;
		if the player carries the item:
			say "Du saugst [den item] auf und nimmst [ihn] an [dich].";
			stop the action;
		else:
			say "Du schaffst es nicht [den item] aufzusaugen." instead.

Check vacuuming a room (called the room) with something (called the tool):
	if the room is not the location:
		say "So etwas kannst Du hier nicht sehen." instead;
	if the tool is the vacuum cleaner and the vacuum cleaner is not carried by the player:
		say "Du hast nichts, um damit Staub zu saugen.";
		stop the action;

Report vacuuming something (called the item) with something (called the tool):
	say "BRRRRRRRR - [der item] [ist] jetzt etwas sauberer.".

Report vacuuming a room (called the room) with something (called the tool):
	say "BRRRRRRRR - [der room] [ist] jetzt etwas sauberer.".

Before vacuuming a container (called the C):
	if something is in the C:
		let item be a random thing in the C;
		try vacuuming the item instead.
	
Before vacuuming a supporter (called the S):
	if something is on the S:
		let item be a random thing on the S;
		try vacuuming the item instead.
	
Instead of vacuuming a candle on the chandelier with the vacuum cleaner :
	try vacuuming the chandelier with the vacuum cleaner instead.

Instead of vacuuming a candle with the chandelier:
		try vacuuming the chandelier instead.

Chapter Info

Requesting information is an action out of world and applying to nothing.
Understand "info" as requesting information.

Carry out requesting information:
	say "Das Spiel 'Drakulas Diamanten' wurde im Oktober 1983 in der Zeitschrift 'Homecomputer' als Listing ";
	say "zum Abtippen für den Sinclair ZX-81 veröffentlicht. Da ich keinen ZX-81 hatte, musste ich mich mit der ";
	say "Spielbeschreibung begnügen.";
	say "Viele Jahre später habe ich das Spiel dann auf dem C64 gespielt. Leider war es nicht so, wie ich es mir ";
	say "ausgemalt hatte. Diese Umsetzung versucht das zu beheben.[paragraph break]";
	say "[show commands]";
	say "Lob, Kritik, Bug-Reports bitte an 'Frank.Gerbig[mail-at]web.de'.[paragraph break]";
	say "Vielen Dank an die Beta-Tester: [italic type]Olaf Nowacki, Martin Oehm, sowie meine Kinder Lukas und Julia.[roman type][line break]".


Chapter When play begins

To say mail-at:
	say "@".

When play begins:
	say "Bei Interpol ist die Hölle los: ";
	say "Die wertvollen Diamanten der Gattin des Milliardärs N.J. Sirmel sind vor drei Tagen verschwunden. ";
	say "Man fand Frau Sirmel am Montagmorgen sowohl ihres Blutes als auch ihres Schmuckes beraubt, ";
	say "tot auf dem kniehohen Perser liegend, das Fenster offen, den Täter fort.[paragraph break]";
	say "Aus folgenden drei Gründen fiel der Verdacht sofort auf den jungen Grafen Drakula:[line break]";
	say "  1) Er hatte weder ein Alibi, noch eine Erklärung für sein sattes Aussehen.[line break]";
	say "  2) Er hatte noch Stunden später entsetzlichen Mundgeruch.[line break]";
	say "  3) Der Graf steckt über beide Beißzähne in Schulden. Das Schloss ist verpfändet, er selbst arbeitet als Nachtwächter.[paragraph break]";
	say "Heute wohnt der Graf in einer bescheidenen 4½-Zimmerwohnung in einem kleinbürgerlichen Villenviertel. ";
	say "Da vermutet wird, dass die Beute dort versteckt ist, beauftragt man Dich, sie dort zu suchen.";
	say "Du hast nur zwei Möglichkeiten: der beste lebende Detektiv zu sein oder der fünft-beste tote zu werden. ";
	say "Die anderen vier waren schon drin; Friede ihrer Asche.[paragraph break]";
	say "Im Haus sind fünf Tipps versteckt (auf Zetteln, eingeritzt, usw.), keiner ist wertlos. ";
	say "Hier noch ein sechster: '[italic type]Ist das Holz erst abgelegt, ist der Stink wie weggefegt[roman type]'.[paragraph break]";
	say "[fixed letter spacing]PS:[variable letter spacing] [show commands]";
	say "[fixed letter spacing]   [variable letter spacing] Lob, Kritik, Bug-Reports bitte an '[italic type]Frank.Gerbig[mail-at]web.de[roman type]'.";
	say "[fixed letter spacing]   [variable letter spacing] Vielen Dank an die Beta-Tester: [italic type]Olaf Nowacki, Martin Oehm, sowie meine Kinder Lukas und Julia.[roman type][line break]".
	

Part Living room

The living room is a room. The printed name of the living room is "Wohnraum[-s][m]". "Gleich beim Eintritt fällt [if the safe is in the location]der kleine eingelassene Tresor in[else]das seltsame, in grauenhaften Farben gehaltene Bild an[end if] der gegenüberliegenden Wand auf. Ein kalter, zugiger Luftstrom weht aus einem geöffneten mit einem Moskitonetz versehenen Fenster. Neben der Tür mit dem runden Griff ist ein Kasten in die Wand eingelassen. Auf einem weichen Teppich steht ein niedriges Tischchen, über dem ein geschmackvoller Leuchter mit [if number of candles on the chandelier is 2]zwei Kerzen[else]einer Kerze[end if] prunkt. Durch einen geblümten Vorhang gelangt man nach Westen[if kitchen was visited] in die Küche[end if], eine Tür mit der Aufschrift 'WC' führt nach Norden und eine Falltür führt nach unten[if the cellar was visited] in den Keller[end if].".
Understand "Wohnraum[m]", "Wohnzimmer[n]" as the living room.

Instead of going up in the living room:
	if the player is not on the table:
		say "(auf das niedrige Tischchen)";
	try climbing the table instead.

Instead of jumping in the living room:
	if the player is on the table:
		say "Das Tischen sieht so wacklig aus, dass [du] das lieber bleiben lässt." instead;
	else:
		if the player does not carry a candle:
			say "Du kannst nicht hoch genug springen, um an die Kerze zu kommen. Vielleicht solltest [du] besser auf etwas steigen." instead;
		else:
			continue the action.
	

Section Painting

The painting is scenery in the living room. The printed name is "seltsam[^] Bild[-es][n]". The description is "Ein seltsames Bild mit grauenhaften Farben. Es zeigt ein, ähh, oder vielleicht doch ein - ach, [du] wirst aus dieser modernen Kunst einfach nicht schlau.[if the safe is not in the living room] Das Bild ist mit Nägeln an der Wand befestigt.[end if]".
Understand "seltsam", "grauenhaft", "farbig", "Farben[p]", "Bild[n]", "Leinwand[f]" or "Gemaelde[n]" as the painting.
Understand "Nagel[m]" or "Naegel[p]" as the painting when the safe is not in the living room.

Instead of taking or pulling or turning or opening the painting:
	if the safe is not in the living room: [ das Bild ist noch an der Wand ]
		say "Das Bild ist an die Wand genagelt." instead;
	else:
		continue the action.

Understand "loes [something]" as taking. ["löse Bild"]

Understand "nimm [something] von Wand" as taking. [ugly hack...]
Understand "nimm [something] von der Wand" as taking.
Understand "entfern [something] von Wand" as taking.
Understand "entfern [something] von der Wand" as taking.
Understand "loes [something] von Wand" as taking.
Understand "loes [something] von der Wand" as taking.

Instead of attacking or burning or cutting or touching the painting:
	say "Du möchtest das Bild nicht beschädigen: es ist zwar hässlich, aber vielleicht doch wertvoll." instead.
	
Instead of attacking the painting with something:
	try attacking the painting instead.

Instead of burning the painting with something:
	try burning the painting instead.

Instead of cutting the painting with something:
	try cutting the painting instead.


Instead of looking under the painting when the safe is not in the living room:
	say "Das Bild ist an die Wand genagelt, [du] kannst nicht dahinter schauen.".


Section Safe

The safe is a closed locked container. The printed name is "klein[^] Tresor[-s][m]". The description is "Ein kleiner Tresor mit Nummernschloss ist in die Wand eingelassen. In das Nummernschloss kann man die Kombination eintippen[if note is not known] (so man sie denn kennt)[end if].".
The safe is fixed in place.
Understand "klein", "Tresor[m]", "Geldschrank[m]", "Panzerschrank[m]", "Safe[m]", "Schloss[n]", "Nummernschloss[n]" as the safe.

A thing can be known or unknown.
A thing is usually unknown.

After examining a thing (called the item):
	now the item is known.

Check unlocking the safe with something (called the tool):
	if the note is known or the tool is the note:
		if the tool is the note:
			continue the action;
		else:
			try unlocking the safe with the note;
	else:
		say "Der Tresor ist verriegelt und [du] kennst die Kombination nicht!" instead.

Carry out unlocking the safe with something:
	now the safe is unlocked.
	
Report unlocking the safe with something:
	say "Du gibst die Kombination vom Notizzettel in das Schloss ein - Klick! [run paragraph on]";
	try opening the safe instead.

Understand "gib [text] in [something] ein" as setting it to (with nouns reversed).
Understand "gib [text] ein" as a mistake ("In was möchtest [du] etwas eingeben?").
Understand "oeffne [something] mit [text]" as setting it to.
Understand "stell [something] ein" as setting it to.
Understand "tipp [text] in [something]" as setting it to (with nouns reversed).
Understand "tipp [text] in [something] ein" as setting it to (with nouns reversed).
Understand "tipp [text]" as a mistake ("In was möchtest [du] etwas eintippen?").
Understand "tipp [text] ein" as a mistake ("In was möchtest [du] etwas eintippen?").

The block setting it to rule is not listed in any rulebook.

Check an actor setting something to:
	if the actor is the player:
		if the noun is the safe:
			if the safe is locked: 
				let T be indexed text; 
				let T be the topic understood;
				say "[T]";
				if the note is known: [ die Kombination ist bekannt ]
					if the player carries the note:
						try unlocking the safe with the note instead;
					else:
						say "Wie war nochmal die Kombination? Du solltest besser nochmal nachschauen.";
				else:
					if T is "" or T is "kombination" or T is "die kombination":
						say "Du kennst die Kombination nicht." instead;
				say "Du tippst auf den Tasten am Schloss herum - ein ärgerlicher Piepston teilt [dir] mit, dass das Schloss nicht vorhat sich zu öffnen." instead;
			else:
				say "Der Tresor ist schon entriegelt." instead;
		else:
			say "Du kannst [den noun] nicht auf irgendetwas einstellen.";
	stop the action.

The board is a thing in the safe. The printed name is "dick[^] Brett[-es][n]". The description is "Ein dickes Holzbrett, ca. 20cm x 50cm groß.".
Understand "dick", "Brett[n]", "Holz[n]", "Holzbrett[n]", "Diele[f]", "Holzdiele[f]", "Bohle[f]", "Holzbohle[f]", "Planke[f]", "Holzplanke[f]" as the board.

Check climbing the board when the board is on a supporter (called the sup):
	try entering the sup instead.

Check entering the board when the board is on a supporter (called the sup):
	try entering the sup instead.


Section Window

The living room window is scenery in the living room. The printed name is "offen[^] Fenster[-s][n]". The description is "Das geöffnete Fenster ist mit einem Moskitonetz versehen. Ein kalter Luftstrom bringt frische Luft ins Zimmer. Draußen ist es [brightness of day] und es regnet.".
Understand "offen", "kalt", "zugig", "Fenster[n]", "Luke[f]", "Scheibe[f]", "Fensterfluegel[m]", "Moskitonetz[n]", "Netz[n]" or "Luftstrom[m]" as the living room window.

Instead of closing the living room window, say "Die Fensterflügel sind festgestellt.".
Instead of opening the living room window, say "Das Fenster ist schon offen.".
Instead of searching the living room window, say "Draußen ist es [brightness of day] und es regnet.".


Section Wand box

The wand box is a scenery closed openable container in the living room. The printed name is "Wandkasten[-s][m]". The description is "In die Wand ist ein Kasten eingelassen.".
Understand "eingelassen", "Kasten[m]", "Wandkasten[m]", "Kaestchen[n]", "Wandkaestchen[n]", "Box[f]" or "Wandbox[f]" as the wand box.

The vacuum cleaner is a device in the wand box. The printed name is "Staubsauger[-s][m]". The description is "Ein Akku-Staubsauger der Marke 'Ghostsucker'.".
Understand "Staubsauger[m]", "Sauger[m]", "Akku[m]", "Akku-Staubsauger[m]", "Akkustaubsauger[m]", "Marke[f]" or "Ghostsucker" as the vacuum cleaner.

After switching on the vacuum cleaner:
	the vacuum cleaner switches off in three turns from now.

Every turn when the vacuum cleaner is switched on:
	say "BRRRRRRRR...".
	
At the time when the vacuum cleaner switches off:
	if the vacuum cleaner is switched on:
		now the vacuum cleaner is switched off; 
		say "Du erträgst das Gebrumme des Staubsaugers nicht länger und schaltest ihn aus. Die Stille ist zunächst ungewohnt.".
	
After switching off the vacuum cleaner:
	say "Die Stille ist zunächst ungewohnt.".
	

Section Curtain

The curtain is a closed scenery door. The printed name is "geblümt[^] Vorhang[-s][m]".
Understand "gebluemt", "Vorhang[m]" or "Gardine[f]" as the curtain.
The curtain is west of the living room and south of the kitchen. 

Instead of pulling the curtain:
	try opening the curtain.


Section Carpet

The carpet is a scenery supporter in the living room. The printed name is "weich[^] Teppich[-s][m]".
The description is "Auf dem Boden liegt ein weicher, sehr hochfloriger Teppich."
Understand "weich", "hochflorig", "Teppich[m]", "Boden[m]" or "Fussboden[m]" as the carpet.

Instead of pushing or pulling the carpet:
	say "Du schiebst den Teppich etwas hin und her.";
	if the tower key is scenery: [key was not found yet]
		say "[line break][find tower key]".
	
Instead of taking the carpet:
	say "Der Teppich ist zu schwer.";
	if the tower key is scenery: [key was not found yet]
		say "[line break][find tower key]".
	
Instead of looking under the carpet:
	if the tower key is scenery: [key was not found yet]
		say "[find tower key]";
	else:
		continue the action.

After searching or examining the carpet:
	if the tower key is scenery: [key was not found yet]
		say "[find tower key]".


The tower key is a scenery portable thing on the carpet. The printed name is "[if tower key is known]Türs[else]S[end if]chlüssel[-s][m]". The description is "Könnte zu einer Tür passen.".
Understand "Schluessel[m]", "Tuerschluessel[m]" as the tower key.

Instead of taking the tower key when the tower key is scenery:
	say "So etwas kannst Du hier nicht sehen.".
	
To say find tower key:
		say "Du findest einen Schlüssel, den [du] mitnimmst.";
		now the tower key is not scenery;
		now the player carries the tower key.


Section Table

The table is a scenery enterable supporter in the living room. The printed name of the table is "niedrig[^] Tischchen[-s][n]". The description is "Das niedrige Tischchen sieht etwas wacklig aus.".
Understand "wacklig", "niedrig", "Tischchen[n]", "Tischbein[n]", "Bein[n]" or "Tisch[m]" as the table.


Section Piece of paper

The piece of paper is a thing on the table. The printed name of the piece of paper is "Blatt Papier[-s][n]".
The description is "Auf dem ca. DIN-A4 großen Blatt steht in zittriger Handschrift: 'Nie findest [du] die Stink-Steine'.".
Understand "Stueck[n]", "Papier[n]" or "Blatt[n]" as the piece of paper.

Check the player entering the table:
	if the piece of paper is on the table:
		say "Du rutschst auf dem Blatt Papier aus und stürzt vom Tisch. Im Fallen schlägst [du] [dir] den Kopf an der Tischecke an und verstirbst leider.";
		end the story finally saying "Du bist tot".


Section Candle

A candle is a kind of thing. The printed name is "Kerze[f]". The printed plural name is "Kerzen[p]". The description is "[if the candle is lit]Die Kerze flackert leicht[else]Eine Kerze[end if].".
Understand "Kerze[f]" as a candle. Understand "Kerzen" as the plural of candles.

To say don't drop candle:
	say "Du behältst die Kerze lieber.".

Instead of dropping a candle carried by the player:
	say "[don't drop candle]".

Instead of putting a candle carried by the player on something:
	say "[don't drop candle]".

Instead of inserting a candle carried by the player into something:
	say "[don't drop candle]".

The block burning rule is not listed in any rulebook.

Before burning a candle when the player does not carry the pack of matches:
	say "Du hast nichts, womit [du] die Kerze anzünden könntest." instead.

Check an actor burning:
	if the actor is the player:
		if the player is in the kitchen and the sink is open:
			if the player carries the matches:
				say "(mit den Streichhölzern)[command clarification break]";
				say "[BOOM]" instead;
			else:
				say "Du hast nichts bei [dir] um Feuer zu machen." instead;
		if the noun is a candle:
			if the player is in the cellar coffin:
				say "Du versuchst die Kerze anzuzünden, aber im Sarg ist zu wenig Luft dafür." instead;
			else:
				continue the action;
		else:
			say "[text of block burning rule response (A)][line break]";
	stop the action.

Carry out burning a candle (called the item):
   now the item is lit.

Report burning a candle:
	say "Du nimmst ein Streichholz aus der Packung und zündest die Kerze an."

Instead of burning the lit candle:
   say "Die Kerze brennt bereits."


Instead of switching on a candle (called the candle):
	try burning the candle.

Instead of switching off a candle (called the candle) carried by the player:
	if the candle is lit:
		now the candle is unlit;
		say "Du löschst die Kerze." instead;
	else:
		say "Die Kerze brennt nicht." instead.

Blowing is an action applying to one thing.
Understand "blas [something preferably held]" as blowing.
Understand "blas [something preferably held] aus/weg" as blowing.
Understand the commands "loesch", "puste" as "blas".

Check an actor blowing something (called the item):
	if the item is a lit candle, continue the action;
	if the item is dust, continue the action;
	if the item is the pile of ash, continue the action;
	say "Du pustest und prustest, ohne jeden Effekt.";
	stop the action.

Carry out blowing something (called the item):
	if the item is a lit candle:
		try switching off the item instead;
	if the item is dust:
		if the player is in the cellar coffin:
			if the player is wearing the towel:
				say "Trotz des Handtuchs schaffst [du] es den feinen Staub so aufzuwirbeln, dass er hinter das Handtuch gerät und [dich] zum Husten reizt. [run paragraph on]";
			else:
				say "Der feine Staub verteilt sich im Sarg und reizt [dich] zum Husten. [run paragraph on]";
			say "Bald kannst [du] vor lauter Husten nicht mehr atmen.[paragraph break]";
			say "[italic type]Du bist erstickt![roman type][paragraph break]";
			end the story finally saying "Du bist tot";
		else:
			now dust is nowhere;
			say "Der feine Staub verteilt sich in der Luft und verschwindet dann.";
		stop the action;
	if the item is the pile of ash:
		now the pile of ash is nowhere;
		say "Ein kurzer Puster und von den Überresten des Grafen ist nichts mehr zu sehen.";
		stop the action.

		
Section Chandelier

The chandelier is a scenery supporter in the living room. The printed name is "geschmackvoll[^] Kerzenleuchter[-s][m]".
Understand "geschmackvoll", "Leuchter[m]", "Kerzenleuchter[m]" or "Kronleuchter[m]" as the chandelier.

On the chandelier are two candles.

Instead of taking something on the chandelier:
	 if the player is on the table:
		if two candles are on the chandelier: 
			continue the action;
		else:
			say "Eine Kerze langt [dir].";
	else:
		say "Du kommst von hier unten nicht dran.".

Instead of putting something on the chandelier:
	 if the player is on the table:
		say "Das bringt nichts.";
	else:
		say "Du kommst von hier unten nicht dran.".

For printing a locale paragraph about the chandelier:
	set the locale priority of the chandelier to 0;
	stop the action. 


Instead of vacuuming the chandelier with the vacuum cleaner:
	if two candles are on the chandelier:
		let the item be a random thing on the chandelier;
		now the player carries the item;
		say "Du schaffst es eine Kerze vom Kerzenleuchter herunter zu saugen.";
	else:
		say "Eine Kerze langt [dir].";
	

Section Trap door

The trapdoor is a closed scenery door. The printed name is "Falltür[f]". The description is "[If the trapdoor is closed]Eine Falltür mit einer Öse für einen Haken, um sie hochzuziehen[else if the location is the living room]In der geöffneten Falltür führt eine Leiter nach unten[else]Die Leiter führt durch die Falltür zurück in den Wohnraum[end if].".
Understand "Falltuer[f]", "Luke[f]", "Schlaufe[f]", "Lasche[f]" or "Oese[f]" as the trapdoor.
Understand "Leiter[f]", "Sprossenleiter[f]" as the trapdoor when the trapdoor is open.
The trapdoor is down of the living room and up of the cellar.

Understand "zieh [something] hoch" as pulling.
Understand "reiss [something] auf" as opening.
Understand "zieh [something] mit [something] auf/hoch" as pulling it with.

Instead of pulling the trapdoor:
	try opening the trapdoor.

Instead of unlocking the trapdoor with something (called the tool):
	if the tool is the hook:
		try opening the trapdoor instead;
	else:
		say "Damit kannst die schwere Falltür nicht richtig fassen." instead.

Check opening the trapdoor:
	if the player does not carry the hook:
		say "Du kannst die schwere Falltür nicht richtig greifen. Trotz aller Anstrengungen schaffst [du] es nicht sie zu öffnen." instead.

Report opening the trapdoor:
	say "Du hakst den Haken in die Öse und ziehst die schwere Falltür schwungvoll nach oben. Eine Leiter kommt zum Vorschein." instead.

Instead of vacuuming the closed trapdoor with the vacuum cleaner:
	say "Der Staubsauger ist nicht stark genug um die Falltür anzuheben.".
	

Instead of closing the trapdoor when the trapdoor is open, say "Dazu gibt es keinen Grund.".


Instead of climbing the trapdoor:
	try going the trapdoor.
	
Instead of getting off the trapdoor:
	try going the trapdoor.

Instead of exiting in the living room when the player is not on a supporter:
	try going the trapdoor.

Before climbing in the cellar:
	if the noun is up:
		try going the trapdoor instead.
	

Section WC door

The wc door is a closed scenery door. The printed name is "WC Tür[f]". The description is "Eine Tür mit der Aufschrift 'WC'.".
Understand "rund", "Griff[m]", "WC[n]", "Tuer[f]", "WC-Tuer[f]", "Toilettentuer[f]" or "Badezimmertuer[f]" as the wc door.
The wc door is north of the living room and south of the lavatory.



Part Kitchen

The kitchen is a room. The printed name of the kitchen is "sauber[^] Küche[f]". 
"Eine saubere Versandhausküche[if kitchen is not visited] (der Graf isst meistens auswärts)[end if]: ein Gasherd, eine Spüle mit Ausguss, ein [if fridge is open]offener [end if]Kühlschrank und eine zerkratzte Bank. An der Wand hängt ein Hängeschrank. Im Osten liegt der Wohnraum, nach Westen führt eine Tür[if tower room was visited] zum Turm[end if]. Ein [if the sink is open]starker[else]leichter[end if] Gasgeruch stört empfindliche Nasen.".
Understand "sauber", "Kueche", "Versandhauskueche" as the kitchen.

The kitchen floor is scenery supporter in the kitchen. The printed name is "gefliest[^] Küchenfußboden[-s][m]".
Understand "gefliest", "Boden[m]", "Kuechenboden[m]", "Kuechenfussboden[m]", "Fussboden[m]", "Fliese[f]", "Fliesen[p]" as the kitchen floor.

Report going to the tower room:
	say "Hinter der Tür ist eine steile Wendeltreppe, die [du] hinaufsteigst.".
	
Instead of going up in the kitchen:
		try entering the tower door instead.

Instead of going east in the kitchen:
		try going south instead.

Instead of smelling in the kitchen:
	say "Es riecht [if the sink is open]stark[else]etwas[end if] nach Gas.".


Section Tower door

The tower door is a closed, locked scenery door. The printed name is "[if tower room was visited]Turmt[else]T[end if]ür[f]".
The description is "[tower door description][run paragraph on]".
Understand "stabil", "Holztuer[f]", "Tuer[f]" as the tower door.
Understand "steil", "Turmtuer[f]", "Treppe[f]", "Wendeltreppe[f]", "Turmtreppe[f]" as the tower door when tower door was open.
The tower key unlocks the tower door.
The tower door is west of the kitchen and south of the tower room.

To say tower door description:
	if the tower door is closed:
		say "Eine stabile Holztür.";
	else:
		if location is the kitchen:
			say "Durch die Tür siehst [du] eine steile Wendeltreppe, die nach oben ins [if tower room was visited]Turmzimmer[else]Ungewisse[end if] führt.";
		else:
			say "Durch die geöffnete Tür siehst [du] die Wendeltreppe, die nach unten in die Küche führt.";

Does the player mean unlocking the tower door with the tower key:
	It is very likely.
	
Check opening the locked tower door:
	if the player carries the tower key:
		say "(mit dem Türschlüssel)";
		try unlocking the tower door with the tower key instead.

Carry out unlocking the tower door with the tower key:
	now the tower key is nowhere;
	now the tower door is open.
	
Report unlocking the tower door with the tower key:
	say "Du schließt die Tür auf, den Schlüssel lässt [du] im Schloß stecken. Dann öffnest [du] die Tür und siehst eine steile Wendeltreppe, die nach oben ins Ungewisse führt." instead.
	
	
Section Fridge

The fridge is a closed, openable, scenery container in the kitchen. The printed name of the fridge is "Kühlschrank[-s][m]".
The description of the fridge is "Ein weißer Kühlschrank mit Gefrierfach[if the fridge is open], das Lämpchen im Innern scheint kaputt zu sein; vielleicht ist aber auch der Strom abgestellt[end if].".
The fridge is fixed in place.
Understand "weiss", "Kuehlschrank[m]", "Eisschrank[m]", "Gefrierschrank[n]", "Eisfach[n]", "Gefrierfach[n]", "Tiefkuehlschrank[m]" as the fridge.

The leg of lamb is a edible thing in the fridge. The printed name is "gefroren[^] Lammkeule[f]".
The description of the leg of lamb is "Aus dem ca. 2kg schweren Fleischstück ragt ein dicker, ca. 30cm langer Knochen.".
Understand "dick", "lang", "Lammkeule[f]", "Keule[f]", "Hammelkeule[f]", "Fleisch[n]", "Fleischstueck[n]", "Knochen[m]", "Schlegel[m]", "Schenkel[m]", "Lammschlegel[m]" or "Lammschenkel[m]" as the leg of lamb.

Instead of burning the leg of lamb:
	if the player carries the matches:
		say "Du zündest ein Streichholz an und hältst es unter die Lammkeule. Als das Streichholz verlischt, ist die Lammkeule immer noch tiefgefroren.";
	else:
		say "Du hast nichts um Feuer zu machen.".

Instead of eating the leg of lamb, say "Du kannst keine tiefgefrorene Lammkeule essen.".

Before going from the kitchen when the fridge is open:
	say "(Bevor [du] die Küche verlässt, schließt [du] den Kühlschrank wieder.)";
	now the fridge is closed.


Section Stove

The stove is a scenery supporter in the kitchen. The printed name is "Gasherd[-s][m]". The description is "Ein Gasherd mit zwei Brennern.".
Understand "Herd[m]", "Ofen[m]", "Gasherd[m]", "Kochherd[m]", "Kuechenherd", "Brenner[p]", "Knopf[m]" or "Knoepfe[p]" as the stove.

Instead of switching on the stove, say "Du drehst an den Knöpfen, aber es tut sich nichts.".
Instead of turning the stove, say "Du drehst an den Knöpfen, aber es tut sich nichts.".

Instead of opening the stove:
	try opening the sink instead.
	
Instead of closing the stove:
	try closing the sink instead.
	
The knife is a thing on the stove. The printed name is "Messer[-s][n]". The description is "Ein kleines Messer, vielleicht zum Kartoffelschälen.".
Understand "Messer[n]", "Kuechenmesser[n]", "Kartoffelmesser[n]" as the knife.

Does the player mean cutting something with the knife:
	it is likely.


Section Sink

The sink is a scenery closed openable container in the kitchen. The printed name is "Spüle[f]". The description is "Eine Spüle mit Ausguss. Das stabile Unterschränkchen [if the sink is open]ist offen[else]lässt sich öffnen[end if].".
Understand "Spuele[f]", "Ausguss[m]", "Spuelbecken[n]" as the sink.
Understand "Wasser[n]", "Wasserhahn[m]", "Wasserkran[m]", "Hahn[m]" or "Kran[m]" as the sink.
Understand "stabil", "Schrank[m]", "Schraenkchen[n]", "Unterschraenkchen[n]", "Spuelschrank[m]" or "Unterschrank[m]" as the sink.

To say no-water:
	say "Du drehst das Wasser an, aber außer ein paar schmutzigen Tropfen kommt nichts." instead.
	
Instead of switching on the sink:
	say "[no-water]".

Instead of turning the sink:
	say "[no-water]".

Report opening the sink:
	say "Du öffnest das Schränkchen unter der Spüle und entdeckst ";
	list the contents of the noun, as a sentence, tersely, not listing concealed items;
	say ". Es riecht jetzt stärker nach Gas.";
	stop the action.
	
Report closing the sink:
	say "Du schließt das Schränkchen unter der Spüle und der Geruch nach Gas lässt etwas nach." instead.

	
Every turn when the player is in the kitchen and the sink is open:
	if the player is carrying a lit candle:
		say "[BOOM]".

To say BOOM:
	say "Das ausströmende Gas entzündet sich an der Flamme und 'BOOM'.[line break]Weder von [dir], noch vom Grafen, noch von den Diamanten hat man je wieder etwas gesehen.";
	end the story finally saying "Du bist tot".
	
	
The leaky gas pipes is a device in the sink. The printed name is "undicht[^] Gasrohre[-n][p]". The description is "Aus den undichten Rohren strömt Gas.".
Understand "Rohr[n]", "Rohre[p]", "Gasrohr[n]", "Gasrohre[p]" or "Gas[n]" as the leaky gas pipes.
The leaky gas pipes are fixed in place. ["device", damit man versuchen kann das Gas abzustellen]
The examine devices rule does nothing when the noun is the leaky gas pipes. [verhindert die Meldung "Die undichten Gasrohre sind ausgeschaltet."]

Instead of doing something other than examining with the leaky gas pipes, say "Du solltest da besser die Finger weglassen.".


The pack of matches is a thing in the sink. The printed name is "Packung Streichhölzer[f]".
Understand "Packung[f]", "Paeckchen[n]", "Schachtel[f]", "Streichholz[n]", "Streichhoelzer[p]", "Hoelzer[p]", "Zuendholz[n]" or "Zuendhoelzer[p]" as the pack of matches.

Instead of opening the pack of matches, say "Darin sind eine Menge Streichhölzer.".

Instead of burning the matches:
	if the player is in the kitchen and the sink is open:
		say "[BOOM]" instead;
	say "Du nimmst ein Streichholz aus der Schachtel und zündest es an. Es brennt kurz und verlischt dann.";


Section Window

The kitchen window is a scenery thing in the kitchen. The printed name is "Fenster[-s][n]". The description is "Das Fenster ist geschlossen. Durch die Scheibe blickst [du] nach draußen: es ist [brightness of day] und es regnet.".
Understand "geschlossen", "Fenster[n]", "Scheibe[f]" as the kitchen window.

Instead of closing the kitchen window, say "Das Fenster ist bereits geschlossen.".
Instead of opening the kitchen window, say "Das Fenster lässt sich nicht öffnen.".
Instead of searching the kitchen window, say "Draußen ist es [brightness of day] und es regnet.".


Section Cupboard

The cupboard is a scenery container in the kitchen. The printed name is "Hängeschrank[-s][m]". The description is "Ein Hängeschrank hängt an der Wand.".
Understand "Haengeschrank[m]" as the cupboard.
 

Section Bench

The bench is an enterable scenery supporter in the kitchen. The printed name is "zerkratzt[^] Sitzbank[f]". The description is "In das Holz der Bank hat jemand 'Trink Blut!' eingeritzt.".
Understand "zerkratzt", "Bank[f]", "Holzbank[f]" or "Sitzbank[f]" as the bench.

Does the player mean inserting the player into the bench:
	it is very likely.
	
Report entering the bench:
	say "Du setzt [dich] auf die Bank." instead.
	

Part Cellar

The cellar is a room. The printed name of the cellar is "düster[^] Keller[-s][m]".
"Ein feuchter, düsterer und schmutziger Raum.[if dust is in the cellar coffin] Ein Moderduft schwebt in der staubigen Luft (wahrscheinlich von dem offenen Sarg am Boden ausgehend).[end if] An der Wand hängt ein roh gezimmertes Regal. Daneben ist der Sicherungsschalter angebracht, mit dem der Strom des Hauses [if fuse switch is switched on]aus[else]ein[end if]geschaltet wird. Sonst befind[if the cobwebs are in the cellar]en sich nur noch Spinnweben und [else]et sich nur noch [end if]eine Leiter nach oben im Raum.".
Understand "feucht", "duester", "schmutzig", "Keller[m]" as the cellar.
The cellar is dark.


The cobwebs are a scenery thing in the cellar. The printed name is "Spinnweben[p]". The description of the cobwebs is "Hauchdünne Spinnweben, so fein, dass sie fast gar nicht da sind.".
Understand "Spinnweben[p]", "Spinneweben[p]", "Netz[n]", "Netze[p]", "Spinnennetze[p]", "Spinnennetz[n]" as the cobwebs.

Instead of blowing or pulling or pushing or taking or touching or vacuuming the cobwebs:
	say "Du hast die Spinnweben kaum berührt, da sind sie auch schon in einem Wölkchen dünnen Staubs vergangen.";
	now the cobwebs are nowhere.

Instead of burning the cobwebs:
	say "Du hast die Kerzenflamme den Spinnweben kaum genähert, da sind sie auch schon in einem kleinen Rauchwölkchen vergangen.";
	now the cobwebs are nowhere.

The cellar floor is a scenery supporter in the cellar. The printed name is "Steinboden[-s][m]".
Understand "Boden[m]", "Fussboden[m]", "Steinboden[m]", "Erde[f]" as the cellar floor.

The note is a thing on the cellar floor. The printed name is "klein[^] Notizzettel[-s][m]". The description is "Ein kleiner Notizzettel auf den jemand die Zahl '5873' gekritzelt hat.".
Understand "klein", "Zettel[m]", "Notiz[f]", "Notizzettel[m]", "Kombination[f]", "Safe-Kombination[f]", "Nummer[f]" as the note.

The note unlocks the safe.

To say don't drop note:
	say "Du behältst den Zettel lieber, er könnte noch wichtig sein.".

Instead of dropping the note:
	say "[don't drop note]".

Instead of putting the note on something:
	say "[don't drop note]".

Instead of inserting the note into something:
	say "[don't drop note]".


Instead of smelling in the cellar:
	say "Es riecht modrig.".


Section Cellar Coffin

The cellar coffin is a scenery open lockable container in the cellar. The printed name is "[if dust is in the cellar coffin]staubig[^] [end if]Sarg[-s][m]". The description is "Ein geöffneter[if dust is in the cellar coffin], staubiger[end if] Sarg mit angelehntem Deckel[if cross is part of the cellar coffin], vorne prangt ein hölzernes Kreuz. Den Sarg umgibt eine bedrohliche Aura[end if].".
Understand "bedrohlich", "Sarg[m]", "Deckel[m]", "Aura[f]" as the cellar coffin.
Understand "staubig" as the cellar coffin when the dust is in the cellar coffin.
Understand "offen" or "geoeffnet" as the cellar coffin when the cellar coffin is open.
Understand "geschlossen", "verschlossen" as the cellar coffin when the cellar coffin is closed.

The cross is a part of the cellar coffin. The printed name is "hölzern[^] Kreuz[-es][n]". The description is "Ein einfaches, hölzernes Kreuz mit spitz zulaufenden Enden.".
Understand "einfach", "hoelzern" or "Kreuz[n]" as the cross. 

Dust is a thing in the cellar coffin. The printed name is "fein[^] Staub[-es][m]". The description is "Feiner, pulveriger Staub.".
Understand "fein", "pulverig", "Staub[m]", "Pulver[n]" as dust.

Instead of taking dust:
	say "Der Staub ist zu fein, um ihn zu nehmen.".

Instead of touching dust:
	say "Der Staub fühlt sich ganz weich an.".

Instead of entering the cellar coffin:
	say "Freiwillig gehst [du] da nicht rein.".
	
Instead of closing the cellar coffin:
	say "Am besten hältst [du] [dich] vom Sarg fern.".

Some screws are a plural-named scenery thing. The printed name is "Schrauben[p]". The description is "Die Schrauben halten den Deckel des Sargs.".
Understand "Schraube[f]", "Schrauben[p]", "Scharnier[n]" or "Scharniere[p]" as the screws. 

Instead of taking or turning or pushing or pulling or touching the cross when the cross is part of the cellar coffin:
	now danger is 0;
	now the coffin is closed;
	now the coffin is locked;
	now the screws are part of the cellar coffin;
	now the player carries the cross;
	say "Als [du] das Kreuz greifen willst, stolperst [du] und stürzt in den Sarg. Zu allem Unglück fällt auch noch der Deckel zu[if a candle carried by the player is lit] und [deine] Kerze verlischt[end if].";
	now all candles carried by the player are not lit;
	now the player is in the cellar coffin;
	
Every turn when the player is in the closed cellar coffin:
	increase danger by 1;
	if danger > 1 and the player is not wearing the towel and the dust is in the cellar coffin:
		say "[italic type]Du bist am aufgewirbelten Staub erstickt![roman type][paragraph break]";
		end the story finally saying "Du bist tot";
	else:
		if danger is:
			-- 1: say "[italic type][if dust is in the cellar coffin]Der aufgewirbelte Staub droht [dich] zu ersticken! Du musst [dich] irgendwie vor dem Staub schützen![end if][roman type][paragraph break]";
			-- 2: say "[italic type][if dust is in the cellar coffin]Das Handtuch schützt [dich] vor dem Staub, aber [du][else]Du[end if] musst hier schnellstens raus, bevor die Luft knapp wird![roman type][paragraph break]";
			-- 3: say "[italic type]Die Luft wird knapp![roman type][paragraph break]";
			-- 4: say "[italic type]Die Luft wird knapper!![roman type][paragraph break]";
			-- 5: say "[italic type]Die Luft wird am knappsten!!![roman type][paragraph break]";
			-- otherwise: 
				say "[italic type]Du bist erstickt![roman type][paragraph break]";
				end the story finally saying "Du bist tot".

Visibility rule when in darkness:
	if the player is in the cellar coffin:
		if doing something to the cellar coffin, there is sufficient light; 
		if doing something to dust, there is sufficient light; 
		if doing something to the screws, there is sufficient light;
	else:
		if the player is in the cellar:
			if doing something to the trapdoor, there is sufficient light; 
	there is insufficient light.

After deciding the scope of the player while the location is the cellar and the player is not in the cellar coffin:
   place the trapdoor in scope.

After deciding the scope of the player while the player is in the cellar coffin and dust is in the cellar coffin:
   place the dust in scope.

Instead of examining the cellar coffin when the player is in the cellar coffin:
	say "An den Scharnieren, die den Deckel halten, ertastest [du] ein paar Schrauben.".

Instead of unlocking the cellar coffin with the chisel:
	say "Du versuchst den Meißel zwischen Deckel und Sarg zu klemmen, aber der Meißel ist zu dick.".

Instead of unlocking the cellar coffin with the knife:
	say "Du klemmst das Messer zwischen Deckel und Sarg, kannst den Sarg damit aber nicht aufhebeln.";
	now the knife is in the cellar coffin.

Check pulling the screws when the player is in the cellar coffin:
	if the player carries the screwdriver:
		say "(mit dem Schraubenzieher)";
		try unlocking the cellar coffin with the screwdriver;
	else:
		say "So sehr [du] auch versuchst die Schrauben herauszubekommen, ohne geeignetes Werkzeug schaffst [du] es nicht.";
	stop the action.
 
Understand "dreh [something] ab/auf/raus" as turning when the player is in the cellar coffin.
Understand "schraub [something] ab/auf/raus" as pulling when the player is in the cellar coffin.
Understand "schraube [something] ab/auf/raus" as pulling when the player is in the cellar coffin. [ warum ist das nötig? ]
Understand "schraub [something] mit [dativ] [something] ab/auf/raus" as pulling it with when the player is in the cellar coffin.

Instead of pulling the cellar coffin when the player is in the cellar coffin:
	try pulling the screws.

Instead of pulling the cellar coffin with something (called the tool) when the player is in the cellar coffin:
	try pulling the screws with the tool.

[ GerX: Understand the commands "schraub" and "rotier" as "dreh". Understand "dreh [something] ab/aus" as switching off. ]
Instead of switching off the cellar coffin: 
	try pulling the screws.

Instead of switching off the screws:
	try pulling the screws.
 
Check turning the screws when the player is in the cellar coffin:
	if the player carries the screwdriver:
		say "(mit dem Schraubenzieher)";
		try unlocking the cellar coffin with the screwdriver;
	else:
		say "So sehr [du] auch versuchst die Schrauben herauszudrehen, ohne geeignetes Werkzeug schaffst [du] es nicht.";
	stop the action.
 
Check opening the cellar coffin when the player is in the cellar coffin:
	say "So sehr [du] auch gegen den Deckel drückst, der Sarg lässt sich nicht öffnen." instead.

Report unlocking the cellar coffin with the screwdriver:
	say "Du schraubst die Schrauben mit dem Schraubenzieher heraus und schaffst es schließlich den Deckel beiseite zu drücken. Du steigst aus dem Sarg[if the player wears the towel] und reißt [dir] das Handtuch vom Kopf[end if]. Luft, Luft![paragraph break]";
	say "Als [du] den Sarg verlässt, musst [du] feststellen, dass es immer noch dunkel ist.";
	now the player is in the cellar;
	if the player wears the towel:
		now the player carries the towel;
	now the screws are nowhere;
	stop the action.
	
Report opening the cellar coffin:
	stop the action.


Section Shelf

The shelf is a scenery supporter in the cellar. The printed name is "Holzregal[-s][n]". The description is "Rohe Holzbretter sind als Regal an die Wand geschraubt.".
Understand "roh", "Holzregal[n]", "Wandregal[n]" or "Regal[n]" as the shelf. 

A blood bottle is a kind of thing. The printed name is "[if a blood bottle is known]Blutkonserve[f][else]Konservendose[f][end if]". The printed plural name is "[if a blood bottle is known]Blutkonserven[p][else]Konservendosen[p][end if]". The description is "[if the blood bottle is opened]Eine geöffnete Konservendose voll Blut[else]Eine Konservendose, die laut Etikett 'Blut' enthält[end if].".
Understand "Etikett[n]", "Dosenetikett[n]", "Buechse[f]", "Blechdose[f]", "Dose[f]", "Konserve[f]", "Konservendose[f]" as a blood bottle.
Understand "Blut[n]" or "Blutkonserve[f]" as a blood bottle when a blood bottle is known.
A blood bottle can be unopened or opened. A blood bottle is usually unopened.

On the shelf are three blood bottles.

The chisel is a thing on the shelf. The printed name is "rostig[^] Meißel[-s][m]". The description is "Ein Meißel, an der Spitze sind bräunliche Flecken, wahrscheinlich Rost.".
Understand "rostig", "spitz", "braun", "braeunlich", "Meissel[m]", "Rost[m]" as the chisel.

Instead of taking a blood bottle on the shelf:
	if three blood bottle are on the shelf: 
		continue the action;
	else:
		say "[Ein noun] langt [dir].";

Instead of opening a unopened blood bottle:
	say "Du siehst keine Möglichkeit [den noun] zu öffnen. Wahrscheinlich wirst [du] [ihn] irgendwie aufstemmen müssen.".

Instead of opening an opened blood bottle:
	say "[Der noun] ist schon auf.".

Instead of drinking the unopened blood bottle:
	say "[Der noun] ist noch zu.".

Instead of drinking the opened blood bottle:
	if the coffin key is unknown:
		now the coffin key is known;
		now the player carries the coffin key; 
		say "Du bringst es nicht über [dich] das Blut zu trinken, aber in der Blutkonserve findest [du] einen kleinen Schlüssel, den [du] an [dich] nimmst.";
	else:
		say "Du bringst es nicht über [dich] das Blut zu trinken.".

Carry out examining the opened blood bottle:
	if the coffin key is unknown:
		now the coffin key is known;
		now the player carries the coffin key; 
		say "In der Blutkonserve findest [du] einen kleinen Schlüssel, den [du] mitnimmst." instead.

To say no mess:
	say "Nein, [du] möchtest keine Sauerei machen".
	
Instead of emptying a blood bottle (called the bottle):
	if the bottle is opened:
		if coffin key is unknown:
			say "[no mess]. [run paragraph on]";
			try examining the bottle instead;
		else:
			say "[no mess].";
	else:
		say "[Der bottle] scheint dicht zu sein, es kommt nichts heraus.".

Before putting an opened blood bottle (called the bottle) on something (called the item):
	if the item is the pile of ash:
		continue the action;
	if the item is a supporter:
		continue the action;
	else:
		if coffin key is unknown:
			say "[no mess]. [run paragraph on]";
			try examining the bottle instead;
		else:
			say "[no mess]." instead;


The coffin key is a thing. The printed name is "klein[^] Schlüssel[-s][m]". The description is "Ein kleiner Schlüssel.".
Understand "klein", "Schluessel[m]", "Sargschluessel[m]" as the coffin key.

The coffin key unlocks the tower coffin.

Does the player mean unlocking the tower coffin with the coffin key:
	it is very likely.


Section Fuse switch

The fuse switch is a scenery device in the cellar. The printed name is "Sicherungsschalter[-s][m]". The description is "Der Sicherungsschalter schaltet den Strom für die Wohnung ein oder aus.".
Understand "Knopf[m]", "Schalter[m]", "Sicherung[f]", "Sicherungsschalter[m]", "Strom[m]", "Stromschalter[m]" as the fuse switch.
The fuse switch is fixed in place.
The fuse switch is switched off.

Carry out switching off the fuse switch:
	now the fan is switched off.

Switching is an action applying to one thing.
Understand the command "schalt" as something new.
Understand "schalt [something switchable]" as switching.
Understand "schalt [something switchable] um" as switching.
Understand "leg [something switchable] um" as switching.
Understand "schalt [something switchable] an/ein" as switching on.
Understand "schalt [something switchable] ab/aus" as switching off.
Understand "schalt [something]" as switching.
Understand "schalt [something] an/ein" as switching on.
Understand "schalt [something] ab/aus" as switching off.

Check an actor switching (this is the can't switch unless switchable rule):
	if the noun provides the property switched on, continue the action;
	if the actor is the player:
		say "Du kannst [den noun] nicht ein- oder ausschalten." (A);
	stop the action.

Carry out an actor switching:
	if the noun is switched on:
		try switching off the noun instead;
	if the noun is switched off:
		try switching on the noun instead;

Instead of pushing something switchable (called the item):
	try switching the item.



Part Lavatory

The lavatory is a room. The printed name is "stinkend[^] Toilette[f]".
"[if the toilet is smelly]Ein fürchterlicher Gestank empfängt [dich], von der schlechten Spülung des WC's zeugend. [end if]Über dem WC hängt
ein [if the fan is switched on]ein[else]aus[end if]geschalteter, altersschwacher Ventilator[if fan is switched off], der durch einen Knopf in Betrieb gesetzt wird[end if]. Neben der Toilette befindet sich ein marmornes Waschbecken, über dem ein halbblinder Spiegel sein klägliches Dasein fristet. Nach Süden gelangst [du] wieder in den Wohnraum.".
Understand "Bad[n]", "Badezimmer[n]" as the lavatory.

The lavatory floor is a scenery supporter in the lavatory. The printed name is "gefliest[^] Boden[-s][m]".
Understand "gefliest", "Boden[m]", "Badboden[m]", "WC-Boden[m]", "Fussboden[m]", "Fliese[f]", "Fliesen[p]" as the lavatory floor.

The lavatory is smelly.

Does the player mean doing something with the wc door:
	it is unlikely.

Does the player mean doing something with the lavatory:
	it is unlikely.

Instead of smelling in the lavatory:
	if the lavatory is smelly:
		say "Es stinkt furchtbar.";
	else:
		say "Es stinkt immer noch, aber es ist kein Vergleich zu dem Gestank, bevor [du] den Ventilator eingeschaltet hast.".

After going to the lavatory:
	now the danger is 0;
	continue the action.

Every turn when the player is in the lavatory and the lavatory is smelly:
	if the player is not wearing the towel:
		increase danger by 1;	
	if danger is:
		-- 1: say "[italic type]Es stinkt fürchterlich![roman type][paragraph break]";
		-- 2: say "[italic type]Der Gestank ist nicht auszuhalten![roman type][paragraph break]";
		-- 3: say "[italic type]Dieser Gestank! Vor [deinen] Augen beginnen leuchtende Punkte zu tanzen. Du brauchst unbedingt frische Luft![roman type][paragraph break]";
		-- otherwise: 
			say "[italic type]Du bist erstunken![roman type][paragraph break]";
			end the story finally saying "Du bist tot".

Section Fan
	
The fan is a scenery device in the lavatory. The printed name is "altersschwach[^] Deckenventilator[-s][m]". The description is "[if the player is on the toilet]Hinter dem Ventilator entdeckst [du] eine Öffnung, in der die Diamanten stecken[else]Ein altersschwacher Deckenventilator[end if]."
Understand "altersschwach", "Ventilator[m]", "Luefter[m]", "Geblaese[n]", "Knopf[m]", "Schalter[m]", "Taste[f]", "Taster[m]" or "Druckschalter[m]" as the fan.
Understand "Oeffnung[f]", "Diamant[m]", "Diamanten[p]", "Steine[p]", "Edelsteine[p]" or "Klunker[p]" as the fan when the player is on the toilet.

Check switching on the fan:
	if the fuse switch is switched off:
		say "Der Strom scheint abgestellt zu sein." instead.

Carry out switching on the fan:
	now the lavatory is fresh;
	now the printed name of the lavatory is "Toilette[f]";
	continue the action.

Report switching on the fan for the first time:
	say "Du schaltest den altersschwachen Deckenventilator ein und der Gestank verzieht sich!" instead.

Instead of unlocking the fan with something:
	try opening the fan.

Instead of taking the fan when the player is on the toilet:
	say "Du hast die Diamanten gefunden. Damit hast [du] bewiesen, dass [du] der beste lebende Detektiv bist!";
	end the story finally saying "Du hast gewonnen!";	


Section Towel

The towel is a wearable thing in the lavatory. The printed name is "weich[^] Handtuch[-s][n]". The description is "Ein weiches Handtuch mit dem Monogramm 'GD'.".
The initial appearance is "An der Wand hängt ein weiches Handtuch mit Monogramm.".
Understand "weich", "Monogramm[n]", "Handtuch[n]", "Tuch[n]" as the towel.

Report wearing the towel:
	say "Du bindest [dir] das Handtuch fest um den Kopf, so dass Mund und Nase bedeckt sind.";
	the towel becomes uncomfortable in five turns from now;
	stop the action.
	
At the time when the towel becomes uncomfortable:
	if the player wears the towel:
		try taking off the towel.

Report taking off the towel:
	say "Du hältst es nicht mehr aus und reißt [dir] das Handtuch vom Kopf. Luft, Luft!" instead.


Section Mirror

The mirror is a scenery thing in the lavatory. The printed name is "halbblind[^] Spiegel[-s][m]". The description is "In dem halbblinden Spiegel siehst Du ein verängstigtes Gesicht - Moment, das bist [du] ja selbst.".
Understand "halbblind", "Spiegel", "Wandspiegel", "WC-Spiegel" or "Badezimmerspiegel" as the mirror.


Section Basin

The basin is a scenery thing in the lavatory. The printed name is "marmorn[^] Waschbecken[-s][n]". The description is "In den Schmutz des Waschbeckens hat jemand 'Im Blut liegt der Schlüssel' geschrieben. Was das wohl heißen soll?".
Understand "marmorn", "schmutzig", "Schmutz[m]", "Marmor[m]", "Waschbecken[n]", "Handwaschbecken[n]" as the basin.
Understand "Wasser[n]", "Wasserhahn[m]", "Wasserkran[m]", "Hahn[m]", "Kran[m]" as the basin.

Instead of switching on the basin:
	say "[no-water]".

Instead of turning the basin:
	say "[no-water]".


Section Toilet

The toilet is a scenery enterable supporter in the lavatory. The printed name is "Toilette[f]". The description is "Eine nicht unbedingt saubere Toilette. Genauer willst [du] [dir] das gar nicht anschauen.".
Understand "Toilette[f]", "Klosett[n]", "WC[n]", "Klo[n]" as the toilet.

Understand "greif in [something]" as searching.

Instead of searching the toilet:
	try opening the toilet instead.
 
Instead of opening the toilet, say "Du öffnest den Toilettendeckel und schließt ihn schnell wieder. Über das was [du] gesehen hast, willst [du] nicht weiter nachdenken.".

To say no-water-toilet:
	say "Du spülst kurz ab, aber es scheint kaum Wasser zu fließen." instead.

Instead of switching on the toilet:
	say "[no-water-toilet]".

Understand "drueck [something] ab" as pushing.
Understand the command "spuel" as "drueck".

Rule for supplying a missing noun while pushing:
	if the location is the lavatory:
		now the noun is the toilet.
		
Instead of pushing the toilet:
	say "[no-water-toilet]".

Check entering the toilet:
	if the board is on the toilet:
		if the fan is switched on:
			say "Du steigst auf die Toilette, kommst dem laufenden Ventilator zu nahe und verlierst den Kopf (wörtlich gemeint).";
			end the story finally saying "Du bist tot";
		else:
			continue the action;
	else:
		say "Du steigst auf den Toilettendeckel. Plötzlich brichst [du] durch, verlierst den Halt und schlägst mit dem Kopf voll gegen die Wand.";
		end the story finally saying "Du bist tot".

Report entering the toilet:
	say "Du kletterst auf das Brett. Hinter dem Ventilator scheint eine Öffnung zu sein." instead.

Instead of taking the board when the player is on the toilet:
	say "Du kannst nicht das Brett nehmen, auf dem [du] stehst.".
	

Section Hook

The hook is a thing in the lavatory. The printed name is "Ziehhaken[-s][m]". The description is "Ein ca. 1m langer Stock mit einem Haken am Ende, wie man ihn benutzt, um beispielsweise eine Leiter zum Dachboden herunterzuziehen.".
The initial appearance is "Hinter der Toilette lehnt ein Ziehhaken an der Wand.".
Understand "Ziehhaken[m]" , "Haken[m]", "Stock[m]", "Zugstock[m]", "Stockhaken[m]" as the hook.



Part Tower Room

The tower room is a room. The printed name is "Turmzimmer[-s][n]".
"Ein Zeichen nostalgischer Gefühle des Bewohners: ein kühler, hoher, runder Raum, dessen Mauer
aus groben Steinen gefügt ist. [if the cavity is in the tower room]Wo der abgegriffene Stein war, ist eine Höhlung in der Wand, der Stein liegt davor auf dem Boden[else]Ein Stein ist ziemlich abgegriffen und steht etwas vor[end if]. Ein winziges Fenster wirft ein düsteres Licht über einen [if tower coffin is closed]verschlossenen[else]geöffneten[end if], prunkvollen Sarg auf dem staubigen Boden. Im Osten führt die Turmtreppe nach unten.".
Understand "kuehl", "hoch", "rund", "Turmzimmer[n]", "Turm[m]", "Zimmer[n]", "Mauer[n]" as the tower room.

The tower room window is scenery in the tower room. The printed name is "klein[^] Fenster[-s][n]". The description is "Ein kleines Fenster ist in die Mauer eingelassen. Draußen ist es [brightness of day] und es regnet.".
Understand "Fenster[n]", "Scheibe[f]" as the tower room window.

The tower room floor is scenery supporter in the tower room. The printed name is "staubig[^] Steinboden[-s][m]". The description is "In den Staub auf dem Boden hat jemand 'Hinter Moderner Kunst verbirgt sich oft wertvolles' gekritzelt."
Understand "staubig", "Staub[m]", "Boden[m]", "Fussboden[m]", "Steinboden[m]" as the tower room floor.


Report going from the tower room to the kitchen:
	say "Du steigst die Turmtreppe hinab.".
		
Instead of going down in the tower room:
	try entering the tower door instead.

Instead of going east in the tower room:
	try going south instead.


Section Tower coffin

The tower coffin is a scenery closed openable enterable locked container in the tower room. The printed name is "prunkvoll[^] Sarg[-s][m]". The description is "Ein prunkvoll verzierter Sarg mit einem ebensolchen Schloss.".
Understand "prunkvoll", "verziert", "Sarg[m]", "Schloss[n]" as the tower coffin.
Understand "offen" or "geoeffnet" as the tower coffin when the tower coffin is open.
Understand "geschlossen" or "verschlossen" as the tower coffin when the tower coffin is closed.

The pliers is a thing. The printed name is "rostig[^] Beißzange[f]". The description is "Eine rostige Beißzange.".
Understand "rostig", "Zange[f]", "Beisszange[f]", "Kneifzange[f]" as the pliers.
	
The count is a man in the tower coffin. The printed name is "Graf[-en] Drakula[m]". The description is "Der Graf höchstselbst.".
Understand "Graf[m]", "Drakula[m]" , "Dracula[m]" as the count. [ falls jemand die "richtige" Schreibweise tippt ]
The special indefinite article of the count is definite article.

A pile of ash is a thing. The printed name is "Häufchen Asche[n]". The description is "Ein kleines Häufchen Asche - RIP Graf Drakula.".
Understand "klein", "Haeufchen[n]", "Haufen[m]", "Asche[f]", "Graf[m]" or "Drakula[m]" as the pile of ash.
The ash pile is fixed in place.

Instead of closing the open tower coffin when the count is in the tower coffin:
	say "Solange der Graf im Weg ist, kannst [du] den Sarg nicht schließen.".

Instead of going when the count is in the open tower coffin:
	say "Der Blick des Grafen schlägt [dich] so in Bann, dass [du] [dich] nicht von der Stelle rühren kannst.".

Instead of giving a blood bottle to the count:
	say "Der Graf sagt: 'Danke, jetzt nicht. Vielleicht als Nachtisch, wenn ich nach [dir] noch Appetit habe.'".

The block showing rule is not listed in any rulebook.

Check showing something (called the item) to someone (called the person):
	if the item is the cross and the person is the count:
		continue the action;
	else:
		say "[Der second noun] [ist] nicht beeindruckt." instead.

Carry out opening the tower coffin when the count is in the tower coffin:
	now danger is 0;

Report opening the tower coffin when the count is in the tower coffin:
	say "[Count arrives]" instead.

Every turn when the player is in the tower room and the count is in the open tower coffin:
	if the player does not carry a lit candle:
		say "[italic type]In der Düsternis des Turmzimmers ist [dir] der Graf haushoch überlegen. Er beißt [dich] und schlürft [dich] genüsslich aus![roman type][paragraph break]";
		end the story finally saying "Du bist tot";
	else:
		increase danger by 1;
		if danger is:
			-- 1: say "[italic type]Der Graf schaut [dich] schlaftrunken an![roman type][paragraph break]";
			-- 2: say "[italic type]Der Graf scheint langsam zu sich zu kommen![roman type][paragraph break]";
			-- 3: say "[italic type]Der Graf bekommt [dich] zu fassen und zieht [dich] zu sich![roman type][paragraph break]";
			-- otherwise: 
				say "[italic type]Der Graf beißt [dich] und schlürft [dich] genüsslich aus![roman type][paragraph break]";
				end the story finally saying "Du bist tot".

Carry out showing the cross to the count:
	say "[Count leaves]".

Instead of protecting yourself with the cross:
	say "[Count leaves]".

Instead of attacking the count:
	say "Mit bloßen Händen?".
	
Instead of attacking the count with the cross:
	say "[Count leaves]".

Instead of throwing the cross at the count:
	say "[Count leaves]".

To say Count is unimpressed:
	say "Der Graf zuck zusammen, scheint aber nicht verletzt sein. Siedend heiß fällt [dir] ein, dass man einen Holzpflock braucht um einem Vampir unschädlich zu machen.".

Instead of attacking the count with the chisel:
	say "[Count is unimpressed]".

Instead of attacking the count with the knife:
	say "[Count is unimpressed]".

Instead of attacking the count with the leg of lamb:
	say "[Count is unimpressed]".

Instead of throwing the chisel at the count:
	say "[Count is unimpressed]".


Understand "wend [someone] mit [dativ] [something preferably held] ab" as attacking it with.
Understand "bann [someone] mit [dativ] [something preferably held]" as attacking it with.
Understand the commands "erstich", "erstech" as "toet".

Arresting is an action applying to one thing.

Understand "verhaft [someone]" as arresting.
Understand "greif [someone]" as arresting. ["fass" und "ergreif"]

Understand the commands "arretier", "fang", "inhaftier", "schnapp", "verhoer", "vernimm" as "verhaft".

Understand "bucht [someone] ein" as arresting.
Understand the commands "kassier", "kerker" as "bucht".

Understand "mach [someone] dingfest" as arresting.
Understand "nimm [someone] fest" as arresting.
Understand "nimm [someone] gefangen" as arresting.
Understand "nimm [someone] in Gewahrsam" as arresting.
Understand "nimm [someone] in Haft" as arresting.

Check arresting:
	if the noun is not the count:
		say "Das bringt nichts.";
		stop the action.

Instead of arresting the count:
 	say "[one of]Der Graf meint ironisch 'Du - und welche Armee?'.[or]Der Graf sagt 'Das ist der Moment in dem [du] weglaufen müsstest!'.[or]Spöttisch lächelnd entblößt der Graf seine Beißzähne.[then at random]".


Instead of taking or touching the pile of ash:
	say "Die feine Asche gleitet [dir] durch die Finger.".

Emptying is an action applying to one thing.
Understand "giess [something preferably held]" as emptying.
Understand "giess [something preferably held] aus" as emptying.

Understand "giess [things preferably held] auf [something] [darauf]" as putting it on.
Understand the commands "begieß", "bespreng", "kipp", "leer", "schuett", "traeufel", "troepfel" , "troepfl", "tropf" as "giess".

Instead of putting a blood bottle on the pile of ash:
	say "Du willst das Blut gerade auf die Asche tun, als [dir] klar wird, dass es eine ziemlich blöde Idee wäre den Grafen wiederzubeleben. Du kannst heilfroh sein, dass es [dir] einmal gelungen ist ihn zu überwinden.".
	

Section Stone

The stone is a scenery thing in the tower room. The printed name is "abgegriffen[^] Stein[-es][m]". The description is "[if the cavity is in the tower room]Der abgegriffene Stein liegt auf dem Boden.[else]Der Stein steht etwas vor und ist abgegriffen, so als wäre er oft angefasst worden, trotzdem scheint er fest verfugt zu sein.[end if]".
Understand "abgegriffen", "glatt", "schwer", "Stein[m]", "Mauerstein[m]" as the stone.
Understand "verfugt", "Fuge[f]", "Mauerfuge[f]" as the stone when the cavity is not in the tower room.
Understand "vorstehend" as the stone when the cavity is not in the tower room.

The stone can be fixed or loose. The stone is fixed.

Instead of turning the stone:
	try taking the stone.

Instead of inserting something (called the tool) into the stone:
	if the cavity is in the tower room:
		say "Der Stein ist kein Behälter.";
	else:
		try pulling the stone with the tool.

Instead of touching the stone:
	say "Der Stein ist ganz glatt und abgegriffen[if the cavity is not in the tower room]. Dadurch ist es schwer ihn zu fassen[end if].".
	
Instead of pushing the stone when the cavity is not in the tower room:
	say "Den Stein weiter in die Wand zu drücken wird nichts bringen.".
	
Instead of pulling or taking the stone when the cavity is not in the tower room:
	say "Der Stein sitzt zu fest. Du wirst ein Werkzeug brauchen um ihn zu lockern.".

Instead of pulling or pushing or taking the stone when the cavity is in the tower room:
	say "Der Stein ist zu schwer.".

The cavity is a scenery open container. The printed name is "dunkl[^] Höhlung[f]". The description is "An der Stelle, an der der Mauerstein war, ist nun eine dunkle Höhlung.".
Understand "dunkel", "Hoehlung[f]", "Aushoehlung[f]", "Hoehle[f]", "Hohlraum[m]" or "Loch[n]" as the cavity.

The screwdriver is a thing in the cavity. The printed name is "Schraubenzieher[-s][m]". The description is "Ein Schraubenzieher für kleine Kreuzschlitzschrauben.".
Understand "Schraubenzieher[m]", "Schraubendreher[m]", "Schrauber[m]" as the screwdriver.
The screwdriver unlocks the cellar coffin.


Part Tests

Test toilet with "purloin kerze / purloin streichhölzer / zünd kerze an / purloin haken / runter / drück sicherungsschalter / hoch / norden / drück schalter / purloin brett / leg brett auf toilette".

Test stone with "x teppich / purloin kerze / purloin streichhölzer / zünd kerze an / purloin haken / w / schliess tür mit schlüssel auf / w".

Test cellar with "x Tisch / nimm das Blatt / x Teppich / kletter auf den Tisch / nimm die Kerze / steig vom Tisch / zieh am Vorhang / W / öffne den Kühlschrank / nimm die Lammkeule / öffne die Spüle / nimm die Streichhölzer / schließ die Spüle / x Herd / nimm das Messer / schließ die Tür mit dem Schlüssel auf / öffne die Tür / W / x Boden / lockere den Stein mit dem Messer / x Höhlung / nimm den Schraubenzieher / O / O / zünde die Kerze an / N / nimm den Haken / nimm das Handtuch / S / öffne die Falltür mit dem Haken / runter".

Test stein with "x Tisch / nimm das Blatt / x Teppich / nimm den Schlüssel / kletter auf den Tisch / nimm die Kerze / steig vom Tisch / zieh am Vorhang / W / öffne den Kühlschrank / nimm die Lammkeule / öffne die Spüle / nimm die Streichhölzer / schließ die Spüle / x Herd / nimm das Messer / schließ die Tür mit dem Schlüssel auf / öffne die Tür / W / x Boden".

Test sarg with "x Tisch / nimm das Blatt / x Teppich / nimm den Schlüssel / kletter auf den Tisch / nimm die Kerze / steig vom Tisch / zieh am Vorhang / W / öffne den Kühlschrank / nimm die Lammkeule / öffne die Spüle / nimm die Streichhölzer / schließ die Spüle / x Herd / nimm das Messer / schließ die Tür mit dem Schlüssel auf / öffne die Tür / W / x Boden / lockere den Stein mit dem Messer / x Höhlung / nimm den Schraubenzieher / S / S / zünde die Kerze an / N / nimm den Haken / S / öffne die Falltür mit dem Haken / runter / drück den Knopf / x Boden / nimm den Zettel / lies den Zettel / x Regal / nimm den Meissel / nimm eine Dose / öffne die Dose / stemm die Dose mit dem Meißel auf / trink das Blut / hoch / N / drück den Knopf / nimm das Handtuch / S / runter / x Sarg / nimm das Kreuz / binde das Handtuch um deinen Kopf / löse die Schrauben mit dem Schraubenzieher / zünde die Kerze an / H / W / W / schließ den Sarg mit dem kleinen Schlüssel auf".

Test me with "x Tisch / nimm das Blatt / x Teppich / kletter auf den Tisch / nimm die Kerze / steig vom Tisch / zieh am Vorhang / W / öffne den Kühlschrank / nimm die Lammkeule / öffne die Spüle / nimm die Streichhölzer / schließ die Spüle / x Herd / nimm das Messer / schließ die Tür mit dem Schlüssel auf / öffne die Tür / W / x Boden / lockere den Stein mit dem Messer / x Höhlung / nimm den Schraubenzieher / O / O / zünde die Kerze an / N / nimm den Ziehhaken / nimm das Handtuch / S / öffne die Falltür mit dem Ziehhaken / runter / drück den Knopf / x Boden / nimm den Zettel / lies den Zettel / x Regal / nimm den Meissel / nimm eine Dose / öffne die Dose / stemm die Dose mit dem Meißel auf / trink das Blut / x Sarg / nimm das Kreuz / binde das Handtuch um deinen Kopf / löse die Schrauben mit dem Schraubenzieher / zünde die Kerze an / H / W / W / schließ den Sarg mit dem kleinen Schlüssel auf / öffne den Sarg / zeig das Kreuz / x Sarg / nimm die Zange / O / O / zieh die Nägel mit der Zange heraus / schliess den Tresor mit der Kombination auf / öffne den Tresor / nimm das Brett / N / drück den Knopf / leg das Brett auf die Toilette / drück den Knopf / kletter auf das Brett / x Ventilator / nimm die Diamanten".
