| ### Las Reliquias de Tolti Aph ### An interactive fiction by Graham Nelson (2005) - the Inform 7 source text
Home page Contents Previous Next Complete text | Section O(e) - La Buhardilla y el Archivero The agujero is an open unopenable door. It is scenery. Understand "abertura" or "abertura circular" as the agujero. It is above the Habitación Anudada and below the Oscura Buhardilla. The printed name of Oscura Buhardilla is "[if the archivero is lit and the archivero is in location]Luminosa[otherwise]Oscura[end if] Buhardilla". Instead of searching the agujero in the Buhardilla: say "Miras hacia la habitación de abajo esperando que tu improvisada escala aguante para el viaje de vuelta." Instead of searching the agujero in the Habitación Anudada: if a lit thing is in the Buhardilla, say "A través del agujero puedes ver una luz blanca y extrañas sombras, pero no alcanzas a distinguir nada más."; otherwise say "Parece que está oscuro." The description of the Oscura Buhardilla is "Una habitación circular[if the archivero is in location and archivero is lit], sucia por el tiempo[otherwise], muy mal iluminada[end if], con un agujero en el suelo que comunica con la habitación de abajo." The casillero is fixed in place in the Oscura Buhardilla. "[if fixed in place]Un casillero vacío, hecho de madera podrida, reposa sobre una de las paredes; debió contener hace mucho hebras de distinto color y grosor[otherwise]En el suelo hay una especie de cajón hecho de madera podrida[end if]." It is a container. Understand "casillero" or "cajon" as the casillero. The casillero is madera. Instead of attacking the fixed in place casillero: now the casillero is portable; change the printed name of the casillero to "cajón de madera podrida"; say "Golpeas el casillero, el cual cae de la pared a trozos, dejándote con una especie de cajón hecho de madera podrida." Instead of attacking the portable casillero: say "¿No has tenido suficiente?" Instead of casting remendar at the portable casillero when the casillero are not in the location: say "Para remendarlo apropiadamente, debe dejarse en el suelo de la habitación, ya que aparenta ser mobiliario." Effect of casting remendar at the portable casillero: now the casillero is fixed in place; change the printed name of the casillero to "casillero"; record outcome "recomponiéndose en un desvencijado pero funcional contenedor"; rule succeeds; The archivero is a clérigo in the Oscura Buhardilla. It is indifferent. The archivero can be active or passive. "Agachado en cuclillas en el centro de la habitación, rodeado por filamentos de diferentes tamaños y colores, hay un archivero[if lit]. Él brilla con luz mágica[end if]." The description is "Es muy delgado, como si se hubiese preservado por desecación. Lleva unos pequeños anteojos redondos[if lit]. Además él brilla con una trémula luz blanca[end if]." Instead of going to the Buhardilla when the player knows luz mágica and the archivero is unlit for the first time: say "Dudas, pues después de todo, el viejo lunático se habrá apagado como una lámpara vieja, y si asomas la cabeza tendrás que reiluminarle otra vez." Instead of attacking the archivero: say "Te lanzas sobre él, pero no consigues hacer contacto. 'Ah,' dice, 'has venido demasiado tarde para matarme, me temo.'" Instead of going to a room in the presence of the unlit archivero when the player knows luz mágica: say "El archivero te detiene con una señal que hace vibrar el aire[if the archivero is affected by silencio]. Aparentemente no te está permitido abandonar la habitación hasta que hayas completado tu parte del trato[otherwise]. 'No hasta que me hayas conseguido algo de luz; ese es nuestro pacto,' dice[end if]." Every turn: repeat through the Table of Enchantments begin; if the duration timer entry < 1, now the archivero is not affected by the spell entry; end repeat; if the archivero is not affected by luz mágica, now the archivero is unlit. Report casting in the presence of the archivero: say "Mientras entonas las palabras del hechizo [italic type][spell understood][roman type], "; if the current spell focus is something begin; say "[the current spell focus] "; if the player is not holding the current spell focus, say "desaparece mientras "; say "proyecta "; otherwise; say "tus dedos proyectan "; end if; say emission of the spell understood; if the second noun is not a room, say " al [the second noun]"; say ", [current spell outcome]"; if the archivero is affected by the spell understood begin; if duration of the spell understood is greater than 0 begin; say ", que durará por [duration of the spell understood in words] turno[s]"; change the duration timer of the spell understood to the duration of the spell understood; increase the duration timer of the spell understood by 1; end if; end if; say "."; consider the current spell event; now the archivero is passive; stop the action. Effect of casting filtrar mente at the archivero: record outcome "pero sus ojos se alzan para sostener tu mirada [if archivero is affected by silencio]Él sonríe y sacude la cabeza, y ahora sabes que involuntariamente le has dejado echar un vistazo a tu propia historia[otherwise]Él sonríe. 'Yo no lo haría,' te previene, en el dialecto de tu ciudad natal[end if]"; rule succeeds. Effect of casting telaraña at the archivero: record outcome "pero las hebras se enrollan en tus propios brazos, dejándote quieto en el sitio, y luego se disuelven ante un gesto del clérigo"; rule succeeds. Effect of casting misil mágico at the archivero: record outcome "pero el fuego parece girar y tratar de engullirte en vez de a él. Sólo que en el último momento un movimiento de su mano hace desaparecer la bola de fuego con un sonoro ¡pop!"; rule succeeds. Effect of casting remendar at the archivero: restore the health of the player; record outcome "pero el hechizo se refleja e impacta sobre ti, restaurando tu propia fuerza. [if archivero is affected by silencio]La boca del archivero se abre con una carcajada que no puedes oir[otherwise]El archivero se ríe, una carcajada agradable y alegre. 'Tienes potencial. Casi desearía poder tener un aprendiz,' agrega[end if]"; rule succeeds. Effect of casting silencio at in the presence of the archivero: record outcome "se aposenta alrededor del archivero, el cual hace un comentario que eres incapaz de oir"; now the archivero is affected by silencio; rule succeeds. Effect of casting escudo aéreo at in the presence of the archivero: now the archivero is affected by escudo aéreo; record outcome "creando un escudo de protección sobre el archivero"; rule succeeds. Effect of casting luz mágica at in the presence of the archivero: now the archivero is affected by luz mágica; now the archivero is lit; record outcome "iluminando al archivero"; rule succeeds. Effect of casting curar calvicie at the archivero: record outcome "pero el hechizo rebota y te golpea. [if archivero is affected by silencio]El archivero sonríe silencionsamente[otherwise]'Si me permites una opinión informada por la moda de hace cientos de años - los bucles no te sientan nada bien,' remarca el archivero[end if]"; rule succeeds. Instead of casting memorizar at in the presence of the archivero: say "El archivero levanta una mano[if the archivero is affected by silencio]. Y señala a su frente a modo de advertencia[otherwise]. 'No, a menos que quieras que sea yo quien aprenda el hechizo,' te advierte[end if]." Instead of giving something to the archivero: say "Le ofreces [the noun], pero cuando el archivero lo alcanza sus dedos traspasan los tuyos sin dejarte el escalofrío que produce el toque de un fantasma." Instead of showing a display listed in the Table of archivero Reactions to the archivero: if the archivero is affected by silencio, say "Se encoje de hombros y señala su boca silenciada."; say "[reaction entry][paragraph break]". Instead of showing or giving the cuerda profusamente anudada to the archivero: remove the cuerda profusamente anudada from play; now the player knows luz mágica; say "El archivero se inclina más cerca, murmurando para si mismo mientras interpreta el hechizo y lo confía a la memoria - a tu memoria, eso es." The cuerda profusamente anudada is a thing. The description is "Presumes que es el equivalente a un pergamino, conteniendo algún encantamiento de luz." The cuerda profusamente anudada is female. Table of archivero Reactions
display | reaction
pergamino alargado | "Él lee a través de sus anteojos. 'No parece completamente inútil, creo,' comenta."
pergamino en blanco | "'Estoy sorprendido de que nadie haya escrito todavía sobre una superficie tan prometedora,' dice."
diario en cursiva | "'Ah, que pena,' dice. 'Ella tenía coraje, pero el coraje por si sólo no siempre es suficiente.'"
Every turn: if the player can see the archivero and the archivero is active begin; if the archivero is affected by silencio begin; say "El archivero continúa trabajando, pero no puedes escuchar en él ningún movimiento."; otherwise; if the archivero is lit begin; say "El archivero trabaja ligero sobre sus hebras, comparando colores."; otherwise; repeat through Table of archivero Chatter begin; say "[reaction entry][paragraph break]"; blank out the whole row; stop the action; end repeat; say "El archivero mueve sus dedos vigorosamente sobre las hebras, anudando aquí y allá."; end if; end if; otherwise; now the archivero is active; end if. Instead of asking the archivero about a topic listed in the Table of archivero Chatter: if the archivero is affected by silencio, say "Él señala a su garganta silenciada." instead; now the archivero is passive; say "[reaction entry][paragraph break]"; blank out the whole row. Instead of asking the archivero about something, say "'¿Qué? ¿Cómo? Bah, no hablas más que tonterías,' dice el archivero." Instead of answering the archivero that something: try asking the archivero about it. Instead of telling the archivero about something: try asking the archivero about it. Table of archivero Chatter
topic | reaction
"hi/hey/hola/salud/saludos/nas" | "'Tu otra vez,' remarca el archivero sin siquiera mirarte. '¿O es tu primera vez? Bueno, no importa.'"
"tiempo/edad/temporal/reflejo" | "'El hechizo temporal consume toda mi fuerza,' dice. 'Yo lo mantengo a él, él me mantiene a mi, todo el mundo contento.'"
"hechizo temporal/hechizo/conjuro/tiempo/pergamino/temporal/edad/infinito/eternidad" | "El archivero saca un pergamino peculiar, con la parte de arriba cosida a la de abajo y girado de forma que no tiene ni principio ni fin, pero cuando alargas la mano tus dedos lo atraviesan. Él se lo guarda de nuevo en sus ropajes. [paragraph break]'No para ti,' dice. 'Permite hacer cosas y deshacerlas, ir hacia adelante, ir hacia atrás... Esta clase de poder no es algo que se supone debamos descubrir, creo yo.'[paragraph break]Entonces frunce el ceño, arrepintiéndose de la revelación que acaba de hacer. Luego hay una especie de pegajoso POP en el aire alrededor de tu cabeza, y te olvidas -[line break]"
"tarea/trabajo/nudos/nudo/hebras/hilo/cuerda/cuerdas/archivo/archivos/archivero" | "'Ya sabes,' dice el archivero, mirándote por encima de sus anteojos. 'Esta tarea sería más sencilla con algo más de luz. Cada hebra tiene colores además de los nudos.'"
"significado/proposito/tema/hebra/hilo/cuerda/cuerdas/nudos/nudo/archivo/archivos" | "'Todo el día y noche contando y comparando,' murmura, más para si mismo que para ti. 'Comparando y contando. Bueno, a veces salgo ahí afuera y practico algo de tiro al arco. ¿Sabías que una buena flecha con suficiente altura puede incluso alcanzar la vieja torre del Gran Muro? ¡Pero a seguir contando! Ese es el espíritu.'"
"luz/hechizo de luz/conjuro de luz" | "'Haría yo mismo el conjuro de luz, pero no tengo la fuerza necesaria, menos aún la madera.'"
"luz/hechizo de luz/conjuro de luz" | "'Tú mismo podrías hacerlo, por supuesto,' dice. 'Aprender el conjuro de luz, lanzarlo por mi. Puedes quedártelo después, si quieres. En tu cabeza. Un pago mental, ¿qué te parece?' Él mueve su cabeza de un lado a otro, como un pajarillo '¿Sí?'"
"luz/hechizo de luz/conjuro de luz/conjuro/hechizo" | "Él selecciona una nueva hebra y comienza a anudarla cuidadosamente, contando, murmurando. No puedes escuchar qué palabras. [string placement] "
"oscuridad/oscuro" | "[if archivero is lit]El archivero sonríe. [otherwise]El archivero continúa trabajando, entornando los ojos sobre las hebras y maldiciendo la oscuridad. [end if]"
"ayuda/ayudar" | "[if archivero is lit]'No creas que no te estoy agradecido,' he says. 'Pero es que tengo que trabajar mientras el hechizo aguante.' [otherwise]'Podrías ayudar si quisieses,' dice, 'sino, preferiría que te largaras.' Y firma esto con una mirada incisiva. [end if]"
"agua/diosa" | "[if archivero is lit]El archivero observa con claridad una hebra: 'No sé si la diosa vive aún,' dice. 'Quizás tan sólo se ha mudado de lugar.' [otherwise]El archivero entorna los ojos sobre su hebra, murmurando: 'Agua, ¿agua como líquido? ¿o la diosa? Difícil de decir sin los colores... ¿Dirías que esto es azul ¿o verde? No, no serías capaz de adivinarlo mejor que yo.' [end if]"
"agua/diosa/azul/verde" | "[if archivero is lit]'El gris verdoso es su color, si es que quieres encontrar a la diosa en las hebras.' Pero por supuesto no serías capaz de obtener ningún significado de ellas. [otherwise]'Debieron dejar una lámpara aquí conmigo,' dice el the archivero. 'Se lo dije - mala organización - los burócratas del templo nunca fueron muy sabios.' [end if]"
"sabios/listos/organizacion/burocratas/templo" | "'Este lugar era un sitio bullicioso,' dice. 'No podrías creerlo... por supuesto, todos se fueron, por supuesto, por supuesto. Demandar tributo es un negocio peligroso en el que meterse.'"
"tributo" | "'Las personas se vuelven irritables cuando sus pozos se secan, ' comenta sin parar de contar. 'Adecuado para echar la culpa - cuatro, cinco, eso es una sequía en toda regla, y no sólo un simple hechizo de secar.' Él sostiene en alto la hebra afrentosa para que la veas, pero no consigues discernir más que una fila de cinco nudos en vez de lo que te ha dicho."
"serpiente/serpientes/serpiente de escamas de cobre" | "'Disminuye de tamaño año tras año mientras la maldición sigue su curso,' comenta, distraídamente. 'No será más que un gusano cuando el hechizo termine. Podría mirar, pero no me gusta implicarme tanto.'"
To say string placement:
| if casillero are fixed in place and casillero are in location
| begin;
| say "Entonces alza y mete la hebra en uno de los casilleros; y en cuanto su mano la deja, se vuelve vieja, seca y quebradiza como si hubiese estado ahí durante siglos. ";
| move cuerda profusamente anudada to casillero;
| otherwise;
| say "Entonces él alza y deja en el suelo una hebra a una cierta distancia de él; y en cuanto su mano la deja, se vuelve vieja y seca y quebradiza como si hubiese estado ahí durante siglos. ";
| move cuerda profusamente anudada to location;
| end if.